[gentoo-commits] gentoo-x86 commit in app-text/jabref: jabref-2.10.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in app-text/jabref: jabref-2.10.ebuild ChangeLog

[Nicolas Bock (nicolasbock)]

nicolasbock    14/03/12 13:21:44

  Modified:             ChangeLog
  Added:                jabref-2.10.ebuild
  Log:
  app-text/jabref-2.10: Version bump.
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key AC91CA52)

Revision  Changes    Path
1.96                 app-text/jabref/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/jabref/ChangeLog?rev=1.96&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/jabref/ChangeLog?rev=1.96&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/jabref/ChangeLog?r1=1.95&r2=1.96

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/jabref/ChangeLog,v
retrieving revision 1.95
retrieving revision 1.96
diff -u -r1.95 -r1.96
--- ChangeLog	19 Feb 2014 17:26:28 -0000	1.95
+++ ChangeLog	12 Mar 2014 13:21:44 -0000	1.96
@@ -1,6 +1,11 @@
 # ChangeLog for app-text/jabref
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/jabref/ChangeLog,v 1.95 2014/02/19 17:26:28 nicolasbock Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/jabref/ChangeLog,v 1.96 2014/03/12 13:21:44 nicolasbock Exp $
+
+*jabref-2.10 (12 Mar 2014)
+
+  12 Mar 2014; Nicolas Bock <nicolasbock@gentoo.org> +jabref-2.10.ebuild:
+  app-text/jabref-2.10: Version bump.
 
   19 Feb 2014; Nicolas Bock <nicolasbock@gentoo.org> jabref-2.6.ebuild:
   app-text/jabref-2.6: Small fix for jdk dependence.



1.1                  app-text/jabref/jabref-2.10.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/jabref/jabref-2.10.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/jabref/jabref-2.10.ebuild?rev=1.1&content-type=text/plain

Index: jabref-2.10.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/jabref/jabref-2.10.ebuild,v 1.1 2014/03/12 13:21:44 nicolasbock Exp $

EAPI=5

JAVA_ANT_REWRITE_CLASSPATH="true"

inherit eutils java-pkg-2 java-ant-2 java-utils-2

MY_PV="${PV/_beta/b}"

DESCRIPTION="Java GUI for managing BibTeX and other bibliographies"
HOMEPAGE="http://jabref.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/JabRef-${MY_PV}-src.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="doc"

COMMON_DEP="
	dev-java/antlr:3
	dev-java/fontbox:1.7
	dev-java/jempbox:1.7
	dev-java/log4j:0
	dev-java/spin:0
	"

DEPEND="
	>=virtual/jdk-1.6
	${COMMON_DEP}"

RDEPEND="
	>=virtual/jre-1.6
	${COMMON_DEP}"

S="${WORKDIR}/${PN}-${MY_PV}"

java_prepare() {
	# Remove bundled dependencies.
	rm lib/antlr*.jar || die
	rm lib/fontbox*.jar || die
	rm lib/jempbox*.jar || die
	rm lib/spin.jar || die

	# Remove unjarlib target (do this only once we have removed all
	# bundled dependencies in lib).
	#sed -i -e 's:depends="build, unjarlib":depends="build":' build.xml
}

src_compile() {
	local EXTERNAL_JARS="antlr-3,fontbox-1.7,jempbox-1.7,spin"
	local CLASSPATH="$(java-pkg_getjars --with-dependencies ${EXTERNAL_JARS})"
	eant \
		-Dgentoo.classpath=${CLASSPATH} \
		jars \
		$(usex doc docs "")
}

src_install() {
	java-pkg_newjar build/lib/JabRef-${MY_PV}.jar

	use doc && java-pkg_dojavadoc build/docs/API
	dodoc src/txt/README

	java-pkg_dolauncher ${PN} --main net.sf.jabref.JabRef
	newicon src/images/JabRef-icon-48.png JabRef-icon.png
	make_desktop_entry ${PN} JabRef JabRef-icon Office
}