[gentoo-commits] gentoo-x86 commit in www-client/lynx: ChangeLog lynx-2.8.8_p2.ebuild

["Tim Harder (radhermit)" <radhermit@gentoo.org>]

radhermit    14/04/25 08:33:08

  Modified:             ChangeLog
  Added:                lynx-2.8.8_p2.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.152                www-client/lynx/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/lynx/ChangeLog?rev=1.152&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/lynx/ChangeLog?rev=1.152&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/lynx/ChangeLog?r1=1.151&r2=1.152

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/lynx/ChangeLog,v
retrieving revision 1.151
retrieving revision 1.152
diff -u -r1.151 -r1.152
--- ChangeLog	6 Apr 2014 15:12:46 -0000	1.151
+++ ChangeLog	25 Apr 2014 08:33:08 -0000	1.152
@@ -1,6 +1,11 @@
 # ChangeLog for www-client/lynx
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/lynx/ChangeLog,v 1.151 2014/04/06 15:12:46 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/lynx/ChangeLog,v 1.152 2014/04/25 08:33:08 radhermit Exp $
+
+*lynx-2.8.8_p2 (25 Apr 2014)
+
+  25 Apr 2014; Tim Harder <radhermit@gentoo.org> +lynx-2.8.8_p2.ebuild:
+  Version bump.
 
   06 Apr 2014; Mike Frysinger <vapier@gentoo.org> lynx-2.8.8_p1.ebuild,
   lynx-2.8.8_rc1.ebuild:



1.1                  www-client/lynx/lynx-2.8.8_p2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/lynx/lynx-2.8.8_p2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/lynx/lynx-2.8.8_p2.ebuild?rev=1.1&content-type=text/plain

Index: lynx-2.8.8_p2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/lynx/lynx-2.8.8_p2.ebuild,v 1.1 2014/04/25 08:33:08 radhermit Exp $

EAPI=5

inherit eutils versionator

# VERSIONING SCHEME TRANSLATION
# Upstream	:	Gentoo
# rel.		:	_p
# pre.		:	_rc
# dev.		:	_pre

case ${PV} in
	*_pre*) MY_P="${PN}${PV/_pre/dev.}" ;;
	*_rc*)  MY_P="${PN}${PV/_rc/pre.}" ;;
	*_p*|*) MY_P="${PN}${PV/_p/rel.}" ;;
esac

DESCRIPTION="An excellent console-based web browser with ssl support"
HOMEPAGE="http://lynx.isc.org/"
SRC_URI="http://lynx.isc.org/current/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~ia64-hpux ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="bzip2 cjk gnutls idn ipv6 nls ssl unicode"

RDEPEND="sys-libs/ncurses[unicode?]
	sys-libs/zlib
	nls? ( virtual/libintl )
	ssl? (
		!gnutls? ( >=dev-libs/openssl-0.9.8 )
		gnutls? (
			dev-libs/libgcrypt:0
			>=net-libs/gnutls-2.6.4
		)
	)
	bzip2? ( app-arch/bzip2 )
	idn? ( net-dns/libidn )"

DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )
	virtual/pkgconfig"

S="${WORKDIR}/${PN}$(replace_all_version_separators - $(get_version_component_range 1-3))"

pkg_setup() {
	! use ssl && elog "SSL support disabled; you will not be able to access secure websites."
}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-2.8.6-mint.patch
	epatch "${FILESDIR}"/${PN}-2.8.8_p1-parallel.patch
}

src_configure() {
	econf \
		--enable-nested-tables \
		--enable-cgi-links \
		--enable-persistent-cookies \
		--enable-prettysrc \
		--enable-nsl-fork \
		--enable-file-upload \
		--enable-read-eta \
		--enable-color-style \
		--enable-scrollbar \
		--enable-included-msgs \
		--enable-externs \
		--with-zlib \
		$(use_enable nls) \
		$(use_enable idn idna) \
		$(use_enable ipv6) \
		$(use_enable cjk) \
		$(use_enable unicode japanese-utf8) \
		$(use_with bzip2 bzlib) \
		$(usex ssl "--with-$(usex gnutls gnutls ssl)=${EPREFIX}/usr" "") \
		$(usex unicode "--with-screen=ncursesw" "")
}

src_install() {
	emake install DESTDIR="${D}"

	sed -i "s|^HELPFILE.*$|HELPFILE:file://localhost/usr/share/doc/${PF}/lynx_help/lynx_help_main.html|" \
			"${ED}"/etc/lynx.cfg || die "lynx.cfg not found"
	if use unicode ; then
		sed -i '/^#CHARACTER_SET:/ c\CHARACTER_SET:utf-8' \
				"${ED}"/etc/lynx.cfg || die "lynx.cfg not found"
	fi

	dodoc CHANGES COPYHEADER PROBLEMS README
	docinto docs
	dodoc docs/*
	docinto lynx_help
	dodoc lynx_help/*.txt
	dohtml -r lynx_help/*
}