[gentoo-commits] gentoo-x86 commit in media-video/kmplayer: kmplayer-0.11.3d-r3.ebuild kmplayer-0.11.3d-r2.ebuild

[gentoo-commits] gentoo-x86 commit in media-video/kmplayer: kmplayer-0.11.3d-r3.ebuild kmplayer-0.11.3d-r2.ebuild

[Johannes Huber (johu)]

johu        14/04/04 11:10:56

  Added:                kmplayer-0.11.3d-r3.ebuild
  Removed:              kmplayer-0.11.3d-r2.ebuild
  Log:
  Revision bump fixes location of config generation for USE npp by Arfrever Frehtes Taifersar Arahesis <arfrever.fta@gmail.com>, bug #505356. Update DESCRIPTION. Remove useflag handbook which is handled by kde4-base eclass. Add missing DEPEND on kde-base/kreadconfig. Remove DOCS array, which defines standard doc files. Remove useless post install message which provides a link to a doc contains the info handled by ebuild itself.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key F3CFD2BD)

Revision  Changes    Path
1.1                  media-video/kmplayer/kmplayer-0.11.3d-r3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/kmplayer/kmplayer-0.11.3d-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/kmplayer/kmplayer-0.11.3d-r3.ebuild?rev=1.1&content-type=text/plain

Index: kmplayer-0.11.3d-r3.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/kmplayer/kmplayer-0.11.3d-r3.ebuild,v 1.1 2014/04/04 11:10:56 johu Exp $

EAPI=5

KDE_LINGUAS="bg bs ca ca@valencia cs da de el en_GB eo es et fr ga gl hr hu it
ja km ku lt lv mai nb nds nl nn pl pt pt_BR ro ru sk sr sr@latin sv th tr ug uk
zh_CN zh_TW"
KDE_HANDBOOK="optional"
inherit kde4-base

DESCRIPTION="Video player plugin for Konqueror and basic MPlayer/Xine/ffmpeg/ffserver/VDR frontend"
HOMEPAGE="http://kmplayer.kde.org/"
SRC_URI="http://kmplayer.kde.org/pkgs/${P}.tar.bz2"

LICENSE="GPL-2 FDL-1.2 LGPL-2.1"
SLOT="4"
KEYWORDS="~amd64 ~x86"
IUSE="cairo debug expat npp"

DEPEND="
	media-libs/phonon
	x11-libs/libX11
	expat? ( >=dev-libs/expat-2.0.1 )
	cairo? (
		x11-libs/cairo
		x11-libs/pango
	)
	npp? (
		dev-libs/dbus-glib
		$(add_kdebase_dep kreadconfig)
		>=x11-libs/gtk+-2.10.14:2
		www-plugins/adobe-flash
	)
"
RDEPEND="${DEPEND}
	media-video/mplayer
"

src_prepare() {
	use npp && epatch "${FILESDIR}/${PN}-flash.patch"
	sed -e '/add_subdirectory(icons)/d' \
		-i CMakeLists.txt || die

	kde4-base_src_prepare
}

src_configure() {
	local mycmakeargs=(
		$(cmake-utils_use cairo KMPLAYER_BUILT_WITH_CAIRO)
		$(cmake-utils_use expat KMPLAYER_BUILT_WITH_EXPAT)
		$(cmake-utils_use npp KMPLAYER_BUILT_WITH_NPP)
	)

	kde4-base_src_configure
}

src_install() {
	kde4-base_src_install

	if use npp; then
		kwriteconfig --file "${ED}/usr/share/config/kmplayerrc" --group "application/x-shockwave-flash" --key player npp
		kwriteconfig --file "${ED}/usr/share/config/kmplayerrc" --group "application/x-shockwave-flash" --key plugin /usr/lib/nsbrowser/plugins/libflashplayer.so
	fi
}