[gentoo-commits] gentoo-x86 commit in media-radio/wspr: ChangeLog wspr-3.01.ebuild

[gentoo-commits] gentoo-x86 commit in media-radio/wspr: ChangeLog wspr-3.01.ebuild

[Thomas Beierlein (tomjbe)]

tomjbe      14/06/26 09:15:53

  Modified:             ChangeLog
  Added:                wspr-3.01.ebuild
  Log:
  Add newer version from SVN snapshot which does not segfault (bug #511630). Thanks for reporting Teun
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0x762053D5)

Revision  Changes    Path
1.14                 media-radio/wspr/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-radio/wspr/ChangeLog?rev=1.14&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-radio/wspr/ChangeLog?rev=1.14&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-radio/wspr/ChangeLog?r1=1.13&r2=1.14

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-radio/wspr/ChangeLog,v
retrieving revision 1.13
retrieving revision 1.14
diff -u -r1.13 -r1.14
--- ChangeLog	30 Jul 2013 13:22:04 -0000	1.13
+++ ChangeLog	26 Jun 2014 09:15:52 -0000	1.14
@@ -1,6 +1,14 @@
 # ChangeLog for media-radio/wspr
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-radio/wspr/ChangeLog,v 1.13 2013/07/30 13:22:04 tomjbe Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-radio/wspr/ChangeLog,v 1.14 2014/06/26 09:15:52 tomjbe Exp $
+
+*wspr-3.01 (26 Jun 2014)
+
+  26 Jun 2014; Thomas Beierlein <tomjbe@gentoo.org> +wspr-3.01.ebuild,
+  +files/wspr-3.01-PIL.patch, +files/wspr-3.01-script.patch,
+  +files/wspr-3.01-verbose.patch:
+  Add newer version from SVN snapshot which does not segfault (bug #511630).
+  Thanks for reporting Teun
 
   30 Jul 2013; Thomas Beierlein <tomjbe@gentoo.org> -wspr-2.00.ebuild:
   Drop pre EAPI=4 version wrt bug #478576



1.1                  media-radio/wspr/wspr-3.01.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-radio/wspr/wspr-3.01.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-radio/wspr/wspr-3.01.ebuild?rev=1.1&content-type=text/plain

Index: wspr-3.01.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-radio/wspr/wspr-3.01.ebuild,v 1.1 2014/06/26 09:15:52 tomjbe Exp $

EAPI="5"
PYTHON_COMPAT=( python2_{6,7} )
PYTHON_REQ_USE="tk"

inherit autotools fortran-2 distutils-r1 flag-o-matic multilib toolchain-funcs

MY_P=${P}.r2792

DESCRIPTION="Weak Signal Propagation Reporter"
HOMEPAGE="http://www.physics.princeton.edu/pulsar/K1JT/wspr.html"
SRC_URI="http://dev.gentoo.org/~tomjbe/distfiles/${MY_P}.tgz"
LICENSE="GPL-2"

SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RDEPEND="
	virtual/python-imaging[tk,${PYTHON_USEDEP}]
	dev-python/numpy[${PYTHON_USEDEP}]
	virtual/pmw[${PYTHON_USEDEP}]
	sci-libs/fftw:3.0
	media-libs/hamlib
	media-libs/portaudio
	media-libs/libsamplerate"
DEPEND="${RDEPEND}"

S="${WORKDIR}/${MY_P}"

DOCS=( BUGS WSPR_Announcement.TXT WSPR0_Instructions.TXT WSPR_Quick_Start.TXT )

pkg_setup() {
	fortran-2_pkg_setup
}

get_fcomp() {
	case $(tc-getFC) in
	*gfortran* )	FCOMP="gfortran" ;;
	* ) 			FCOMP=$(tc-getFC) ;;
	esac
}

python_prepare_all() {
	tc-export FC
	get_fcomp
	export FC="${FCOMP}"

	local PATCHES=(
		"${FILESDIR}"/${PN}-2.00-libdir.patch
		"${FILESDIR}"/${P}-verbose.patch
		"${FILESDIR}"/${PN}-3.01-script.patch
		"${FILESDIR}"/${P}-PIL.patch
	)

	distutils-r1_python_prepare_all

	sed -i -e "s/LDFLAGS} ${LIBS}/LDFLAGS} -fPIC ${LIBS}/" Makefile.in || die
	sed -i -e "s#/usr/local/lib#/usr/$(get_libdir)#" configure.ac || die
	sed -i -e '/makedirs/d' setup.py || die
	eautoreconf
}

# Note: very hacky build system.
# autoconf which doesn't really need Python
# then custom Makefile which compiles the Python module with f2py
# and finally hacked setup.py which relies on w.so created by make

src_configure() {
	# configure the build of the fortran module
	econf --with-portaudio-lib-dir=/usr/$(get_libdir)

	# then fork the sources
	python_copy_sources
	DISTUTILS_IN_SOURCE_BUILD=1
}

python_compile() {
	# -shared is neded by f2py but cannot be set earlier as configure does
	# not like it
	local LDFLAGS=${LDFLAGS}
	append-ldflags -shared
	emake -j1
}

python_install_all() {
	distutils-r1_python_install_all

	dobin wspr
	insinto /usr/share/${PN}
	doins hamlib_rig_numbers
}