[gentoo-commits] gentoo-x86 commit in app-office/akonadi-server: akonadi-server-1.12.1-r1.ebuild ChangeLog akonadi-server-1.12.1.ebuild

[gentoo-commits] gentoo-x86 commit in app-office/akonadi-server: akonadi-server-1.12.1-r1.ebuild ChangeLog akonadi-server-1.12.1.ebuild

[Johannes Huber (johu)]

johu        14/04/22 15:44:02

  Modified:             ChangeLog
  Added:                akonadi-server-1.12.1-r1.ebuild
  Removed:              akonadi-server-1.12.1.ebuild
  Log:
  Revision bump adds upstream patch which fixes db initialization error, bug #506608. Remove old.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key F3CFD2BD)

Revision  Changes    Path
1.141                app-office/akonadi-server/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/akonadi-server/ChangeLog?rev=1.141&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/akonadi-server/ChangeLog?rev=1.141&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/akonadi-server/ChangeLog?r1=1.140&r2=1.141

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-office/akonadi-server/ChangeLog,v
retrieving revision 1.140
retrieving revision 1.141
diff -u -r1.140 -r1.141
--- ChangeLog	21 Apr 2014 13:45:37 -0000	1.140
+++ ChangeLog	22 Apr 2014 15:44:02 -0000	1.141
@@ -1,6 +1,15 @@
 # ChangeLog for app-office/akonadi-server
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/akonadi-server/ChangeLog,v 1.140 2014/04/21 13:45:37 johu Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-office/akonadi-server/ChangeLog,v 1.141 2014/04/22 15:44:02 johu Exp $
+
+*akonadi-server-1.12.1-r1 (22 Apr 2014)
+
+  22 Apr 2014; Johannes Huber <johu@gentoo.org>
+  +akonadi-server-1.12.1-r1.ebuild,
+  +files/akonadi-server-1.12.1-db-initialize.patch,
+  -akonadi-server-1.12.1.ebuild:
+  Revision bump adds upstream patch which fixes db initialization error, bug
+  #506608. Remove old.
 
   21 Apr 2014; Johannes Huber <johu@gentoo.org> akonadi-server-1.12.1.ebuild,
   metadata.xml:



1.1                  app-office/akonadi-server/akonadi-server-1.12.1-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/akonadi-server/akonadi-server-1.12.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/akonadi-server/akonadi-server-1.12.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: akonadi-server-1.12.1-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-office/akonadi-server/akonadi-server-1.12.1-r1.ebuild,v 1.1 2014/04/22 15:44:02 johu Exp $

EAPI=5

if [[ $PV = *9999* ]]; then
	scm_eclass=git-r3
	EGIT_REPO_URI=( "git://anongit.kde.org/akonadi" )
	SRC_URI=""
	KEYWORDS=""
else
	SRC_URI="mirror://kde/stable/${PN/-server/}/src/${P/-server/}.tar.bz2"
	KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
	S="${WORKDIR}/${P/-server/}"
fi

inherit cmake-utils ${scm_eclass}

DESCRIPTION="The server part of Akonadi"
HOMEPAGE="http://pim.kde.org/akonadi"

LICENSE="LGPL-2.1"
SLOT="0"
IUSE="+mysql postgres +qt4 qt5 soprano sqlite test"

REQUIRED_USE="^^ ( qt4 qt5 ) || ( sqlite mysql postgres )"

CDEPEND="
	dev-libs/boost:=
	x11-misc/shared-mime-info
	qt4? (
		>=dev-qt/qtcore-4.8.5:4
		>=dev-qt/qtdbus-4.8.5:4
		>=dev-qt/qtgui-4.8.5:4
		>=dev-qt/qtsql-4.8.5:4[mysql?,postgres?]
		>=dev-qt/qttest-4.8.5:4
	)
	qt5? (
		dev-qt/qtcore:5
		dev-qt/qtdbus:5
		dev-qt/qtgui:5
		dev-qt/qtnetwork:5
		dev-qt/qtsql:5[mysql?,postgres?]
		dev-qt/qttest:5
		dev-qt/qtwidgets:5
		dev-qt/qtxml:5
		soprano? ( dev-libs/soprano[-qt4,qt5] )
	)
	soprano? ( dev-libs/soprano )
	sqlite? ( dev-db/sqlite:3 )
"
DEPEND="${CDEPEND}
	dev-libs/libxslt
	>=dev-util/automoc-0.9.88
	test? ( sys-apps/dbus )
"
RDEPEND="${CDEPEND}
	postgres? ( dev-db/postgresql-server )
"

PATCHES=( "${FILESDIR}/${P}-db-initialize.patch" )

pkg_setup() {
	# Set default storage backend in order: MySQL, SQLite PostgreSQL
	# reverse driver check to keep the order
	if use postgres; then
		DRIVER="QPSQL"
		AVAILABLE+=" ${DRIVER}"
	fi

	if use sqlite; then
		DRIVER="QSQLITE3"
		AVAILABLE+=" ${DRIVER}"
	fi

	if use mysql; then
		DRIVER="QMYSQL"
		AVAILABLE+=" ${DRIVER}"
	fi

	# Notify about MySQL is recommend by upstream
	if use sqlite || has_version "<${CATEGORY}/${P}[sqlite]"; then
		ewarn
		ewarn "We strongly recommend you change your Akonadi database backend to MySQL in your"
		ewarn "user configuration. This is the backend recommended by KDE upstream."
		ewarn "In particular, kde-base/kmail-4.10 does not work properly with the sqlite"
		ewarn "backend anymore."
		ewarn "You can select the backend in your ~/.config/akonadi/akonadiserverrc."
		ewarn "Available drivers are:${AVAILABLE}"
		ewarn
	fi
}

src_configure() {
	local mycmakeargs=(
		-DINSTALL_QSQLITE_IN_QT_PREFIX=ON
		$(cmake-utils_use test AKONADI_BUILD_TESTS)
		$(cmake-utils_use_with soprano)
		$(cmake-utils_use sqlite AKONADI_BUILD_QSQLITE)
		$(cmake-utils_use qt5 QT5_BUILD)
	)

	cmake-utils_src_configure
}

src_test() {
	export $(dbus-launch)
	cmake-utils_src_test
}

src_install() {
	# Who knows, maybe it accidentally fixes our permission issues
	cat <<-EOF > "${T}"/akonadiserverrc
[%General]
Driver=${DRIVER}
EOF
	insinto /usr/share/config/akonadi
	doins "${T}"/akonadiserverrc

	cmake-utils_src_install
}

pkg_postinst() {
	elog "${DRIVER} has been set as your default akonadi storage backend."
	elog "You can override it in your ~/.config/akonadi/akonadiserverrc."
	elog "Available drivers are: ${AVAILABLE}"
}