[gentoo-commits] gentoo-x86 commit in net-misc/rygel: ChangeLog rygel-0.22.0.ebuild rygel-0.18.4.ebuild rygel-0.20.0.ebuild

[gentoo-commits] gentoo-x86 commit in net-misc/rygel: ChangeLog rygel-0.22.0.ebuild rygel-0.18.4.ebuild rygel-0.20.0.ebuild

[Gilles Dartiguelongue (eva)]

eva         14/04/06 21:29:02

  Modified:             ChangeLog
  Added:                rygel-0.22.0.ebuild
  Removed:              rygel-0.18.4.ebuild rygel-0.20.0.ebuild
  Log:
  Version bump. Clean up old revisions.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key C6085806)

Revision  Changes    Path
1.50                 net-misc/rygel/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/rygel/ChangeLog?rev=1.50&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/rygel/ChangeLog?rev=1.50&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/rygel/ChangeLog?r1=1.49&r2=1.50

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/rygel/ChangeLog,v
retrieving revision 1.49
retrieving revision 1.50
diff -u -r1.49 -r1.50
--- ChangeLog	9 Mar 2014 12:03:56 -0000	1.49
+++ ChangeLog	6 Apr 2014 21:29:02 -0000	1.50
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/rygel
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/rygel/ChangeLog,v 1.49 2014/03/09 12:03:56 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/rygel/ChangeLog,v 1.50 2014/04/06 21:29:02 eva Exp $
+
+*rygel-0.22.0 (06 Apr 2014)
+
+  06 Apr 2014; Gilles Dartiguelongue <eva@gentoo.org> -rygel-0.18.4.ebuild,
+  -rygel-0.20.0.ebuild, +rygel-0.22.0.ebuild:
+  Version bump. Clean up old revisions.
 
   09 Mar 2014; Pacho Ramos <pacho@gentoo.org> rygel-0.20.3.ebuild:
   x86 stable, bug 499954



1.1                  net-misc/rygel/rygel-0.22.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/rygel/rygel-0.22.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/rygel/rygel-0.22.0.ebuild?rev=1.1&content-type=text/plain

Index: rygel-0.22.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/rygel/rygel-0.22.0.ebuild,v 1.1 2014/04/06 21:29:02 eva Exp $

EAPI="5"
GCONF_DEBUG="no"

inherit gnome2 virtualx

DESCRIPTION="Rygel is an open source UPnP/DLNA MediaServer"
HOMEPAGE="http://live.gnome.org/Rygel"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="X nls +sqlite tracker test transcode"

# The deps for tracker? and transcode? are just the earliest available
# version at the time of writing this ebuild
RDEPEND="
	>=dev-libs/glib-2.34:2
	>=dev-libs/libgee-0.8:0.8
	>=dev-libs/libxml2-2.7:2
	>=media-libs/gupnp-dlna-0.9.4:2.0
	media-libs/gstreamer:1.0
	media-libs/gst-plugins-base:1.0
	media-plugins/gst-plugins-soup:1.0
	>=net-libs/gssdp-0.13
	>=net-libs/gupnp-0.19
	>=net-libs/gupnp-av-0.12.4
	>=net-libs/libsoup-2.42:2.4
	>=sys-apps/util-linux-2.20
	x11-misc/shared-mime-info
	sqlite? (
		>=dev-db/sqlite-3.5:3
		dev-libs/libunistring
	)
	tracker? ( >=app-misc/tracker-0.16:= )
	transcode? (
		media-libs/gst-plugins-bad:1.0
		media-plugins/gst-plugins-twolame:1.0
		media-plugins/gst-plugins-libav:1.0
	)
	X? ( >=x11-libs/gtk+-3:3 )
"
DEPEND="${RDEPEND}
	dev-util/gtk-doc-am
	>=dev-util/intltool-0.40
	sys-devel/gettext
	virtual/pkgconfig
"
# Maintainer only
#	>=dev-lang/vala-0.22
#   dev-libs/libxslt

src_prepare() {
	# runs gst-plugins-scanner on run with triggers sandbox violation
	# trying to open dri
	sed -e 's/rygel-media-engine-test$(EXEEXT)//' \
		-e 's/rygel-playbin-renderer-test$(EXEEXT)//' \
		-i tests/Makefile.in || die

	gnome2_src_prepare
}

src_configure() {
	# We defined xsltproc because man pages are provided by upstream
	# and we do not want to regenerate them automagically.
	gnome2_src_configure \
		XSLTPROC=$(type -P false) \
		--enable-gst-launch-plugin \
		--enable-mediathek-plugin \
		--with-media-engine=gstreamer \
		$(use_enable nls) \
		$(use_enable sqlite media-export-plugin) \
		$(use_enable test tests) \
		$(use_enable tracker tracker-plugin) \
		$(use_with X ui)
}

src_install() {
	gnome2_src_install
	# Autostart file is not placed correctly, bug #402745
	insinto /etc/xdg/autostart
	doins "${D}"/usr/share/applications/rygel.desktop
	rm "${D}"/usr/share/applications/rygel.desktop
}