[gentoo-commits] gentoo-x86 commit in net-libs/xrootd: xrootd-3.3.6.ebuild ChangeLog

["Sebastien Fabbro (bicatali)" <bicatali@gentoo.org>]

bicatali    14/03/10 18:00:43

  Modified:             ChangeLog
  Added:                xrootd-3.3.6.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0x13CB1360)

Revision  Changes    Path
1.17                 net-libs/xrootd/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/xrootd/ChangeLog?rev=1.17&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/xrootd/ChangeLog?rev=1.17&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/xrootd/ChangeLog?r1=1.16&r2=1.17

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/xrootd/ChangeLog,v
retrieving revision 1.16
retrieving revision 1.17
diff -u -r1.16 -r1.17
--- ChangeLog	20 Nov 2013 03:10:18 -0000	1.16
+++ ChangeLog	10 Mar 2014 18:00:43 -0000	1.17
@@ -1,6 +1,11 @@
 # ChangeLog for net-libs/xrootd
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/xrootd/ChangeLog,v 1.16 2013/11/20 03:10:18 patrick Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/xrootd/ChangeLog,v 1.17 2014/03/10 18:00:43 bicatali Exp $
+
+*xrootd-3.3.6 (10 Mar 2014)
+
+  10 Mar 2014; Sébastien Fabbro <bicatali@gentoo.org> +xrootd-3.3.6.ebuild:
+  Version bump
 
   20 Nov 2013; Patrick Lauer <patrick@gentoo.org> xrootd-3.3.4.ebuild:
   Whitespace



1.1                  net-libs/xrootd/xrootd-3.3.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/xrootd/xrootd-3.3.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/xrootd/xrootd-3.3.6.ebuild?rev=1.1&content-type=text/plain

Index: xrootd-3.3.6.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/xrootd/xrootd-3.3.6.ebuild,v 1.1 2014/03/10 18:00:43 bicatali Exp $

EAPI=5

inherit cmake-utils eutils user multilib

DURI="http://xrootd.slac.stanford.edu/doc/prod"

DESCRIPTION="Extended ROOT remote file server"
HOMEPAGE="http://xrootd.org/"
SRC_URI="${HOMEPAGE}/download/v${PV}/${P}.tar.gz"

LICENSE="LGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="doc fuse kerberos perl readline ssl test"

RDEPEND="
	!<sci-physics/root-5.32[xrootd]
	sys-libs/zlib:0=
	fuse? ( sys-fs/fuse )
	kerberos? ( virtual/krb5 )
	perl? (
		dev-lang/perl
		readline? ( dev-perl/Term-ReadLine-Perl )
	)
	readline? ( sys-libs/readline:0= )
	ssl? ( dev-libs/openssl:= )"
DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen[dot] )
	perl? ( dev-lang/swig )
	test? ( dev-util/cppunit )"

pkg_setup() {
	enewgroup xrootd
	enewuser xrootd -1 -1 "${EPREFIX}"/var/spool/xrootd xrootd
}


src_configure() {
	local mycmakeargs=(
		$(cmake-utils_use_enable fuse)
		$(cmake-utils_use_enable kerberos KRB5)
		$(cmake-utils_use_enable perl)
		$(cmake-utils_use_enable readline)
		$(cmake-utils_use_enable ssl CRYPTO)
		$(cmake-utils_use_enable test TESTS)
	)
	cmake-utils_src_configure
}

src_compile() {
	cmake-utils_src_compile
	use doc && doxygen Doxyfile
}

src_install() {
	cmake-utils_src_install

	# base configs
	insinto /etc/xrootd
	doins packaging/common/*.cfg

	fowners root:xrootd /etc/xrootd
	keepdir /var/log/xrootd
	fowners xrootd:xrootd /var/log/xrootd

	local i
	for i in cmsd frm_purged frm_xfrd xrootd; do
		newinitd "${FILESDIR}"/${i}.initd ${i}
	done
	# all daemons MUST use single master config file
	newconfd "${FILESDIR}"/xrootd.confd xrootd

	dodoc docs/ReleaseNotes.txt
	use doc && dohtml -r doxydoc/html/*
}