[gentoo-commits] gentoo-x86 commit in sys-block/fio: fio-2.1.10-r1.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in sys-block/fio: fio-2.1.10-r1.ebuild ChangeLog

[Mike Frysinger (vapier)]

vapier      14/06/25 17:53:59

  Modified:             ChangeLog
  Added:                fio-2.1.10-r1.ebuild
  Log:
  Add fix from upstream for json int parsing.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

Revision  Changes    Path
1.48                 sys-block/fio/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-block/fio/ChangeLog?rev=1.48&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-block/fio/ChangeLog?rev=1.48&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-block/fio/ChangeLog?r1=1.47&r2=1.48

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-block/fio/ChangeLog,v
retrieving revision 1.47
retrieving revision 1.48
diff -u -r1.47 -r1.48
--- ChangeLog	25 Jun 2014 17:48:42 -0000	1.47
+++ ChangeLog	25 Jun 2014 17:53:59 -0000	1.48
@@ -1,6 +1,12 @@
 # ChangeLog for sys-block/fio
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-block/fio/ChangeLog,v 1.47 2014/06/25 17:48:42 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-block/fio/ChangeLog,v 1.48 2014/06/25 17:53:59 vapier Exp $
+
+*fio-2.1.10-r1 (25 Jun 2014)
+
+  25 Jun 2014; Mike Frysinger <vapier@gentoo.org> +files/fio-2.1.10-json.patch,
+  +fio-2.1.10-r1.ebuild:
+  Add fix from upstream for json int parsing.
 
   25 Jun 2014; Mike Frysinger <vapier@gentoo.org> fio-2.1.10.ebuild:
   Add arm love.



1.1                  sys-block/fio/fio-2.1.10-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-block/fio/fio-2.1.10-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-block/fio/fio-2.1.10-r1.ebuild?rev=1.1&content-type=text/plain

Index: fio-2.1.10-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-block/fio/fio-2.1.10-r1.ebuild,v 1.1 2014/06/25 17:53:59 vapier Exp $

EAPI="5"
PYTHON_COMPAT=( python2_7 )
inherit eutils python-r1 toolchain-funcs

MY_PV="${PV/_rc/-rc}"
MY_P="${PN}-${MY_PV}"

DESCRIPTION="Jens Axboe's Flexible IO tester"
HOMEPAGE="http://brick.kernel.dk/snaps/"
SRC_URI="http://brick.kernel.dk/snaps/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ia64 ~ppc ~ppc64 ~x86"
IUSE="aio gnuplot gtk numa zlib"

DEPEND="aio? ( dev-libs/libaio )
	gtk? (
		dev-libs/glib:2
		x11-libs/gtk+:2
	)
	numa? ( sys-process/numactl )
	zlib? ( sys-libs/zlib )"
RDEPEND="${DEPEND}
	gnuplot? (
		sci-visualization/gnuplot
		${PYTHON_DEPS}
	)"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	sed -i '/^DEBUGFLAGS/s, -D_FORTIFY_SOURCE=2,,g' Makefile || die
	epatch "${FILESDIR}"/${P}-json.patch
	epatch_user

	# Many checks don't have configure flags.
	sed -i \
		-e "s:\<pkg-config\>:$(tc-getPKG_CONFIG):" \
		-e '/if compile_prog "" "-lz" "zlib" *; *then/  '"s::if $(usex zlib true false) ; then:" \
		-e '/if compile_prog "" "-laio" "libaio" ; then/'"s::if $(usex aio true false) ; then:" \
		configure || die
}

src_configure() {
	# not a real configure script
	./configure \
		--extra-cflags="${CFLAGS} ${CPPFLAGS}" \
		--cc="$(tc-getCC)" \
		$(usex gtk '--enable-gfio' '') \
		$(usex numa '' '--disable-numa') \
		|| die 'configure failed'
}

src_compile() {
	emake V=1 OPTFLAGS=
}

src_install() {
	emake install DESTDIR="${D}" prefix="${EPREFIX}/usr" mandir="${EPREFIX}/usr/share/man"

	if use gnuplot ; then
		python_replicate_script "${ED}/usr/bin/fio2gnuplot"
	else
		rm "${ED}"/usr/bin/{fio2gnuplot,fio_generate_plots} || die
		rm "${ED}"/usr/share/man/man1/{fio2gnuplot,fio_generate_plots}.1 || die
		rm "${ED}"/usr/share/fio/*.gpm || die
		rmdir "${ED}"/usr/share/fio/ 2>/dev/null
	fi

	# This tool has security/parallel issues -- it hardcodes /tmp/template.fio.
	rm "${ED}"/usr/bin/genfio || die

	dodoc README REPORTING-BUGS HOWTO
	docinto examples
	dodoc examples/*
}