[gentoo-commits] gentoo-x86 commit in app-misc/sphinx: sphinx-2.1.7.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in app-misc/sphinx: sphinx-2.1.7.ebuild ChangeLog

[Hans de Graaff (graaff)]

graaff      14/04/02 05:53:11

  Modified:             ChangeLog
  Added:                sphinx-2.1.7.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0x8883FA56A308A8D7!)

Revision  Changes    Path
1.76                 app-misc/sphinx/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/sphinx/ChangeLog?rev=1.76&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/sphinx/ChangeLog?rev=1.76&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/sphinx/ChangeLog?r1=1.75&r2=1.76

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/sphinx/ChangeLog,v
retrieving revision 1.75
retrieving revision 1.76
diff -u -r1.75 -r1.76
--- ChangeLog	4 Mar 2014 20:20:17 -0000	1.75
+++ ChangeLog	2 Apr 2014 05:53:11 -0000	1.76
@@ -1,6 +1,11 @@
 # ChangeLog for app-misc/sphinx
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/sphinx/ChangeLog,v 1.75 2014/03/04 20:20:17 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/sphinx/ChangeLog,v 1.76 2014/04/02 05:53:11 graaff Exp $
+
+*sphinx-2.1.7 (02 Apr 2014)
+
+  02 Apr 2014; Hans de Graaff <graaff@gentoo.org> +sphinx-2.1.7.ebuild:
+  Version bump.
 
   04 Mar 2014; Agostino Sarubbo <ago@gentoo.org> sphinx-2.0.10.ebuild:
   Stable for x86, wrt bug #502496



1.1                  app-misc/sphinx/sphinx-2.1.7.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/sphinx/sphinx-2.1.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/sphinx/sphinx-2.1.7.ebuild?rev=1.1&content-type=text/plain

Index: sphinx-2.1.7.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/sphinx/sphinx-2.1.7.ebuild,v 1.1 2014/04/02 05:53:11 graaff Exp $

EAPI=5
inherit eutils autotools toolchain-funcs

#MY_P=${P/_/-}
MY_P=${P}-release

DESCRIPTION="Full-text search engine with support for MySQL and PostgreSQL"
HOMEPAGE="http://www.sphinxsearch.com/"
SRC_URI="http://sphinxsearch.com/files/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~ppc-macos ~x86-macos ~sparc-solaris ~sparc64-solaris"
IUSE="debug id64 mysql odbc postgres stemmer syslog test xml"

RDEPEND="mysql? ( virtual/mysql )
	postgres? ( dev-db/postgresql-base )
	odbc? ( dev-db/unixODBC )
	stemmer? ( dev-libs/snowball-stemmer )
	xml? ( dev-libs/expat )
	virtual/libiconv"

S=${WORKDIR}/${MY_P}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-2.0.1_beta-darwin8.patch

	# drop nasty hardcoded search path breaking Prefix
	# We patch configure directly since otherwise we need to run
	# eautoreconf twice and that causes problems, bug 425380
	sed -i -e 's/\/usr\/local\//\/someplace\/nonexisting\//g' configure || die

	# Fix QA compilation warnings.
	sed -i -e '19i#include <string.h>' api/libsphinxclient/test.c || die

	pushd api/libsphinxclient || die
	eautoreconf
	popd || die
}

src_configure() {
	# fix libiconv detection
	use !elibc_glibc && export ac_cv_search_iconv=-liconv

	econf \
		--sysconfdir="${EPREFIX}/etc/${PN}" \
		$(use_enable id64) \
		$(use_with debug) \
		$(use_with mysql) \
		$(use_with odbc unixodbc) \
		$(use_with postgres pgsql) \
		$(use_with stemmer libstemmer) \
		$(use_with syslog syslog) \
		$(use_with xml libexpat )

	cd api/libsphinxclient || die
	econf STRIP=:
}

src_compile() {
	emake AR="$(tc-getAR)" || die "emake failed"

	emake -j 1 -C api/libsphinxclient || die "emake libsphinxclient failed"
}

src_test() {
	elog "Tests require access to a live MySQL database and may require configuration."
	elog "You will find them in /usr/share/${PN}/test and they require dev-lang/php"
}

src_install() {
	emake DESTDIR="${D}" install || die "install failed"
	emake DESTDIR="${D}" -C api/libsphinxclient install || die "install libsphinxclient failed"

	dodoc doc/*

	dodir /var/lib/sphinx
	dodir /var/log/sphinx

	newinitd "${FILESDIR}"/searchd.rc searchd

	if use test; then
		insinto /usr/share/${PN}
		doins -r test
	fi
}