[gentoo-commits] gentoo-x86 commit in dev-python/py-amqp: py-amqp-1.4.4.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in dev-python/py-amqp: py-amqp-1.4.4.ebuild ChangeLog

[Matt Thode (prometheanfire)]

prometheanfire    14/03/25 21:03:49

  Modified:             ChangeLog
  Added:                py-amqp-1.4.4.ebuild
  Log:
  update for bug 505484
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0x2471eb3e40ac5ac3)

Revision  Changes    Path
1.19                 dev-python/py-amqp/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/py-amqp/ChangeLog?rev=1.19&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/py-amqp/ChangeLog?rev=1.19&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/py-amqp/ChangeLog?r1=1.18&r2=1.19

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/py-amqp/ChangeLog,v
retrieving revision 1.18
retrieving revision 1.19
diff -u -r1.18 -r1.19
--- ChangeLog	25 Feb 2014 22:03:16 -0000	1.18
+++ ChangeLog	25 Mar 2014 21:03:49 -0000	1.19
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/py-amqp
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/py-amqp/ChangeLog,v 1.18 2014/02/25 22:03:16 iksaif Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/py-amqp/ChangeLog,v 1.19 2014/03/25 21:03:49 prometheanfire Exp $
+
+*py-amqp-1.4.4 (25 Mar 2014)
+
+  25 Mar 2014; Matthew Thode <prometheanfire@gentoo.org> +py-amqp-1.4.4.ebuild:
+  update for bug 505484
 
   25 Feb 2014; Corentin Chary <iksaif@gentoo.org> -py-amqp-1.0.11.ebuild,
   -py-amqp-1.0.12.ebuild, -py-amqp-1.0.9.ebuild, -py-amqp-1.3.0.ebuild,



1.1                  dev-python/py-amqp/py-amqp-1.4.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/py-amqp/py-amqp-1.4.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/py-amqp/py-amqp-1.4.4.ebuild?rev=1.1&content-type=text/plain

Index: py-amqp-1.4.4.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/py-amqp/py-amqp-1.4.4.ebuild,v 1.1 2014/03/25 21:03:49 prometheanfire Exp $

EAPI=5

PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} pypy2_0 )

inherit distutils-r1

MY_PN="amqp"
MY_P="${MY_PN}-${PV}"

DESCRIPTION="Low-level AMQP client for Python (fork of amqplib)"
HOMEPAGE="https://github.com/celery/py-amqp http://pypi.python.org/pypi/amqp/"
SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"

S="${WORKDIR}/${MY_P}"

LICENSE="LGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc examples extras test"

RDEPEND=""
DEPEND="test? ( virtual/python-unittest2[${PYTHON_USEDEP}]
				dev-python/nose[${PYTHON_USEDEP}]
				dev-python/nose-cover3[${PYTHON_USEDEP}]
				>=dev-python/coverage-3.0[${PYTHON_USEDEP}]
				dev-python/mock[${PYTHON_USEDEP}]
				doc? (	dev-python/sphinx[${PYTHON_USEDEP}]
						>=dev-python/sphinxcontrib-issuetracker-0.9[${PYTHON_USEDEP}]
				)
			)"

# Same tests from before require a socket connection
PATCHES=( "${FILESDIR}"/${PN}-1.3.3-disable_socket_tests.patch )

python_compile_all() {
	use doc && emake -C docs html
}

python_test() {
	cp -r -l funtests "${BUILD_DIR}"/lib/ || die
	cd "${BUILD_DIR}"/lib || die
	if [[ ${EPYTHON:6:1} == 3 ]]; then
		#   -n causes Python to write into hardlinked files
		2to3 --no-diffs -w funtests || die
	fi
	"${PYTHON}" funtests/run_all.py || die "Tests failed under ${EPYTHON}"
	rm -rf funtests/ || die
}

python_install_all() {
	use examples && local EXAMPLES=( demo/. )
	use doc && local HTML_DOCS=( docs/.build/html/. )
	if use extras; then
		insinto /usr/share/${PF}/extras
		doins -r extra
	fi
	distutils-r1_python_install_all
}