From: "Pacho Ramos (pacho)" <pacho@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] gentoo-x86 commit in net-wireless/bluez: bluez-5.18.ebuild ChangeLog bluez-5.16.ebuild
Date: Thu, 17 Apr 2014 06:56:39 +0000 (UTC) [thread overview]
Message-ID: <20140417065639.BC0072004B@flycatcher.gentoo.org> (raw)
pacho 14/04/17 06:56:39
Modified: ChangeLog
Added: bluez-5.18.ebuild
Removed: bluez-5.16.ebuild
Log:
Version bump (#507752 by Manuel Ruger), drop rfcomm init.d as it's not compatible with recent versions (#505786 by Antti Makela), drop old.
(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)
Revision Changes Path
1.198 net-wireless/bluez/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/bluez/ChangeLog?rev=1.198&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/bluez/ChangeLog?rev=1.198&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/bluez/ChangeLog?r1=1.197&r2=1.198
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-wireless/bluez/ChangeLog,v
retrieving revision 1.197
retrieving revision 1.198
diff -u -r1.197 -r1.198
--- ChangeLog 9 Apr 2014 14:04:14 -0000 1.197
+++ ChangeLog 17 Apr 2014 06:56:39 -0000 1.198
@@ -1,6 +1,13 @@
# ChangeLog for net-wireless/bluez
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/bluez/ChangeLog,v 1.197 2014/04/09 14:04:14 scarabeus Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/bluez/ChangeLog,v 1.198 2014/04/17 06:56:39 pacho Exp $
+
+*bluez-5.18 (17 Apr 2014)
+
+ 17 Apr 2014; Pacho Ramos <pacho@gentoo.org> +bluez-5.18.ebuild,
+ -bluez-5.16.ebuild:
+ Version bump (#507752 by Manuel Ruger), drop rfcomm init.d as it's not
+ compatible with recent versions (#505786 by Antti Makela), drop old.
09 Apr 2014; Tomáš Chvátal <scarabeus@gentoo.org>
files/0001-work-around-Logitech-diNovo-Edge-keyboard-firmware-i.patch:
1.1 net-wireless/bluez/bluez-5.18.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/bluez/bluez-5.18.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/bluez/bluez-5.18.ebuild?rev=1.1&content-type=text/plain
Index: bluez-5.18.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-wireless/bluez/bluez-5.18.ebuild,v 1.1 2014/04/17 06:56:39 pacho Exp $
EAPI=5
PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} )
inherit eutils multilib python-any-r1 readme.gentoo systemd udev user
DESCRIPTION="Bluetooth Tools and System Daemons for Linux"
HOMEPAGE="http://www.bluez.org"
SRC_URI="mirror://kernel/linux/bluetooth/${P}.tar.xz"
LICENSE="GPL-2+ LGPL-2.1+"
SLOT="0/3"
KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86"
IUSE="cups debug +obex +readline selinux systemd test +udev"
REQUIRED_USE="test? ( ${PYTHON_REQUIRED_USE} )"
RDEPEND="
>=dev-libs/glib-2.28:2
>=sys-apps/dbus-1.6:=
>=sys-apps/hwids-20121202.2
cups? ( net-print/cups:= )
obex? ( dev-libs/libical )
readline? ( sys-libs/readline:= )
selinux? ( sec-policy/selinux-bluetooth )
systemd? ( sys-apps/systemd )
udev? ( >=virtual/udev-171 )
"
DEPEND="${RDEPEND}
virtual/pkgconfig
test? (
${PYTHON_DEPS}
>=dev-python/dbus-python-1
dev-python/pygobject:2
dev-python/pygobject:3
)
"
DOC_CONTENTS="
If you want to use rfcomm as a normal user, you need to add the user
to the uucp group.
"
pkg_setup() {
enewgroup plugdev
use test && python-any-r1_pkg_setup
if ! use udev; then
ewarn
ewarn "You are installing ${PN} with USE=-udev. This means various bluetooth"
ewarn "devices and adapters from Apple, Dell, Logitech etc. will not work,"
ewarn "and hid2hci will not be available."
ewarn
fi
}
src_prepare() {
# Use static group "plugdev" if there is no ConsoleKit (or systemd logind)
epatch "${FILESDIR}"/bluez-plugdev.patch
# Fedora patches
# http://www.spinics.net/lists/linux-bluetooth/msg38490.html
epatch "${FILESDIR}"/0001-Allow-using-obexd-without-systemd-in-the-user-sessio.patch
# http://www.spinics.net/lists/linux-bluetooth/msg40136.html
epatch "${FILESDIR}"/0001-obex-Use-GLib-helper-function-to-manipulate-paths.patch
# http://www.spinics.net/lists/linux-bluetooth/msg41264.html
epatch "${FILESDIR}"/0002-autopair-Don-t-handle-the-iCade.patch
# ???
epatch "${FILESDIR}"/0004-agent-Assert-possible-infinite-loop.patch
# Ubuntu workaround for bug #501120
epatch "${FILESDIR}"/0001-work-around-Logitech-diNovo-Edge-keyboard-firmware-i.patch
if use cups; then
sed -i \
-e "s:cupsdir = \$(libdir)/cups:cupsdir = `cups-config --serverbin`:" \
Makefile.{in,tools} || die
fi
}
src_configure() {
# readline is automagic when client is enabled
# --enable-client always needs readline, bug #504038
export ac_cv_header_readline_readline_h=$(usex readline)
# Missing flags: experimental (sap, nfc, ...)
econf \
--localstatedir=/var \
--disable-android \
--enable-experimental \
--enable-optimization \
$(use_enable debug) \
--enable-pie \
--enable-threads \
--enable-library \
$(use_enable test) \
--enable-tools \
--enable-monitor \
$(use_enable cups) \
$(use_enable obex) \
$(use_enable readline client) \
$(use_enable systemd) \
$(systemd_with_unitdir) \
$(use_enable udev) \
$(use_enable udev sixaxis)
}
src_install() {
default
prune_libtool_files --modules
keepdir /var/lib/bluetooth
# Unittests are not that useful once installed
if use test ; then
rm -r "${ED}"/usr/$(get_libdir)/bluez/test || die
fi
insinto /etc/bluetooth
local d
for d in input network proximity; do
doins profiles/${d}/${d}.conf
done
doins src/main.conf
doins src/bluetooth.conf
insinto /usr/share/dbus-1/system-services
doins src/org.bluez.service
newinitd "${FILESDIR}"/bluetooth-init.d-r3 bluetooth
readme.gentoo_create_doc
}
pkg_postinst() {
readme.gentoo_print_elog
use udev && udev_reload
has_version net-dialup/ppp || elog "To use dial up networking you must install net-dialup/ppp."
if ! has_version sys-auth/consolekit && ! has_version sys-apps/systemd; then
elog "Since you don't have sys-auth/consolekit neither sys-apps/systemd, you will only"
elog "be able to run bluetooth clients as root. If you want to be able to run bluetooth clientes as"
elog "a regular user, you need to enable the consolekit use flag for this package or"
elog "to add the user to the plugdev group."
fi
}
reply other threads:[~2014-04-17 6:56 UTC|newest]
Thread overview: [no followups] expand[flat|nested] mbox.gz Atom feed
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20140417065639.BC0072004B@flycatcher.gentoo.org \
--to=pacho@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox