[gentoo-commits] gentoo-x86 commit in net-ftp/lftp: ChangeLog lftp-4.4.99.20140314.ebuild lftp-4.4.99.20140205.ebuild

[gentoo-commits] gentoo-x86 commit in net-ftp/lftp: ChangeLog lftp-4.4.99.20140314.ebuild lftp-4.4.99.20140205.ebuild

[Jeroen Roovers (jer)]

jer         14/03/14 15:18:33

  Modified:             ChangeLog
  Added:                lftp-4.4.99.20140314.ebuild
  Removed:              lftp-4.4.99.20140205.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.461                net-ftp/lftp/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/lftp/ChangeLog?rev=1.461&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/lftp/ChangeLog?rev=1.461&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/lftp/ChangeLog?r1=1.460&r2=1.461

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-ftp/lftp/ChangeLog,v
retrieving revision 1.460
retrieving revision 1.461
diff -u -r1.460 -r1.461
--- ChangeLog	14 Mar 2014 10:05:15 -0000	1.460
+++ ChangeLog	14 Mar 2014 15:18:32 -0000	1.461
@@ -1,6 +1,12 @@
 # ChangeLog for net-ftp/lftp
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-ftp/lftp/ChangeLog,v 1.460 2014/03/14 10:05:15 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-ftp/lftp/ChangeLog,v 1.461 2014/03/14 15:18:32 jer Exp $
+
+*lftp-4.4.99.20140314 (14 Mar 2014)
+
+  14 Mar 2014; Jeroen Roovers <jer@gentoo.org> -lftp-4.4.99.20140205.ebuild,
+  +lftp-4.4.99.20140314.ebuild:
+  Version bump.
 
   14 Mar 2014; Agostino Sarubbo <ago@gentoo.org> lftp-4.4.15.ebuild:
   Stable for ppc64, wrt bug #503784



1.1                  net-ftp/lftp/lftp-4.4.99.20140314.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/lftp/lftp-4.4.99.20140314.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/lftp/lftp-4.4.99.20140314.ebuild?rev=1.1&content-type=text/plain

Index: lftp-4.4.99.20140314.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-ftp/lftp/lftp-4.4.99.20140314.ebuild,v 1.1 2014/03/14 15:18:32 jer Exp $

EAPI=5
inherit autotools eutils libtool

DESCRIPTION="A sophisticated ftp/sftp/http/https/torrent client and file transfer program"
HOMEPAGE="http://lftp.yar.ru/"
SRC_URI="http://${PN}.yar.ru/ftp/devel/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS=""

IUSE="convert-mozilla-cookies +gnutls nls openssl socks5 +ssl verify-file"
LFTP_LINGUAS=( cs de es fr it ja ko pl pt_BR ru zh_CN zh_HK zh_TW )
IUSE+=" ${LFTP_LINGUAS[@]/#/linguas_}"

REQUIRED_USE="
	ssl? ( ^^ ( openssl gnutls ) )
"

RDEPEND="
	>=sys-libs/ncurses-5.1
	>=sys-libs/readline-5.1
	dev-libs/expat
	sys-libs/zlib
	convert-mozilla-cookies? ( dev-perl/DBI )
	socks5? (
		>=net-proxy/dante-1.1.12
		virtual/pam
	)
	ssl? (
		gnutls? ( >=net-libs/gnutls-1.2.3 )
		openssl? ( >=dev-libs/openssl-0.9.6 )
	)
	verify-file? (
		dev-perl/string-crc32
		virtual/perl-Digest-MD5
	)
"

DEPEND="
	${RDEPEND}
	=sys-devel/libtool-2*
	nls? ( sys-devel/gettext )
	virtual/pkgconfig
"

DOCS=(
	BUGS ChangeLog FAQ FEATURES MIRRORS NEWS README README.debug-levels
	README.dnssec README.modules THANKS TODO
)

src_prepare() {
	epatch \
		"${FILESDIR}/${PN}-4.0.2.91-lafile.patch" \
		"${FILESDIR}/${PN}-4.3.5-autopoint.patch" \
		"${FILESDIR}/${PN}-4.3.8-gets.patch"
	sed -i configure.ac -e 's|^AM_CONFIG_HEADER|AC_CONFIG_HEADERS|g' || die
	eautoreconf
	elibtoolize # for Darwin bundles
}

src_configure() {
	econf \
		$(use_enable nls) \
		$(use_with gnutls) \
		$(use_with openssl openssl "${EPREFIX}"/usr) \
		$(use_with socks5 socksdante "${EPREFIX}"/usr) \
		--enable-packager-mode \
		--sysconfdir="${EPREFIX}"/etc/${PN} \
		--with-modules \
		--without-included-regex
}

src_install() {
	default
	local script
	for script in {convert-mozilla-cookies,verify-file}; do
		use ${script} || { rm "${ED}"/usr/share/${PN}/${script} || die ;}
	done
}