[gentoo-commits] gentoo-x86 commit in x11-misc/redshift: ChangeLog redshift-1.9.ebuild

[gentoo-commits] gentoo-x86 commit in x11-misc/redshift: ChangeLog redshift-1.9.ebuild

[Sebastian Pipping (sping)]

sping       14/04/13 15:09:40

  Modified:             ChangeLog
  Added:                redshift-1.9.ebuild
  Log:
  x11-misc/redshift: 1.9 (bug #507062)
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0x401A1600)

Revision  Changes    Path
1.22                 x11-misc/redshift/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/redshift/ChangeLog?rev=1.22&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/redshift/ChangeLog?rev=1.22&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/redshift/ChangeLog?r1=1.21&r2=1.22

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/redshift/ChangeLog,v
retrieving revision 1.21
retrieving revision 1.22
diff -u -r1.21 -r1.22
--- ChangeLog	21 Jan 2014 22:45:34 -0000	1.21
+++ ChangeLog	13 Apr 2014 15:09:40 -0000	1.22
@@ -1,6 +1,11 @@
 # ChangeLog for x11-misc/redshift
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/redshift/ChangeLog,v 1.21 2014/01/21 22:45:34 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/redshift/ChangeLog,v 1.22 2014/04/13 15:09:40 sping Exp $
+
+*redshift-1.9 (13 Apr 2014)
+
+  13 Apr 2014; Sebastian Pipping <sping@gentoo.org> +redshift-1.9.ebuild:
+  Bump to 1.9 (bug #507062)
 
   21 Jan 2014; Gilles Dartiguelongue <eva@gentoo.org> redshift-1.7.ebuild,
   redshift-1.7-r1.ebuild, redshift-1.8.ebuild:



1.1                  x11-misc/redshift/redshift-1.9.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/redshift/redshift-1.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/redshift/redshift-1.9.ebuild?rev=1.1&content-type=text/plain

Index: redshift-1.9.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/redshift/redshift-1.9.ebuild,v 1.1 2014/04/13 15:09:40 sping Exp $

EAPI=5
PYTHON_COMPAT=( python{3_2,3_3} )

inherit autotools eutils gnome2-utils python-r1

DESCRIPTION="A screen color temperature adjusting software"
HOMEPAGE="http://jonls.dk/redshift/"
SRC_URI="https://github.com/jonls/redshift/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="geoclue gtk nls"

COMMON_DEPEND=">=x11-libs/libX11-1.4
	x11-libs/libXxf86vm
	x11-libs/libxcb
	x11-libs/libdrm
	geoclue? ( app-misc/geoclue:0 dev-libs/glib:2 )
	gtk? ( ${PYTHON_DEPS} )"
RDEPEND="${COMMON_DEPEND}
	gtk? ( dev-python/pygobject[${PYTHON_USEDEP}]
		dev-python/pyxdg[${PYTHON_USEDEP}] )"
DEPEND="${COMMON_DEPEND}
	nls? ( sys-devel/gettext )"

src_prepare() {
	epatch_user
	eautoreconf
}

src_configure() {
	python_export_best

	econf \
		--disable-silent-rules \
		$(use_enable nls) \
		--enable-drm \
		--enable-randr \
		--enable-vidmode \
		--disable-wingdi \
		$(use_enable geoclue) \
		$(use_enable gtk gui) \
		--disable-ubuntu
}

_impl_specific_src_install() {
	emake DESTDIR="${D}" pythondir="$(python_get_sitedir)" \
			-C src/redshift-gtk install
}

src_install() {
	emake DESTDIR="${D}" UPDATE_ICON_CACHE=/bin/true install

	if use gtk; then
		python_foreach_impl _impl_specific_src_install
		python_replicate_script "${D}"/usr/bin/redshift-gtk
		dosym redshift-gtk /usr/bin/gtk-redshift
	fi
}

pkg_preinst() {
	use gtk && gnome2_icon_savelist
}

pkg_postinst() {
	use gtk && gnome2_icon_cache_update
}

pkg_postrm() {
	use gtk && gnome2_icon_cache_update
}