[gentoo-commits] gentoo-x86 commit in dev-util/plan9port: plan9port-20140306.ebuild ChangeLog plan9port-20140228.ebuild

[gentoo-commits] gentoo-x86 commit in dev-util/plan9port: plan9port-20140306.ebuild ChangeLog plan9port-20140228.ebuild

[Anthony G. Basile (blueness)]

blueness    14/03/27 12:40:16

  Modified:             ChangeLog
  Added:                plan9port-20140306.ebuild
  Removed:              plan9port-20140228.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 0xF52D4BBA)

Revision  Changes    Path
1.36                 dev-util/plan9port/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/plan9port/ChangeLog?rev=1.36&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/plan9port/ChangeLog?rev=1.36&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/plan9port/ChangeLog?r1=1.35&r2=1.36

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/plan9port/ChangeLog,v
retrieving revision 1.35
retrieving revision 1.36
diff -u -r1.35 -r1.36
--- ChangeLog	6 Mar 2014 15:17:55 -0000	1.35
+++ ChangeLog	27 Mar 2014 12:40:16 -0000	1.36
@@ -1,6 +1,12 @@
 # ChangeLog for dev-util/plan9port
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/plan9port/ChangeLog,v 1.35 2014/03/06 15:17:55 blueness Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/plan9port/ChangeLog,v 1.36 2014/03/27 12:40:16 blueness Exp $
+
+*plan9port-20140306 (27 Mar 2014)
+
+  27 Mar 2014; Anthony G. Basile <blueness@gentoo.org>
+  +plan9port-20140306.ebuild, -plan9port-20140228.ebuild:
+  Version bump
 
 *plan9port-20140304 (06 Mar 2014)
 



1.1                  dev-util/plan9port/plan9port-20140306.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/plan9port/plan9port-20140306.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/plan9port/plan9port-20140306.ebuild?rev=1.1&content-type=text/plain

Index: plan9port-20140306.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/plan9port/plan9port-20140306.ebuild,v 1.1 2014/03/27 12:40:16 blueness Exp $

EAPI="4"

inherit eutils

DESCRIPTION="Port of many Plan 9 programs and libraries"
HOMEPAGE="http://swtch.com/plan9port/"
SRC_URI="http://${PN}.googlecode.com/files/${P}.tgz"

LICENSE="9base BSD-4 MIT LGPL-2.1 BigelowHolmes"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="X"

DEPEND="X? ( x11-apps/xauth )"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${PN}"

PLAN9=/usr/lib/plan9
QA_MULTILIB_PATHS="${PLAN9}/.*/.*"

src_prepare()
{
	epatch "${FILESDIR}/${PN}-"{noexecstack,cflags,builderr}".patch"

	# Fix paths, done in place of ./INSTALL -c
	einfo "Fixing hard-coded /usr/local/plan9 paths"
	grep  --null -l -r '/usr/local/plan9' |
	xargs --null sed -i "s!/usr/local/plan9!${PLAN9}!g"
}

src_configure() {
	if ! use X; then
		echo "WSYSTYPE=nowsys" >> LOCAL.config
	fi
}

src_compile() {
	# Convert -j5 to NPROC=5 for mk
	export NPROC="$(echo "$MAKEOPTS" | sed -r -n 's/.*(^| )-j([0-9]*).*/\2/p')"

	# The INSTALL script builds mk then [re]builds everything using that
	einfo "Compiling Plan 9 from User Space can take a very long time"
	einfo "depending on the speed of your computer. Please be patient!"
	./INSTALL -b || die "Please report bugs to bugs.gentoo.org, NOT Plan9Port."
}

src_install() {
	dodir "${PLAN9}"

	# P9P's man does not handle compression
	docompress -x $PLAN9/man

	# do* plays with the executable bit, and we should not modify them
	cp -a * "${D}/${PLAN9}"

	# build the environment variables and install them in env.d
	cat > "${T}/30plan9" <<-EOF
		PLAN9="${PLAN9}"
		PATH="${PLAN9}/bin"
		ROOTPATH="${PLAN9}/bin"
		MANPATH="${PLAN9}/man"
	EOF
	doenvd "${T}/30plan9"
}

pkg_postinst() {
	elog "Plan 9 from User Space has been successfully installed into"
	elog "${PLAN9}. Your PLAN9 and PATH environment variables have"
	elog "also been appropriately set, please use env-update and"
	elog "source /etc/profile to bring that into immediate effect."
	elog
	elog "Please note that ${PLAN9}/bin has been appended to the"
	elog "*end* or your PATH to prevent conflicts. To use the Plan9"
	elog "versions of common UNIX tools, use the absolute path:"
	elog "${PLAN9}/bin or the 9 command (eg: 9 troff)"
	elog
	elog "Please report any bugs to bugs.gentoo.org, NOT Plan9Port."
}