[gentoo-commits] gentoo-x86 commit in dev-libs/libgdata: libgdata-0.14.3.ebuild ChangeLog libgdata-0.14.0.ebuild

[gentoo-commits] gentoo-x86 commit in dev-libs/libgdata: libgdata-0.14.3.ebuild ChangeLog libgdata-0.14.0.ebuild

[Pacho Ramos (pacho)]

pacho       14/05/31 10:12:39

  Modified:             ChangeLog
  Added:                libgdata-0.14.3.ebuild
  Removed:              libgdata-0.14.0.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.75                 dev-libs/libgdata/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libgdata/ChangeLog?rev=1.75&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libgdata/ChangeLog?rev=1.75&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libgdata/ChangeLog?r1=1.74&r2=1.75

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/libgdata/ChangeLog,v
retrieving revision 1.74
retrieving revision 1.75
diff -u -r1.74 -r1.75
--- ChangeLog	9 Mar 2014 11:55:19 -0000	1.74
+++ ChangeLog	31 May 2014 10:12:39 -0000	1.75
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/libgdata
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libgdata/ChangeLog,v 1.74 2014/03/09 11:55:19 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libgdata/ChangeLog,v 1.75 2014/05/31 10:12:39 pacho Exp $
+
+*libgdata-0.14.3 (31 May 2014)
+
+  31 May 2014; Pacho Ramos <pacho@gentoo.org> +libgdata-0.14.3.ebuild,
+  -libgdata-0.14.0.ebuild:
+  Version bump
 
   09 Mar 2014; Pacho Ramos <pacho@gentoo.org> libgdata-0.14.1.ebuild:
   x86 stable, bug 499954



1.1                  dev-libs/libgdata/libgdata-0.14.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libgdata/libgdata-0.14.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libgdata/libgdata-0.14.3.ebuild?rev=1.1&content-type=text/plain

Index: libgdata-0.14.3.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/libgdata/libgdata-0.14.3.ebuild,v 1.1 2014/05/31 10:12:39 pacho Exp $

EAPI="5"
GCONF_DEBUG="yes"
VALA_MIN_API_VERSION="0.20"
VALA_USE_DEPEND="vapigen"

inherit gnome2 vala

DESCRIPTION="GLib-based library for accessing online service APIs using the GData protocol"
HOMEPAGE="https://wiki.gnome.org/Projects/libgdata"

LICENSE="LGPL-2.1+"
SLOT="0/13" # subslot = libgdata soname version
IUSE="gnome +introspection static-libs vala"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
REQUIRED_IUSE="vala? ( introspection )"

# gtk+ is needed for gdk
# configure checks for gtk:3, but only uses it for demos which are not installed
RDEPEND="
	>=dev-libs/glib-2.31:2
	>=dev-libs/libxml2-2:2
	>=net-libs/liboauth-0.9.4
	>=net-libs/libsoup-2.42.0:2.4[introspection?]
	>=x11-libs/gdk-pixbuf-2.14:2
	gnome? (
		app-crypt/gcr:=
		>=net-libs/gnome-online-accounts-3.2 )
	introspection? ( >=dev-libs/gobject-introspection-0.9.7 )
"
DEPEND="${RDEPEND}
	>=dev-util/gtk-doc-am-1.14
	>=dev-util/intltool-0.40
	>=gnome-base/gnome-common-3.6
	virtual/pkgconfig
	vala? ( $(vala_depend) )
"

src_prepare() {
	# Disable tests requiring network access, bug #307725
	sed -e '/^TEST_PROGS = / s:\(.*\):TEST_PROGS = general perf calendar client-login-authorizer contacts documents oauth1-authorizer picasaweb youtube \nOLD_\1:' \
		-i gdata/tests/Makefile.in || die "network test disable failed"

	vala_src_prepare
	gnome2_src_prepare
}

src_configure() {
	DOCS="AUTHORS ChangeLog HACKING NEWS README"
	gnome2_src_configure \
		$(use_enable gnome) \
		$(use_enable gnome goa) \
		$(use_enable introspection) \
		$(use_enable vala) \
		$(use_enable static-libs static)
}

src_test() {
	unset ORBIT_SOCKETDIR
	unset DBUS_SESSION_BUS_ADDRESS
	dbus-launch emake check || die "emake check failed"
}