* [gentoo-commits] gentoo-x86 commit in app-admin/sysstat: ChangeLog sysstat-11.0.0.ebuild sysstat-10.3.1.ebuild
@ 2014-06-23 20:43 Jeroen Roovers (jer)
0 siblings, 0 replies; only message in thread
From: Jeroen Roovers (jer) @ 2014-06-23 20:43 UTC (permalink / raw
To: gentoo-commits
jer 14/06/23 20:43:15
Modified: ChangeLog
Added: sysstat-11.0.0.ebuild
Removed: sysstat-10.3.1.ebuild
Log:
Version bump.
(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key A792A613)
Revision Changes Path
1.265 app-admin/sysstat/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/sysstat/ChangeLog?rev=1.265&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/sysstat/ChangeLog?rev=1.265&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/sysstat/ChangeLog?r1=1.264&r2=1.265
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/sysstat/ChangeLog,v
retrieving revision 1.264
retrieving revision 1.265
diff -u -r1.264 -r1.265
--- ChangeLog 14 Jun 2014 10:46:19 -0000 1.264
+++ ChangeLog 23 Jun 2014 20:43:15 -0000 1.265
@@ -1,6 +1,12 @@
# ChangeLog for app-admin/sysstat
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/sysstat/ChangeLog,v 1.264 2014/06/14 10:46:19 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/sysstat/ChangeLog,v 1.265 2014/06/23 20:43:15 jer Exp $
+
+*sysstat-11.0.0 (23 Jun 2014)
+
+ 23 Jun 2014; Jeroen Roovers <jer@gentoo.org> -sysstat-10.3.1.ebuild,
+ +sysstat-11.0.0.ebuild:
+ Version bump.
14 Jun 2014; Pawel Hajdan jr <phajdan.jr@gentoo.org>
sysstat-10.2.1-r1.ebuild:
1.1 app-admin/sysstat/sysstat-11.0.0.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/sysstat/sysstat-11.0.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/sysstat/sysstat-11.0.0.ebuild?rev=1.1&content-type=text/plain
Index: sysstat-11.0.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/sysstat/sysstat-11.0.0.ebuild,v 1.1 2014/06/23 20:43:15 jer Exp $
EAPI=5
inherit eutils multilib systemd toolchain-funcs
DESCRIPTION="System performance tools for Linux"
HOMEPAGE="http://pagesperso-orange.fr/sebastien.godard/"
SRC_URI="${HOMEPAGE}${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="cron debug +doc isag nls lm_sensors selinux"
RDEPEND="
cron? ( sys-process/cronbase )
isag? (
dev-lang/tk
dev-vcs/rcs
sci-visualization/gnuplot
)
nls? ( virtual/libintl )
lm_sensors? ( sys-apps/lm_sensors )
selinux? ( sec-policy/selinux-sysstat )
"
DEPEND="
${RDEPEND}
nls? ( sys-devel/gettext )
"
src_prepare() {
if use nls; then
strip-linguas -i nls/
local lingua pofile
for pofile in nls/*.po; do
lingua=${pofile/nls\/}
lingua=${lingua/.po}
if ! has ${lingua} ${LINGUAS}; then
rm "nls/${lingua}.po" || die
fi
done
fi
epatch "${FILESDIR}"/${PN}-10.0.4-flags.patch
}
src_configure() {
tc-export AR
sa_lib_dir=/usr/$(get_libdir)/sa \
conf_dir=/etc \
rcdir=Gentoo-does-not-use-rc.d \
econf \
--enable-copy-only \
--with-systemdsystemunitdir=$(systemd_get_unitdir) \
$(use_enable cron install-cron) \
$(use_enable debug debuginfo) \
$(use_enable doc documentation ) \
$(use_enable isag install-isag) \
$(use_enable lm_sensors sensors) \
$(use_enable nls)
}
src_compile() {
emake LFLAGS="${LDFLAGS}"
}
src_install() {
keepdir /var/log/sa
use cron && dodir /etc/cron.{daily,hourly}
emake \
DESTDIR="${D}" \
DOC_DIR=/usr/share/doc/${PF} \
install
dodoc contrib/sargraph/sargraph
newinitd "${FILESDIR}"/${PN}.init.d ${PN}
systemd_dounit ${PN}.service
use doc && rm -f "${D}"usr/share/doc/${PF}/COPYING
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2014-06-23 20:43 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-06-23 20:43 [gentoo-commits] gentoo-x86 commit in app-admin/sysstat: ChangeLog sysstat-11.0.0.ebuild sysstat-10.3.1.ebuild Jeroen Roovers (jer)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox