[gentoo-commits] gentoo-x86 commit in dev-ruby/thor: ChangeLog thor-0.19.1.ebuild

[gentoo-commits] gentoo-x86 commit in dev-ruby/thor: ChangeLog thor-0.19.1.ebuild

[Hans de Graaff (graaff)]

graaff      14/04/19 08:41:03

  Modified:             ChangeLog
  Added:                thor-0.19.1.ebuild
  Log:
  Version bump. Add ruby21.
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0x8883FA56A308A8D7!)

Revision  Changes    Path
1.21                 dev-ruby/thor/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/thor/ChangeLog?rev=1.21&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/thor/ChangeLog?rev=1.21&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/thor/ChangeLog?r1=1.20&r2=1.21

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-ruby/thor/ChangeLog,v
retrieving revision 1.20
retrieving revision 1.21
diff -u -r1.20 -r1.21
--- ChangeLog	5 Apr 2014 14:35:29 -0000	1.20
+++ ChangeLog	19 Apr 2014 08:41:03 -0000	1.21
@@ -1,6 +1,11 @@
 # ChangeLog for dev-ruby/thor
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/thor/ChangeLog,v 1.20 2014/04/05 14:35:29 mrueg Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/thor/ChangeLog,v 1.21 2014/04/19 08:41:03 graaff Exp $
+
+*thor-0.19.1 (19 Apr 2014)
+
+  19 Apr 2014; Hans de Graaff <graaff@gentoo.org> +thor-0.19.1.ebuild:
+  Version bump. Add ruby21.
 
   05 Apr 2014; Manuel Rüger <mrueg@gentoo.org> thor-0.14.6.ebuild,
   thor-0.15.2.ebuild, thor-0.18.1.ebuild:



1.1                  dev-ruby/thor/thor-0.19.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/thor/thor-0.19.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/thor/thor-0.19.1.ebuild?rev=1.1&content-type=text/plain

Index: thor-0.19.1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ruby/thor/thor-0.19.1.ebuild,v 1.1 2014/04/19 08:41:03 graaff Exp $

EAPI=5
USE_RUBY="ruby19 ruby20 ruby21 jruby"

RUBY_FAKEGEM_RECIPE_DOC="rdoc"
RUBY_FAKEGEM_RECIPE_TEST="rspec"
RUBY_FAKEGEM_DOCDIR="rdoc"
RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"
RUBY_FAKEGEM_BINWRAP="thor"

inherit ruby-fakegem

DESCRIPTION="A scripting framework that replaces rake and sake"
HOMEPAGE="http://whatisthor.com/"

SRC_URI="http://github.com/erikhuda/${PN}/archive/v${PV}.tar.gz -> ${PN}-git-${PV}.tgz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="doc"

ruby_add_bdepend "
	test? (
		>=dev-ruby/fakeweb-1.3
		dev-ruby/childlabor
	)"

all_ruby_prepare() {
	# Remove rspec default options (as we might not have the last
	# rspec).
	rm .rspec || die

	# Remove Bundler
	#rm Gemfile || die
	sed -i -e '/[Bb]undler/d' Thorfile || die

	# Remove mandatory coverage collection using simplecov which is not
	# packaged.
	sed -i -e '/require .simplecov/,/^end/ s:^:#:' spec/helper.rb || die

	# Avoid a spec that requires UTF-8 support, so LANG=C still works,
	# bug 430402
	sed -i -e '/uses maximum terminal width/,/end/ s:^:#:' spec/shell/basic_spec.rb || die
}

each_ruby_prepare() {
	# Skip two failing specs on thor. Our jruby 1.6 is too old to file
	# bugs against and the next thor version will no longer work with
	# this version altogether.
	case ${RUBY} in
		*jruby)
			sed -i -e '/works with glob characters in the path/,/end/ s:^:#:' \
				spec/actions/directory_spec.rb || die
			;;
	esac
}