[gentoo-commits] gentoo-x86 commit in sys-fs/mdadm: mdadm-3.3-r3.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in sys-fs/mdadm: mdadm-3.3-r3.ebuild ChangeLog

[Pacho Ramos (pacho)]

pacho       14/04/13 08:42:22

  Modified:             ChangeLog
  Added:                mdadm-3.3-r3.ebuild
  Log:
  Fix unit file following policy and solving bug #507396 by Szymon Jaranowski
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.176                sys-fs/mdadm/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/mdadm/ChangeLog?rev=1.176&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/mdadm/ChangeLog?rev=1.176&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/mdadm/ChangeLog?r1=1.175&r2=1.176

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-fs/mdadm/ChangeLog,v
retrieving revision 1.175
retrieving revision 1.176
diff -u -r1.175 -r1.176
--- ChangeLog	7 Jan 2014 10:11:58 -0000	1.175
+++ ChangeLog	13 Apr 2014 08:42:21 -0000	1.176
@@ -1,6 +1,12 @@
 # ChangeLog for sys-fs/mdadm
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/mdadm/ChangeLog,v 1.175 2014/01/07 10:11:58 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/mdadm/ChangeLog,v 1.176 2014/04/13 08:42:21 pacho Exp $
+
+*mdadm-3.3-r3 (13 Apr 2014)
+
+  13 Apr 2014; Pacho Ramos <pacho@gentoo.org> +files/mdadm.service-r1,
+  +mdadm-3.3-r3.ebuild:
+  Fix unit file following policy and solving bug #507396 by Szymon Jaranowski
 
   07 Jan 2014; Lars Wendler <polynomial-c@gentoo.org> -mdadm-3.1.4.ebuild,
   -mdadm-3.1.5.ebuild, -mdadm-3.2.3-r2.ebuild, -mdadm-3.2.5-r1.ebuild,



1.1                  sys-fs/mdadm/mdadm-3.3-r3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/mdadm/mdadm-3.3-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/mdadm/mdadm-3.3-r3.ebuild?rev=1.1&content-type=text/plain

Index: mdadm-3.3-r3.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/mdadm/mdadm-3.3-r3.ebuild,v 1.1 2014/04/13 08:42:21 pacho Exp $

EAPI="4"
inherit multilib flag-o-matic systemd toolchain-funcs

DESCRIPTION="A useful tool for running RAID systems - it can be used as a replacement for the raidtools"
HOMEPAGE="http://neil.brown.name/blog/mdadm"
DEB_PR=2
SRC_URI="mirror://kernel/linux/utils/raid/mdadm/${P}.tar.xz
		mirror://debian/pool/main/m/mdadm/${PN}_${PV}-${DEB_PR}.debian.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
IUSE="static"

DEPEND="virtual/pkgconfig
	app-arch/xz-utils"
RDEPEND=">=sys-apps/util-linux-2.16"

# The tests edit values in /proc and run tests on software raid devices.
# Thus, they shouldn't be run on systems with active software RAID devices.
RESTRICT="test"

mdadm_emake() {
	emake \
		PKG_CONFIG="$(tc-getPKG_CONFIG)" \
		CC="$(tc-getCC)" \
		CWFLAGS="-Wall" \
		CXFLAGS="${CFLAGS}" \
		MAP_DIR=/run/mdadm \
		"$@"
}

src_compile() {
	use static && append-ldflags -static
	mdadm_emake all mdassemble
}

src_test() {
	mdadm_emake test

	sh ./test || die
}

src_install() {
	emake \
		DESTDIR="${D}" \
		SYSTEMD_DIR=$(systemd_get_unitdir) \
		install install-systemd
	into /
	dosbin mdassemble
	dodoc ChangeLog INSTALL TODO README* ANNOUNCE-${PV}

	insinto /etc
	newins mdadm.conf-example mdadm.conf
	newinitd "${FILESDIR}"/mdadm.rc mdadm
	newconfd "${FILESDIR}"/mdadm.confd mdadm
	newinitd "${FILESDIR}"/mdraid.rc mdraid
	newconfd "${FILESDIR}"/mdraid.confd mdraid
	systemd_newunit "${FILESDIR}"/mdadm.service-r1 mdadm.service

	# From the Debian patchset
	into /usr
	dodoc "${WORKDIR}/debian/README.checkarray"
	dosbin "${WORKDIR}/debian/checkarray"

	insinto /etc/cron.d
	newins "${WORKDIR}"/debian/mdadm.cron.d mdadm
	sed -i \
		-e 's:/usr/share/mdadm/checkarray:/usr/sbin/checkarray:g' \
		-e 's: root : :' \
		"${ED}"/etc/cron.d/mdadm || die
}

pkg_postinst() {
	if ! systemd_is_booted; then
		if [[ -z ${REPLACING_VERSIONS} ]] ; then
			# Only inform people the first time they install.
			elog "If you're not relying on kernel auto-detect of your RAID"
			elog "devices, you need to add 'mdraid' to your 'boot' runlevel:"
			elog "	rc-update add mdraid boot"
		fi
	fi
}