[gentoo-commits] gentoo-x86 commit in app-arch/engrampa: metadata.xml ChangeLog engrampa-1.8.0.ebuild

["Tom Wijsman (tomwij)" <tomwij@gentoo.org>]

tomwij      14/04/27 15:49:04

  Added:                metadata.xml ChangeLog engrampa-1.8.0.ebuild
  Log:
  Version bump to 1.8.0, continuation of app-arch/mate-file-archiver.
  
  (Portage version: HEAD/cvs/Linux x86_64, signed Manifest commit with key 6D34E57D)

Revision  Changes    Path
1.1                  app-arch/engrampa/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/engrampa/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/engrampa/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<maintainer>
		<email>TomWij@gentoo.org</email>
		<name>Tom Wijsman</name>
	</maintainer>
	<use>
		<flag name="caja">Enable engrampa to integrate with
			<pkg>mate-base/mate-file-manager</pkg> by providing entries in its 
			context menu</flag>
	</use>
</pkgmetadata>



1.1                  app-arch/engrampa/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/engrampa/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/engrampa/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for app-arch/engrampa
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/app-arch/engrampa/ChangeLog,v 1.1 2014/04/27 15:49:03 tomwij Exp $

*engrampa-1.8.0 (27 Apr 2014)

  27 Apr 2014; Tom Wijsman <TomWij@gentoo.org> +engrampa-1.8.0.ebuild,
  +metadata.xml:
  Version bump to 1.8.0, continuation of app-arch/mate-file-archiver.



1.1                  app-arch/engrampa/engrampa-1.8.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/engrampa/engrampa-1.8.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/engrampa/engrampa-1.8.0.ebuild?rev=1.1&content-type=text/plain

Index: engrampa-1.8.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-arch/engrampa/engrampa-1.8.0.ebuild,v 1.1 2014/04/27 15:49:03 tomwij Exp $

EAPI="5"

GCONF_DEBUG="yes"
GNOME2_LA_PUNT="yes"

inherit gnome2 versionator

MATE_BRANCH="$(get_version_component_range 1-2)"

SRC_URI="http://pub.mate-desktop.org/releases/${MATE_BRANCH}/${P}.tar.xz"
DESCRIPTION="Engrampa archive manager for MATE"
HOMEPAGE="http://mate-desktop.org"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64"

IUSE="caja"

RDEPEND=">=x11-libs/gtk+-2.21.4:2
	>=dev-libs/glib-2.25.5:2
	>=dev-libs/json-glib-0.14:0
	x11-libs/gdk-pixbuf:2
	x11-libs/pango:0
	virtual/libintl:0
	caja? ( || ( >=mate-base/caja-1.8:0 >=mate-base/mate-file-manager-1.6:0 ) )
	!!app-arch/mate-file-archiver"

DEPEND="${RDEPEND}
	>=dev-util/intltool-0.35:*
	>=mate-base/mate-common-1.6:0
	sys-devel/gettext:*
	virtual/pkgconfig:*"

src_prepare() {
	gnome2_src_prepare

	# Drop DEPRECATED flags as configure option doesn't do it, bug #385453
	sed -i -e 's:-D[A-Z_]*DISABLE_DEPRECATED:$(NULL):g' \
		copy-n-paste/Makefile.am copy-n-paste/Makefile.in || die
}

src_configure() {
	gnome2_src_configure \
		--disable-run-in-place \
		--disable-packagekit \
		--disable-deprecations \
		--with-gtk=2.0 \
		$(use_enable caja caja-actions)
}

DOCS="AUTHORS HACKING MAINTAINERS NEWS README TODO"

pkg_postinst() {
	gnome2_pkg_postinst

	elog ""
	elog "${PN} is a frontend for several archiving utilities. If you want a"
	elog "particular achive format supported install the relevant package."
	elog
	elog "For example:"
	elog "  7-zip   : emerge app-arch/p7zip"
	elog "  ace     : emerge app-arch/unace"
	elog "  arj     : emerge app-arch/arj"
	elog "  cpio    : emerge app-arch/cpio"
	elog "  deb     : emerge app-arch/dpkg"
	elog "  iso     : emerge app-cdr/cdrtools"
	elog "  jar,zip : emerge app-arch/zip  or  emerge app-arch/unzip"
	elog "  lha     : emerge app-arch/lha"
	elog "  lzma    : emerge app-arch/xz-utils"
	elog "  lzop    : emerge app-arch/lzop"
	elog "  rar     : emerge app-arch/unrar"
	elog "  rpm     : emerge app-arch/rpm"
	elog "  unstuff : emerge app-arch/stuffit"
	elog "  zoo     : emerge app-arch/zoo"
}