[gentoo-commits] gentoo-x86 commit in kde-base/kdebase-startkde: kdebase-startkde-4.11.7.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in kde-base/kdebase-startkde: kdebase-startkde-4.11.7.ebuild ChangeLog

[Johannes Huber (johu)]

johu        14/03/04 19:30:42

  Modified:             ChangeLog
  Added:                kdebase-startkde-4.11.7.ebuild
  Log:
  Version bump KDE Workspace 4.11.7
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key F3CFD2BD)

Revision  Changes    Path
1.360                kde-base/kdebase-startkde/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kdebase-startkde/ChangeLog?rev=1.360&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kdebase-startkde/ChangeLog?rev=1.360&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kdebase-startkde/ChangeLog?r1=1.359&r2=1.360

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/kdebase-startkde/ChangeLog,v
retrieving revision 1.359
retrieving revision 1.360
diff -u -r1.359 -r1.360
--- ChangeLog	23 Feb 2014 10:01:18 -0000	1.359
+++ ChangeLog	4 Mar 2014 19:30:41 -0000	1.360
@@ -1,6 +1,12 @@
 # ChangeLog for kde-base/kdebase-startkde
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kdebase-startkde/ChangeLog,v 1.359 2014/02/23 10:01:18 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdebase-startkde/ChangeLog,v 1.360 2014/03/04 19:30:41 johu Exp $
+
+*kdebase-startkde-4.11.7 (04 Mar 2014)
+
+  04 Mar 2014; Johannes Huber <johu@gentoo.org>
+  +kdebase-startkde-4.11.7.ebuild:
+  Version bump KDE Workspace 4.11.7
 
   23 Feb 2014; Agostino Sarubbo <ago@gentoo.org>
   -kdebase-startkde-4.11.2.ebuild:



1.1                  kde-base/kdebase-startkde/kdebase-startkde-4.11.7.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kdebase-startkde/kdebase-startkde-4.11.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kdebase-startkde/kdebase-startkde-4.11.7.ebuild?rev=1.1&content-type=text/plain

Index: kdebase-startkde-4.11.7.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/kdebase-startkde/kdebase-startkde-4.11.7.ebuild,v 1.1 2014/03/04 19:30:41 johu Exp $

EAPI=5

KMNAME="kde-workspace"
KMNOMODULE="true"
inherit kde4-meta prefix

DESCRIPTION="Startkde script, which starts a complete KDE session, and associated scripts"
KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
IUSE="+wallpapers"

# The KDE apps called from the startkde script.
# These provide the most minimal KDE desktop.
RDEPEND="
	$(add_kdebase_dep kcminit)
	$(add_kdebase_dep kdebase-runtime-meta)
	wallpapers? ( $(add_kdebase_dep kde-wallpapers) )
	$(add_kdebase_dep kfmclient)
	$(add_kdebase_dep knotify)
	$(add_kdebase_dep kreadconfig)
	$(add_kdebase_dep krunner)
	$(add_kdebase_dep ksmserver)
	$(add_kdebase_dep ksplash)
	$(add_kdebase_dep kstartupconfig)
	$(add_kdebase_dep kwin)
	$(add_kdebase_dep phonon-kde)
	$(add_kdebase_dep plasma-apps)
	$(add_kdebase_dep plasma-workspace)
	$(add_kdebase_dep systemsettings)
	x11-apps/mkfontdir
	x11-apps/xmessage
	x11-apps/xprop
	x11-apps/xrandr
	x11-apps/xrdb
	x11-apps/xsetroot
	x11-apps/xset
"

KMEXTRACTONLY="
	ConfigureChecks.cmake
	kdm/
	startkde.cmake
"

PATCHES=("${FILESDIR}/gentoo-startkde4-4.patch")

src_prepare() {
	kde4-meta_src_prepare

	cp "${FILESDIR}/KDE-4" "${T}"

	# fix ${EPREFIX}
	eprefixify startkde.cmake "${T}/KDE-4"
}

src_install() {
	kde4-meta_src_install

	# startup and shutdown scripts
	insinto /etc/kde/startup
	doins "${FILESDIR}/agent-startup.sh"

	insinto /etc/kde/shutdown
	doins "${FILESDIR}/agent-shutdown.sh"

	# x11 session script
	exeinto /etc/X11/Sessions
	doexe "${T}/KDE-4"

	# freedesktop compliant session script
	sed -e "s:\${BIN_INSTALL_DIR}:${EPREFIX}/usr/bin:g" \
		"${S}/kdm/kfrontend/sessions/kde-plasma.desktop.cmake" > "${T}/KDE-4.desktop"
	insinto /usr/share/xsessions
	doins "${T}/KDE-4.desktop"
}

pkg_postinst () {
	kde4-meta_pkg_postinst

	echo
	elog "To enable gpg-agent and/or ssh-agent in KDE sessions,"
	elog "edit ${EPREFIX}/etc/kde/startup/agent-startup.sh and"
	elog "${EPREFIX}/etc/kde/shutdown/agent-shutdown.sh"
	echo
	elog "The name of the session script has changed."
	elog "If you currently have XSESSION=\"kde-$(get_kde_version)\" in your"
	elog "configuration files, you will need to change it to"
	elog "XSESSION=\"KDE-4\""
}