[gentoo-commits] gentoo-x86 commit in mail-mta/opensmtpd: opensmtpd-5.4.2.201403261207_p1.ebuild ChangeLog opensmtpd-5.4.2.201403051040_p1.ebuild

[gentoo-commits] gentoo-x86 commit in mail-mta/opensmtpd: opensmtpd-5.4.2.201403261207_p1.ebuild ChangeLog opensmtpd-5.4.2.201403051040_p1.ebuild

[Jason Donenfeld (zx2c4)]

zx2c4       14/04/10 15:23:13

  Modified:             ChangeLog
  Added:                opensmtpd-5.4.2.201403261207_p1.ebuild
  Removed:              opensmtpd-5.4.2.201403051040_p1.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key A5DE03AE)

Revision  Changes    Path
1.53                 mail-mta/opensmtpd/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-mta/opensmtpd/ChangeLog?rev=1.53&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-mta/opensmtpd/ChangeLog?rev=1.53&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-mta/opensmtpd/ChangeLog?r1=1.52&r2=1.53

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-mta/opensmtpd/ChangeLog,v
retrieving revision 1.52
retrieving revision 1.53
diff -u -r1.52 -r1.53
--- ChangeLog	6 Mar 2014 06:22:43 -0000	1.52
+++ ChangeLog	10 Apr 2014 15:23:13 -0000	1.53
@@ -1,6 +1,13 @@
 # ChangeLog for mail-mta/opensmtpd
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-mta/opensmtpd/ChangeLog,v 1.52 2014/03/06 06:22:43 zx2c4 Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-mta/opensmtpd/ChangeLog,v 1.53 2014/04/10 15:23:13 zx2c4 Exp $
+
+*opensmtpd-5.4.2.201403261207_p1 (10 Apr 2014)
+
+  10 Apr 2014; Jason A. Donenfeld <zx2c4@gentoo.org>
+  +opensmtpd-5.4.2.201403261207_p1.ebuild,
+  -opensmtpd-5.4.2.201403051040_p1.ebuild:
+  Version bump.
 
 *opensmtpd-5.4.2.201403051040_p1 (06 Mar 2014)
 



1.1                  mail-mta/opensmtpd/opensmtpd-5.4.2.201403261207_p1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-mta/opensmtpd/opensmtpd-5.4.2.201403261207_p1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-mta/opensmtpd/opensmtpd-5.4.2.201403261207_p1.ebuild?rev=1.1&content-type=text/plain

Index: opensmtpd-5.4.2.201403261207_p1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-mta/opensmtpd/opensmtpd-5.4.2.201403261207_p1.ebuild,v 1.1 2014/04/10 15:23:13 zx2c4 Exp $

EAPI=5

inherit multilib user flag-o-matic eutils pam toolchain-funcs autotools systemd versionator

DESCRIPTION="Lightweight but featured SMTP daemon from OpenBSD"
HOMEPAGE="http://www.opensmtpd.org/"
MY_P="${P}"
if [ $(get_last_version_component_index) -eq 4 ]; then
	MY_P="${PN}-$(get_version_component_range 4-)"
fi
SRC_URI="http://www.opensmtpd.org/archives/${MY_P/_}.tar.gz"

LICENSE="ISC BSD BSD-1 BSD-2 BSD-4"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="pam sqlite +mta"

DEPEND="dev-libs/openssl
		sys-libs/zlib
		pam? ( virtual/pam )
		sys-libs/db
		sqlite? ( dev-db/sqlite:3 )
		dev-libs/libevent
		app-misc/ca-certificates
		!mail-mta/courier
		!mail-mta/esmtp
		!mail-mta/exim
		!mail-mta/mini-qmail
		!mail-mta/msmtp[mta]
		!mail-mta/netqmail
		!mail-mta/nullmailer
		!mail-mta/postfix
		!mail-mta/qmail-ldap
		!mail-mta/sendmail
		!mail-mta/ssmtp[mta]
"
RDEPEND="${DEPEND}"

S=${WORKDIR}/${MY_P/_}

src_prepare() {
	epatch_user
	eautoreconf
}

src_configure() {
	tc-export AR
	AR="$(which "$AR")" econf \
		--with-privsep-user=smtpd \
		--with-queue-user=smtpq \
		--with-privsep-path=/var/empty \
		--with-sock-dir=/var/run \
		--sysconfdir=/etc/opensmtpd \
		--with-ca-file=/etc/ssl/certs/ca-certificates.crt \
		$(use_with sqlite experimental-sqlite) \
		$(use_with pam)
}

src_install() {
	default
	newinitd "${FILESDIR}"/smtpd.initd smtpd
	systemd_dounit "${FILESDIR}"/smtpd.{service,socket}
	use pam && newpamd "${FILESDIR}"/smtpd.pam smtpd
	if use mta ; then
		dodir /usr/sbin
		dosym /usr/sbin/smtpctl /usr/sbin/sendmail
		dosym /usr/sbin/smtpctl /usr/bin/sendmail
		dosym /usr/sbin/smtpctl /usr/$(get_libdir)/sendmail
	fi
}

pkg_preinst() {
	enewgroup smtpd 25
	enewuser smtpd 25 -1 /var/empty smtpd
	enewgroup smtpq 252
	enewuser smtpq 252 -1 /var/empty smtpq
}