[gentoo-commits] gentoo-x86 commit in x11-wm/herbstluftwm: ChangeLog herbstluftwm-0.6.0.ebuild

[gentoo-commits] gentoo-x86 commit in x11-wm/herbstluftwm: ChangeLog herbstluftwm-0.6.0.ebuild

[Tim Harder (radhermit)]

radhermit    14/03/21 01:51:36

  Modified:             ChangeLog
  Added:                herbstluftwm-0.6.0.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.15                 x11-wm/herbstluftwm/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/herbstluftwm/ChangeLog?rev=1.15&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/herbstluftwm/ChangeLog?rev=1.15&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/herbstluftwm/ChangeLog?r1=1.14&r2=1.15

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/herbstluftwm/ChangeLog,v
retrieving revision 1.14
retrieving revision 1.15
diff -u -r1.14 -r1.15
--- ChangeLog	1 Jan 2014 22:54:50 -0000	1.14
+++ ChangeLog	21 Mar 2014 01:51:35 -0000	1.15
@@ -1,6 +1,11 @@
 # ChangeLog for x11-wm/herbstluftwm
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/herbstluftwm/ChangeLog,v 1.14 2014/01/01 22:54:50 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/herbstluftwm/ChangeLog,v 1.15 2014/03/21 01:51:35 radhermit Exp $
+
+*herbstluftwm-0.6.0 (21 Mar 2014)
+
+  21 Mar 2014; Tim Harder <radhermit@gentoo.org> +herbstluftwm-0.6.0.ebuild:
+  Version bump.
 
   01 Jan 2014; Tim Harder <radhermit@gentoo.org> herbstluftwm-0.5.3.ebuild,
   herbstluftwm-9999.ebuild:



1.1                  x11-wm/herbstluftwm/herbstluftwm-0.6.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/herbstluftwm/herbstluftwm-0.6.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/herbstluftwm/herbstluftwm-0.6.0.ebuild?rev=1.1&content-type=text/plain

Index: herbstluftwm-0.6.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/herbstluftwm/herbstluftwm-0.6.0.ebuild,v 1.1 2014/03/21 01:51:35 radhermit Exp $

EAPI=5
inherit toolchain-funcs bash-completion-r1

if [[ ${PV} == 9999* ]] ; then
	inherit git-r3
	EGIT_REPO_URI="git://git.cs.fau.de/hlwm"
	EXTRA_DEPEND="app-text/asciidoc"
else
	SRC_URI="http://herbstluftwm.org/tarballs/${P}.tar.gz"
	KEYWORDS="~amd64 ~x86"
	EXTRA_DEPEND=""
fi

DESCRIPTION="A manual tiling window manager for X"
HOMEPAGE="http://herbstluftwm.org"

LICENSE="BSD-2"
SLOT="0"
IUSE="examples xinerama zsh-completion"

CDEPEND=">=dev-libs/glib-2.24:2
	x11-libs/libX11
	xinerama? ( x11-libs/libXinerama )"
RDEPEND="${CDEPEND}
	app-shells/bash
	zsh-completion? ( app-shells/zsh )"
DEPEND="${CDEPEND}
	${EXTRA_DEPEND}
	virtual/pkgconfig"

src_compile() {
	emake CC="$(tc-getCC)" LD="$(tc-getCC)" COLOR=0 VERBOSE= \
		$(use xinerama || echo XINERAMAFLAGS= XINERAMALIBS= )
}

src_install() {
	dobin herbstluftwm herbstclient
	dodoc BUGS MIGRATION NEWS README

	doman doc/{herbstluftwm,herbstclient}.1

	exeinto /etc/xdg/herbstluftwm
	doexe share/{autostart,panel.sh,restartpanels.sh}

	insinto /usr/share/xsessions
	doins share/herbstluftwm.desktop

	newbashcomp share/herbstclient-completion herbstclient

	if use zsh-completion ; then
		insinto /usr/share/zsh/site-functions
		doins share/_herbstclient
	fi

	if use examples ; then
		exeinto /usr/share/doc/${PF}/examples
		doexe scripts/*.sh
		docinto examples
		dodoc scripts/README
		docompress -x /usr/share/doc/${PF}/examples
	fi
}