[gentoo-commits] gentoo-x86 commit in app-editors/mg: ChangeLog mg-20140406.ebuild

[gentoo-commits] gentoo-x86 commit in app-editors/mg: ChangeLog mg-20140406.ebuild

[Ulrich Mueller (ulm)]

ulm         14/04/06 20:51:44

  Modified:             ChangeLog
  Added:                mg-20140406.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 9433907D693FB5B8!)

Revision  Changes    Path
1.76                 app-editors/mg/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/mg/ChangeLog?rev=1.76&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/mg/ChangeLog?rev=1.76&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/mg/ChangeLog?r1=1.75&r2=1.76

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/mg/ChangeLog,v
retrieving revision 1.75
retrieving revision 1.76
diff -u -r1.75 -r1.76
--- ChangeLog	22 Mar 2014 23:05:38 -0000	1.75
+++ ChangeLog	6 Apr 2014 20:51:44 -0000	1.76
@@ -1,6 +1,11 @@
 # ChangeLog for app-editors/mg
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/mg/ChangeLog,v 1.75 2014/03/22 23:05:38 nimiux Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/mg/ChangeLog,v 1.76 2014/04/06 20:51:44 ulm Exp $
+
+*mg-20140406 (06 Apr 2014)
+
+  06 Apr 2014; Ulrich Müller <ulm@gentoo.org> +mg-20140406.ebuild:
+  Version bump.
 
   22 Mar 2014; Chema Alonso <nimiux@gentoo.org> mg-20140306.ebuild:
   Stable for amd64 wrt bug #504870



1.1                  app-editors/mg/mg-20140406.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/mg/mg-20140406.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/mg/mg-20140406.ebuild?rev=1.1&content-type=text/plain

Index: mg-20140406.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/mg/mg-20140406.ebuild,v 1.1 2014/04/06 20:51:44 ulm Exp $

EAPI=5

inherit eutils toolchain-funcs

DESCRIPTION="MicroGnuEmacs, a port from the BSDs"
HOMEPAGE="http://homepage.boetes.org/software/mg/"
SRC_URI="http://homepage.boetes.org/software/mg/${P}.tar.gz"

LICENSE="public-domain"
SLOT="0"
KEYWORDS="~amd64 ~arm ~hppa ~x86 ~amd64-fbsd ~x86-fbsd"
IUSE="livecd"

RDEPEND="sys-libs/ncurses
	!elibc_FreeBSD? ( dev-libs/libbsd )"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

src_prepare() {
	epatch_user

	# remove OpenBSD specific easter egg
	sed -i -e 's/theo\.o//' GNUmakefile || die
	sed -i -e '/theo_init/d' main.c || die

	# fix path to tutorial in man page
	sed -i -e "s:doc/mg/:doc/${PF}/:" mg.1 || die
}

src_compile() {
	emake CC="$(tc-getCC)" \
		CFLAGS="${CFLAGS}" \
		CURSES_LIBS="$("$(tc-getPKG_CONFIG)" --libs ncurses)"
}

src_install()  {
	einstall
	dodoc README tutorial
	# don't compress the tutorial, otherwise mg cannot open it
	docompress -x /usr/share/doc/${PF}/tutorial
}

pkg_postinst() {
	if use livecd; then
		[[ -e ${EROOT}/usr/bin/emacs ]] || ln -s mg "${EROOT}"/usr/bin/emacs
	fi
}