* [gentoo-commits] gentoo-x86 commit in sys-apps/shadow: shadow-4.2.1.ebuild ChangeLog
@ 2014-06-16 5:52 Mike Frysinger (vapier)
0 siblings, 0 replies; 3+ messages in thread
From: Mike Frysinger (vapier) @ 2014-06-16 5:52 UTC (permalink / raw
To: gentoo-commits
vapier 14/06/16 05:52:44
Modified: ChangeLog
Added: shadow-4.2.1.ebuild
Log:
Version bump.
(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key D2E96200)
Revision Changes Path
1.293 sys-apps/shadow/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/shadow/ChangeLog?rev=1.293&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/shadow/ChangeLog?rev=1.293&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/shadow/ChangeLog?r1=1.292&r2=1.293
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/shadow/ChangeLog,v
retrieving revision 1.292
retrieving revision 1.293
diff -u -r1.292 -r1.293
--- ChangeLog 18 Jan 2014 04:48:18 -0000 1.292
+++ ChangeLog 16 Jun 2014 05:52:44 -0000 1.293
@@ -1,6 +1,11 @@
# ChangeLog for sys-apps/shadow
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/shadow/ChangeLog,v 1.292 2014/01/18 04:48:18 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/shadow/ChangeLog,v 1.293 2014/06/16 05:52:44 vapier Exp $
+
+*shadow-4.2.1 (16 Jun 2014)
+
+ 16 Jun 2014; Mike Frysinger <vapier@gentoo.org> +shadow-4.2.1.ebuild:
+ Version bump.
18 Jan 2014; Mike Frysinger <vapier@gentoo.org> shadow-4.1.5.1-r1.ebuild:
Add arm64 love.
1.1 sys-apps/shadow/shadow-4.2.1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/shadow/shadow-4.2.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/shadow/shadow-4.2.1.ebuild?rev=1.1&content-type=text/plain
Index: shadow-4.2.1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/shadow/shadow-4.2.1.ebuild,v 1.1 2014/06/16 05:52:43 vapier Exp $
EAPI=4
inherit eutils libtool toolchain-funcs pam multilib
DESCRIPTION="Utilities to deal with user accounts"
HOMEPAGE="http://shadow.pld.org.pl/ http://pkg-shadow.alioth.debian.org/"
SRC_URI="http://pkg-shadow.alioth.debian.org/releases/${P}.tar.xz"
LICENSE="BSD GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="acl audit cracklib nls pam selinux skey xattr"
RDEPEND="acl? ( sys-apps/acl )
audit? ( sys-process/audit )
cracklib? ( >=sys-libs/cracklib-2.7-r3 )
pam? ( virtual/pam )
skey? ( sys-auth/skey )
selinux? (
>=sys-libs/libselinux-1.28
sys-libs/libsemanage
)
nls? ( virtual/libintl )
xattr? ( sys-apps/attr )"
DEPEND="${RDEPEND}
app-arch/xz-utils
nls? ( sys-devel/gettext )"
RDEPEND="${RDEPEND}
pam? ( >=sys-auth/pambase-20120417 )"
src_prepare() {
epatch "${FILESDIR}"/${PN}-4.1.3-dots-in-usernames.patch #22920
epatch_user
elibtoolize
}
src_configure() {
tc-is-cross-compiler && export ac_cv_func_setpgrp_void=yes
econf \
--without-group-name-max-length \
--without-tcb \
--enable-shared=no \
--enable-static=yes \
$(use_with acl) \
$(use_with audit) \
$(use_with cracklib libcrack) \
$(use_with pam libpam) \
$(use_with skey) \
$(use_with selinux) \
$(use_enable nls) \
$(use_with elibc_glibc nscd) \
$(use_with xattr attr)
has_version 'sys-libs/uclibc[-rpc]' && sed -i '/RLOGIN/d' config.h #425052
}
set_login_opt() {
local comment="" opt=$1 val=$2
[[ -z ${val} ]] && comment="#"
sed -i -r \
-e "/^#?${opt}/s:.*:${comment}${opt} ${val}:" \
"${D}"/etc/login.defs
local res=$(grep "^${comment}${opt}" "${D}"/etc/login.defs)
einfo ${res:-Unable to find ${opt} in /etc/login.defs}
}
src_install() {
emake DESTDIR="${D}" suidperms=4711 install
# Remove libshadow and libmisc; see bug 37725 and the following
# comment from shadow's README.linux:
# Currently, libshadow.a is for internal use only, so if you see
# -lshadow in a Makefile of some other package, it is safe to
# remove it.
rm -f "${D}"/{,usr/}$(get_libdir)/lib{misc,shadow}.{a,la}
insinto /etc
# Using a securetty with devfs device names added
# (compat names kept for non-devfs compatibility)
insopts -m0600 ; doins "${FILESDIR}"/securetty
if ! use pam ; then
insopts -m0600
doins etc/login.access etc/limits
fi
# Output arch-specific cruft
local devs
case $(tc-arch) in
ppc*) devs="hvc0 hvsi0 ttyPSC0";;
hppa) devs="ttyB0";;
arm) devs="ttyFB0 ttySAC0 ttySAC1 ttySAC2 ttySAC3 ttymxc0 ttymxc1 ttymxc2 ttymxc3 ttyO0 ttyO1 ttyO2";;
sh) devs="ttySC0 ttySC1";;
esac
[[ -n ${devs} ]] && printf '%s\n' ${devs} >> "${D}"/etc/securetty
# needed for 'useradd -D'
insinto /etc/default
insopts -m0600
doins "${FILESDIR}"/default/useradd
# move passwd to / to help recover broke systems #64441
mv "${D}"/usr/bin/passwd "${D}"/bin/
dosym /bin/passwd /usr/bin/passwd
cd "${S}"
insinto /etc
insopts -m0644
newins etc/login.defs login.defs
if ! use pam ; then
set_login_opt MAIL_CHECK_ENAB no
set_login_opt SU_WHEEL_ONLY yes
set_login_opt CRACKLIB_DICTPATH /usr/$(get_libdir)/cracklib_dict
set_login_opt LOGIN_RETRIES 3
set_login_opt ENCRYPT_METHOD SHA512
else
dopamd "${FILESDIR}"/pam.d-include/shadow
for x in chpasswd chgpasswd newusers; do
newpamd "${FILESDIR}"/pam.d-include/passwd ${x}
done
for x in chage chsh chfn \
user{add,del,mod} group{add,del,mod} ; do
newpamd "${FILESDIR}"/pam.d-include/shadow ${x}
done
# comment out login.defs options that pam hates
local opt
for opt in \
CHFN_AUTH \
CRACKLIB_DICTPATH \
ENV_HZ \
ENVIRON_FILE \
FAILLOG_ENAB \
FTMP_FILE \
LASTLOG_ENAB \
MAIL_CHECK_ENAB \
MOTD_FILE \
NOLOGINS_FILE \
OBSCURE_CHECKS_ENAB \
PASS_ALWAYS_WARN \
PASS_CHANGE_TRIES \
PASS_MIN_LEN \
PORTTIME_CHECKS_ENAB \
QUOTAS_ENAB \
SU_WHEEL_ONLY
do
set_login_opt ${opt}
done
sed -i -f "${FILESDIR}"/login_defs_pam.sed \
"${D}"/etc/login.defs
# remove manpages that pam will install for us
# and/or don't apply when using pam
find "${D}"/usr/share/man \
'(' -name 'limits.5*' -o -name 'suauth.5*' ')' \
-exec rm {} +
# Remove pam.d files provided by pambase.
rm "${D}"/etc/pam.d/{login,passwd,su} || die
fi
# Remove manpages that are handled by other packages
find "${D}"/usr/share/man \
'(' -name id.1 -o -name passwd.5 -o -name getspnam.3 ')' \
-exec rm {} +
cd "${S}"
dodoc ChangeLog NEWS TODO
newdoc README README.download
cd doc
dodoc HOWTO README* WISHLIST *.txt
}
pkg_preinst() {
rm -f "${ROOT}"/etc/pam.d/system-auth.new \
"${ROOT}/etc/login.defs.new"
}
pkg_postinst() {
# Enable shadow groups.
if [ ! -f "${ROOT}"/etc/gshadow ] ; then
if grpck -r -R "${ROOT}" 2>/dev/null ; then
grpconv -R "${ROOT}"
else
ewarn "Running 'grpck' returned errors. Please run it by hand, and then"
ewarn "run 'grpconv' afterwards!"
fi
fi
einfo "The 'adduser' symlink to 'useradd' has been dropped."
}
^ permalink raw reply [flat|nested] 3+ messages in thread
* [gentoo-commits] gentoo-x86 commit in sys-apps/shadow: shadow-4.2.1.ebuild ChangeLog
@ 2014-12-09 1:50 Benda XU (heroxbd)
0 siblings, 0 replies; 3+ messages in thread
From: Benda XU (heroxbd) @ 2014-12-09 1:50 UTC (permalink / raw
To: gentoo-commits
heroxbd 14/12/09 01:50:57
Modified: shadow-4.2.1.ebuild ChangeLog
Log:
Prefix support: trivial D -> ED and ROOT -> EROOT.
(Portage version: 2.2.14/cvs/Linux x86_64, unsigned Manifest commit)
Revision Changes Path
1.2 sys-apps/shadow/shadow-4.2.1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/shadow/shadow-4.2.1.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/shadow/shadow-4.2.1.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/shadow/shadow-4.2.1.ebuild?r1=1.1&r2=1.2
Index: shadow-4.2.1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/shadow/shadow-4.2.1.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- shadow-4.2.1.ebuild 16 Jun 2014 05:52:43 -0000 1.1
+++ shadow-4.2.1.ebuild 9 Dec 2014 01:50:57 -0000 1.2
@@ -1,6 +1,6 @@
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/shadow/shadow-4.2.1.ebuild,v 1.1 2014/06/16 05:52:43 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/shadow/shadow-4.2.1.ebuild,v 1.2 2014/12/09 01:50:57 heroxbd Exp $
EAPI=4
@@ -62,8 +62,8 @@
[[ -z ${val} ]] && comment="#"
sed -i -r \
-e "/^#?${opt}/s:.*:${comment}${opt} ${val}:" \
- "${D}"/etc/login.defs
- local res=$(grep "^${comment}${opt}" "${D}"/etc/login.defs)
+ "${ED}"/etc/login.defs
+ local res=$(grep "^${comment}${opt}" "${ED}"/etc/login.defs)
einfo ${res:-Unable to find ${opt} in /etc/login.defs}
}
@@ -75,7 +75,7 @@
# Currently, libshadow.a is for internal use only, so if you see
# -lshadow in a Makefile of some other package, it is safe to
# remove it.
- rm -f "${D}"/{,usr/}$(get_libdir)/lib{misc,shadow}.{a,la}
+ rm -f "${ED}"/{,usr/}$(get_libdir)/lib{misc,shadow}.{a,la}
insinto /etc
# Using a securetty with devfs device names added
@@ -93,7 +93,7 @@
arm) devs="ttyFB0 ttySAC0 ttySAC1 ttySAC2 ttySAC3 ttymxc0 ttymxc1 ttymxc2 ttymxc3 ttyO0 ttyO1 ttyO2";;
sh) devs="ttySC0 ttySC1";;
esac
- [[ -n ${devs} ]] && printf '%s\n' ${devs} >> "${D}"/etc/securetty
+ [[ -n ${devs} ]] && printf '%s\n' ${devs} >> "${ED}"/etc/securetty
# needed for 'useradd -D'
insinto /etc/default
@@ -101,7 +101,7 @@
doins "${FILESDIR}"/default/useradd
# move passwd to / to help recover broke systems #64441
- mv "${D}"/usr/bin/passwd "${D}"/bin/
+ mv "${ED}"/usr/bin/passwd "${ED}"/bin/
dosym /bin/passwd /usr/bin/passwd
cd "${S}"
@@ -152,20 +152,20 @@
done
sed -i -f "${FILESDIR}"/login_defs_pam.sed \
- "${D}"/etc/login.defs
+ "${ED}"/etc/login.defs
# remove manpages that pam will install for us
# and/or don't apply when using pam
- find "${D}"/usr/share/man \
+ find "${ED}"/usr/share/man \
'(' -name 'limits.5*' -o -name 'suauth.5*' ')' \
-exec rm {} +
# Remove pam.d files provided by pambase.
- rm "${D}"/etc/pam.d/{login,passwd,su} || die
+ rm "${ED}"/etc/pam.d/{login,passwd,su} || die
fi
# Remove manpages that are handled by other packages
- find "${D}"/usr/share/man \
+ find "${ED}"/usr/share/man \
'(' -name id.1 -o -name passwd.5 -o -name getspnam.3 ')' \
-exec rm {} +
@@ -177,13 +177,13 @@
}
pkg_preinst() {
- rm -f "${ROOT}"/etc/pam.d/system-auth.new \
- "${ROOT}/etc/login.defs.new"
+ rm -f "${EROOT}"/etc/pam.d/system-auth.new \
+ "${EROOT}/etc/login.defs.new"
}
pkg_postinst() {
# Enable shadow groups.
- if [ ! -f "${ROOT}"/etc/gshadow ] ; then
+ if [ ! -f "${EROOT}"/etc/gshadow ] ; then
if grpck -r -R "${ROOT}" 2>/dev/null ; then
grpconv -R "${ROOT}"
else
1.295 sys-apps/shadow/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/shadow/ChangeLog?rev=1.295&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/shadow/ChangeLog?rev=1.295&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/shadow/ChangeLog?r1=1.294&r2=1.295
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/shadow/ChangeLog,v
retrieving revision 1.294
retrieving revision 1.295
diff -u -r1.294 -r1.295
--- ChangeLog 13 Jul 2014 17:52:55 -0000 1.294
+++ ChangeLog 9 Dec 2014 01:50:57 -0000 1.295
@@ -1,6 +1,9 @@
# ChangeLog for sys-apps/shadow
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/shadow/ChangeLog,v 1.294 2014/07/13 17:52:55 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/shadow/ChangeLog,v 1.295 2014/12/09 01:50:57 heroxbd Exp $
+
+ 09 Dec 2014; Benda Xu <heroxbd@gentoo.org> shadow-4.2.1.ebuild:
+ Prefix support: trivial D -> ED and ROOT -> EROOT.
13 Jul 2014; Mike Frysinger <vapier@gentoo.org> files/securetty:
Allow root login via any serial device.
^ permalink raw reply [flat|nested] 3+ messages in thread
* [gentoo-commits] gentoo-x86 commit in sys-apps/shadow: shadow-4.2.1.ebuild ChangeLog
@ 2015-02-09 20:34 Mike Frysinger (vapier)
0 siblings, 0 replies; 3+ messages in thread
From: Mike Frysinger (vapier) @ 2015-02-09 20:34 UTC (permalink / raw
To: gentoo-commits
vapier 15/02/09 20:34:28
Modified: shadow-4.2.1.ebuild ChangeLog
Log:
Use -delete with find, and fix prefix handling in a few places.
(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key D2E96200)
Revision Changes Path
1.3 sys-apps/shadow/shadow-4.2.1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/shadow/shadow-4.2.1.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/shadow/shadow-4.2.1.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/shadow/shadow-4.2.1.ebuild?r1=1.2&r2=1.3
Index: shadow-4.2.1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/shadow/shadow-4.2.1.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- shadow-4.2.1.ebuild 9 Dec 2014 01:50:57 -0000 1.2
+++ shadow-4.2.1.ebuild 9 Feb 2015 20:34:28 -0000 1.3
@@ -1,6 +1,6 @@
-# Copyright 1999-2014 Gentoo Foundation
+# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/shadow/shadow-4.2.1.ebuild,v 1.2 2014/12/09 01:50:57 heroxbd Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/shadow/shadow-4.2.1.ebuild,v 1.3 2015/02/09 20:34:28 vapier Exp $
EAPI=4
@@ -101,7 +101,7 @@
doins "${FILESDIR}"/default/useradd
# move passwd to / to help recover broke systems #64441
- mv "${ED}"/usr/bin/passwd "${ED}"/bin/
+ mv "${ED}"/usr/bin/passwd "${ED}"/bin/ || die
dosym /bin/passwd /usr/bin/passwd
cd "${S}"
@@ -158,7 +158,7 @@
# and/or don't apply when using pam
find "${ED}"/usr/share/man \
'(' -name 'limits.5*' -o -name 'suauth.5*' ')' \
- -exec rm {} +
+ -delete
# Remove pam.d files provided by pambase.
rm "${ED}"/etc/pam.d/{login,passwd,su} || die
@@ -167,7 +167,7 @@
# Remove manpages that are handled by other packages
find "${ED}"/usr/share/man \
'(' -name id.1 -o -name passwd.5 -o -name getspnam.3 ')' \
- -exec rm {} +
+ -delete
cd "${S}"
dodoc ChangeLog NEWS TODO
@@ -184,8 +184,8 @@
pkg_postinst() {
# Enable shadow groups.
if [ ! -f "${EROOT}"/etc/gshadow ] ; then
- if grpck -r -R "${ROOT}" 2>/dev/null ; then
- grpconv -R "${ROOT}"
+ if grpck -r -R "${EROOT}" 2>/dev/null ; then
+ grpconv -R "${EROOT}"
else
ewarn "Running 'grpck' returned errors. Please run it by hand, and then"
ewarn "run 'grpconv' afterwards!"
1.296 sys-apps/shadow/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/shadow/ChangeLog?rev=1.296&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/shadow/ChangeLog?rev=1.296&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/shadow/ChangeLog?r1=1.295&r2=1.296
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/shadow/ChangeLog,v
retrieving revision 1.295
retrieving revision 1.296
diff -u -r1.295 -r1.296
--- ChangeLog 9 Dec 2014 01:50:57 -0000 1.295
+++ ChangeLog 9 Feb 2015 20:34:28 -0000 1.296
@@ -1,6 +1,9 @@
# ChangeLog for sys-apps/shadow
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/shadow/ChangeLog,v 1.295 2014/12/09 01:50:57 heroxbd Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/shadow/ChangeLog,v 1.296 2015/02/09 20:34:28 vapier Exp $
+
+ 09 Feb 2015; Mike Frysinger <vapier@gentoo.org> shadow-4.2.1.ebuild:
+ Use -delete with find, and fix prefix handling in a few places.
09 Dec 2014; Benda Xu <heroxbd@gentoo.org> shadow-4.2.1.ebuild:
Prefix support: trivial D -> ED and ROOT -> EROOT.
^ permalink raw reply [flat|nested] 3+ messages in thread
end of thread, other threads:[~2015-02-09 20:34 UTC | newest]
Thread overview: 3+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-06-16 5:52 [gentoo-commits] gentoo-x86 commit in sys-apps/shadow: shadow-4.2.1.ebuild ChangeLog Mike Frysinger (vapier)
-- strict thread matches above, loose matches on Subject: below --
2014-12-09 1:50 Benda XU (heroxbd)
2015-02-09 20:34 Mike Frysinger (vapier)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox