[gentoo-commits] gentoo-x86 commit in net-libs/polarssl: metadata.xml ChangeLog polarssl-1.3.5.ebuild

[gentoo-commits] gentoo-x86 commit in net-libs/polarssl: metadata.xml ChangeLog polarssl-1.3.5.ebuild

[Julian Ospald (hasufell)]

hasufell    14/03/27 19:57:00

  Modified:             metadata.xml ChangeLog
  Added:                polarssl-1.3.5.ebuild
  Log:
  version bump, add SUBSLOT
  
  (Portage version: 2.2.9-r1/cvs/Linux x86_64, signed Manifest commit with key BDEED020)

Revision  Changes    Path
1.5                  net-libs/polarssl/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/polarssl/metadata.xml?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/polarssl/metadata.xml?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/polarssl/metadata.xml?r1=1.4&r2=1.5

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/polarssl/metadata.xml,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- metadata.xml	11 Mar 2014 12:31:32 -0000	1.4
+++ metadata.xml	27 Mar 2014 19:56:59 -0000	1.5
@@ -16,5 +16,6 @@
 			Warning: the HAVEGE random generator is not suitable for
 			virtualized environments
 		</flag>
+		<flag name='programs'>Build PolarSSL programs</flag>
 	</use>
 </pkgmetadata>



1.70                 net-libs/polarssl/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/polarssl/ChangeLog?rev=1.70&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/polarssl/ChangeLog?rev=1.70&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/polarssl/ChangeLog?r1=1.69&r2=1.70

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/polarssl/ChangeLog,v
retrieving revision 1.69
retrieving revision 1.70
diff -u -r1.69 -r1.70
--- ChangeLog	15 Mar 2014 20:06:18 -0000	1.69
+++ ChangeLog	27 Mar 2014 19:56:59 -0000	1.70
@@ -1,6 +1,12 @@
 # ChangeLog for net-libs/polarssl
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/polarssl/ChangeLog,v 1.69 2014/03/15 20:06:18 hasufell Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/polarssl/ChangeLog,v 1.70 2014/03/27 19:56:59 hasufell Exp $
+
+*polarssl-1.3.5 (27 Mar 2014)
+
+  27 Mar 2014; Julian Ospald <hasufell@gentoo.org> +polarssl-1.3.5.ebuild,
+  metadata.xml:
+  version bump, add SUBSLOT
 
   15 Mar 2014; Julian Ospald <hasufell@gentoo.org> polarssl-1.3.4.ebuild:
   install docs



1.1                  net-libs/polarssl/polarssl-1.3.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/polarssl/polarssl-1.3.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/polarssl/polarssl-1.3.5.ebuild?rev=1.1&content-type=text/plain

Index: polarssl-1.3.5.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/polarssl/polarssl-1.3.5.ebuild,v 1.1 2014/03/27 19:57:00 hasufell Exp $

EAPI=5

inherit eutils multilib toolchain-funcs cmake-utils multilib-minimal

DESCRIPTION="Cryptographic library for embedded systems"
HOMEPAGE="http://polarssl.org/"
SRC_URI="http://polarssl.org/download/${P}-gpl.tgz"

LICENSE="GPL-2"
SLOT="0/5"
KEYWORDS="~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
IUSE="havege programs sse2 static-libs zlib"

RDEPEND="
	programs? (
		dev-libs/openssl:0
		amd64? ( abi_x86_32? (
			|| (
				dev-libs/openssl:0[abi_x86_32]
				app-emulation/emul-linux-x86-baselibs
			)
		) )
	)
	zlib? ( sys-libs/zlib[${MULTILIB_USEDEP}] )"
DEPEND="${RDEPEND}"

enable_polarssl_option() {
	local myopt="$@"
	# check that config.h syntax is the same at version bump
	sed -i \
		-e "s://#define ${myopt}:#define ${myopt}:" \
		include/polarssl/config.h || die
}

src_prepare() {
	use sse2 && enable_polarssl_option POLARSSL_HAVE_SSE2
	use zlib && enable_polarssl_option POLARSSL_ZLIB_SUPPORT
	use havege && enable_polarssl_option POLARSSL_HAVEGE_C
}

multilib_src_configure() {
	local mycmakeargs=(
		$(cmake-utils_use_enable programs PROGRAMS)
		$(cmake-utils_use_enable zlib ZLIB_SUPPORT)
		$(cmake-utils_use_use static-libs STATIC_POLARSSL_LIBRARY)
		-DUSE_SHARED_POLARSSL_LIBRARY=ON
		-DINSTALL_POLARSSL_HEADERS=ON
		-DLIB_INSTALL_DIR="/usr/$(get_libdir)"
	)

	cmake-utils_src_configure
}

multilib_src_compile() {
	cmake-utils_src_compile
}

multilib_src_test() {
	LD_LIBRARY_PATH="${LD_LIBRARY_PATH}:${BUILD_DIR}/library" cmake-utils_src_test
}

multilib_src_install() {
	cmake-utils_src_install
}

multilib_src_install_all() {
	einstalldocs

	if use programs ; then
		# avoid file collisions with sys-apps/coreutils
		local p e
		for p in "${ED%/}"/usr/bin/* ; do
			if [[ -x "${p}" && ! -d "${p}" ]] ; then
				mv "${p}" "${ED%/}"/usr/bin/polarssl_`basename "${p}"` || die
			fi
		done
		for e in aes hash pkey ssl test ; do
			docinto "${e}"
			dodoc programs/"${e}"/*.c
			dodoc programs/"${e}"/*.txt
		done
	fi
}