[gentoo-commits] gentoo-x86 commit in dev-cpp/gtkmm: ChangeLog gtkmm-3.12.0.ebuild

["Gilles Dartiguelongue (eva)" <eva@gentoo.org>]

eva         14/04/27 16:13:05

  Modified:             ChangeLog
  Added:                gtkmm-3.12.0.ebuild
  Log:
  Version bump for Gnome 3.12.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key C6085806)

Revision  Changes    Path
1.280                dev-cpp/gtkmm/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-cpp/gtkmm/ChangeLog?rev=1.280&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-cpp/gtkmm/ChangeLog?rev=1.280&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-cpp/gtkmm/ChangeLog?r1=1.279&r2=1.280

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-cpp/gtkmm/ChangeLog,v
retrieving revision 1.279
retrieving revision 1.280
diff -u -r1.279 -r1.280
--- ChangeLog	23 Apr 2014 21:04:34 -0000	1.279
+++ ChangeLog	27 Apr 2014 16:13:05 -0000	1.280
@@ -1,6 +1,11 @@
 # ChangeLog for dev-cpp/gtkmm
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-cpp/gtkmm/ChangeLog,v 1.279 2014/04/23 21:04:34 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-cpp/gtkmm/ChangeLog,v 1.280 2014/04/27 16:13:05 eva Exp $
+
+*gtkmm-3.12.0 (27 Apr 2014)
+
+  27 Apr 2014; Gilles Dartiguelongue <eva@gentoo.org> +gtkmm-3.12.0.ebuild:
+  Version bump for Gnome 3.12.
 
   23 Apr 2014; Pacho Ramos <pacho@gentoo.org>
   -files/gtkmm-3.4.0-automagic-gdk-targets.patch, -gtkmm-2.24.2.ebuild,



1.1                  dev-cpp/gtkmm/gtkmm-3.12.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-cpp/gtkmm/gtkmm-3.12.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-cpp/gtkmm/gtkmm-3.12.0.ebuild?rev=1.1&content-type=text/plain

Index: gtkmm-3.12.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-cpp/gtkmm/gtkmm-3.12.0.ebuild,v 1.1 2014/04/27 16:13:05 eva Exp $

EAPI="5"
GCONF_DEBUG="no"

inherit gnome2

DESCRIPTION="C++ interface for GTK+"
HOMEPAGE="http://www.gtkmm.org"

LICENSE="LGPL-2.1"
SLOT="3.0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~x86-solaris"
IUSE="aqua doc examples test wayland +X"
REQUIRED_USE="|| ( aqua wayland X )"

RDEPEND="
	>=dev-cpp/glibmm-2.38.0:2
	>=x11-libs/gtk+-3.12:3[aqua?,wayland?,X?]
	>=x11-libs/gdk-pixbuf-2.26:2
	>=dev-cpp/atkmm-2.22.2
	>=dev-cpp/cairomm-1.9.2.2
	>=dev-cpp/pangomm-2.27.1:1.4
	dev-libs/libsigc++:2
"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	doc? (
		media-gfx/graphviz
		dev-libs/libxslt
		app-doc/doxygen )
"
#	dev-cpp/mm-common"
# eautoreconf needs mm-common

src_prepare() {
	if ! use test; then
		# don't waste time building tests
		sed 's/^\(SUBDIRS =.*\)tests\(.*\)$/\1\2/' -i Makefile.am Makefile.in \
			|| die "sed 1 failed"
	fi

	if ! use examples; then
		# don't waste time building tests
		sed 's/^\(SUBDIRS =.*\)demos\(.*\)$/\1\2/' -i Makefile.am Makefile.in \
			|| die "sed 2 failed"
	fi

	gnome2_src_prepare
}

src_configure() {
	DOCS="AUTHORS ChangeLog PORTING NEWS README"
	gnome2_src_configure \
		--enable-api-atkmm \
		$(use_enable doc documentation) \
		$(use_enable aqua quartz-backend) \
		$(use_enable wayland wayland-backend) \
		$(use_enable X x11-backend)
}