[gentoo-commits] gentoo-x86 commit in media-libs/gstreamer: gstreamer-1.2.4.ebuild ChangeLog gstreamer-1.0.10.ebuild gstreamer-1.2.0.ebuild gstreamer-1.0.5-r1.ebuild

[gentoo-commits] gentoo-x86 commit in media-libs/gstreamer: gstreamer-1.2.4.ebuild ChangeLog gstreamer-1.0.10.ebuild gstreamer-1.2.0.ebuild gstreamer-1.0.5-r1.ebuild

[Pacho Ramos (pacho)]

pacho       14/05/31 14:05:50

  Modified:             ChangeLog
  Added:                gstreamer-1.2.4.ebuild
  Removed:              gstreamer-1.0.10.ebuild gstreamer-1.2.0.ebuild
                        gstreamer-1.0.5-r1.ebuild
  Log:
  Version bump, drop old
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.367                media-libs/gstreamer/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/gstreamer/ChangeLog?rev=1.367&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/gstreamer/ChangeLog?rev=1.367&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/gstreamer/ChangeLog?r1=1.366&r2=1.367

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/gstreamer/ChangeLog,v
retrieving revision 1.366
retrieving revision 1.367
diff -u -r1.366 -r1.367
--- ChangeLog	29 Apr 2014 07:02:03 -0000	1.366
+++ ChangeLog	31 May 2014 14:05:50 -0000	1.367
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/gstreamer
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/gstreamer/ChangeLog,v 1.366 2014/04/29 07:02:03 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/gstreamer/ChangeLog,v 1.367 2014/05/31 14:05:50 pacho Exp $
+
+*gstreamer-1.2.4 (31 May 2014)
+
+  31 May 2014; Pacho Ramos <pacho@gentoo.org> +gstreamer-1.2.4.ebuild,
+  -gstreamer-1.0.10.ebuild, -gstreamer-1.0.5-r1.ebuild, -gstreamer-1.2.0.ebuild:
+  Version bump, drop old
 
   29 Apr 2014; Lars Wendler <polynomial-c@gentoo.org> gstreamer-0.10.36.ebuild,
   +files/gstreamer-make-grammar.y-work-with-bison-3.patch:



1.1                  media-libs/gstreamer/gstreamer-1.2.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/gstreamer/gstreamer-1.2.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/gstreamer/gstreamer-1.2.4.ebuild?rev=1.1&content-type=text/plain

Index: gstreamer-1.2.4.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/gstreamer/gstreamer-1.2.4.ebuild,v 1.1 2014/05/31 14:05:50 pacho Exp $

EAPI="5"

inherit eutils multilib pax-utils

DESCRIPTION="Streaming media framework"
HOMEPAGE="http://gstreamer.freedesktop.org/"
SRC_URI="http://${PN}.freedesktop.org/src/${PN}/${P}.tar.xz"

LICENSE="LGPL-2+"
SLOT="1.0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="+introspection nls +orc test"

RDEPEND="
	>=dev-libs/glib-2.32:2
	introspection? ( >=dev-libs/gobject-introspection-1.31.1 )
"
DEPEND="${RDEPEND}
	app-arch/xz-utils
	>=dev-util/gtk-doc-am-1.12
	sys-devel/bison
	sys-devel/flex
	virtual/pkgconfig
	nls? ( sys-devel/gettext )
"
# gtk-doc-am to install API docs

src_configure() {
	if [[ ${CHOST} == *-interix* ]] ; then
		export ac_cv_lib_dl_dladdr=no
		export ac_cv_func_poll=no
	fi
	if [[ ${CHOST} == powerpc-apple-darwin* ]] ; then
		# GCC groks this, but then refers to an implementation (___multi3,
		# ___udivti3) that don't exist (at least I can't find it), so force
		# this one to be off, such that we use 2x64bit emulation code.
		export gst_cv_uint128_t=no
	fi

	# Disable static archives, dependency tracking and examples
	# to speed up build time
	# Disable debug, as it only affects -g passing (debugging symbols), this must done through make.conf in gentoo
	econf \
		--disable-debug \
		--disable-examples \
		--disable-static \
		--disable-valgrind \
		--enable-check \
		$(use_enable introspection) \
		$(use_enable nls) \
		$(use_enable test tests) \
		--with-package-name="GStreamer ebuild for Gentoo" \
		--with-package-origin="http://packages.gentoo.org/package/media-libs/gstreamer"
}

src_install() {
	DOCS="AUTHORS ChangeLog NEWS MAINTAINERS README RELEASE"
	default
	prune_libtool_files --modules

	# Needed for orc-using gst plugins on hardened/PaX systems, bug #421579
	use orc && pax-mark -m "${ED}usr/bin/gst-launch-${SLOT}" \
		"${ED}usr/libexec/gstreamer-${SLOT}/gst-plugin-scanner"
}