[gentoo-commits] gentoo-x86 commit in sci-astronomy/cpl: cpl-6.4.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in sci-astronomy/cpl: cpl-6.4.ebuild ChangeLog

[Sebastien Fabbro (bicatali)]

bicatali    14/03/03 20:50:46

  Modified:             ChangeLog
  Added:                cpl-6.4.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.8-prefix/cvs/Linux x86_64, signed Manifest commit with key 0x13CB1360)

Revision  Changes    Path
1.15                 sci-astronomy/cpl/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-astronomy/cpl/ChangeLog?rev=1.15&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-astronomy/cpl/ChangeLog?rev=1.15&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-astronomy/cpl/ChangeLog?r1=1.14&r2=1.15

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-astronomy/cpl/ChangeLog,v
retrieving revision 1.14
retrieving revision 1.15
diff -u -r1.14 -r1.15
--- ChangeLog	11 Jun 2013 17:40:51 -0000	1.14
+++ ChangeLog	3 Mar 2014 20:50:46 -0000	1.15
@@ -1,6 +1,11 @@
 # ChangeLog for sci-astronomy/cpl
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-astronomy/cpl/ChangeLog,v 1.14 2013/06/11 17:40:51 bicatali Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sci-astronomy/cpl/ChangeLog,v 1.15 2014/03/03 20:50:46 bicatali Exp $
+
+*cpl-6.4 (03 Mar 2014)
+
+  03 Mar 2014; Sébastien Fabbro <bicatali@gentoo.org> +cpl-6.4.ebuild:
+  Version bump
 
   11 Jun 2013; Sébastien Fabbro <bicatali@gentoo.org> -cpl-6.1.1.ebuild,
   -cpl-6.2.ebuild:



1.1                  sci-astronomy/cpl/cpl-6.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-astronomy/cpl/cpl-6.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-astronomy/cpl/cpl-6.4.ebuild?rev=1.1&content-type=text/plain

Index: cpl-6.4.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-astronomy/cpl/cpl-6.4.ebuild,v 1.1 2014/03/03 20:50:46 bicatali Exp $

EAPI=5

JAVA_PKG_OPT_USE=gasgano
AUTOTOOLS_AUTORECONF=1

inherit eutils java-pkg-opt-2 autotools-utils

DESCRIPTION="ESO common pipeline library for astronomical data reduction"
HOMEPAGE="http://www.eso.org/sci/software/cpl/"
SRC_URI="ftp://ftp.eso.org/pub/dfs/pipelines/libraries/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0/20"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"

IUSE="doc gasgano static-libs threads"

RDEPEND="
	>=sci-astronomy/wcslib-4.8.4
	>=sci-libs/cfitsio-3.310
	>=sci-libs/fftw-3.1.2
	gasgano? ( sci-astronomy/gasgano )"
DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen )"

PATCHES=(
	"${FILESDIR}"/${PN}-6.1.1-check-shared-libs.patch
	"${FILESDIR}"/${PN}-6.1.1-use-system-ltdl.patch
)

src_prepare() {
	# bug 422455 and remove cpu chcking
	sed -i \
		-e '/AM_C_PROTOTYPES/d' \
		-e '/CPL_CHECK_CPU/d' \
		configure.ac libcext/configure.ac || die
	autotools-utils_src_prepare
}

src_configure() {
	local myeconfargs=(
		--htmldir="${EPREFIX}/usr/share/doc/${PF}/html"
		--disable-ltdl-install
		--without-included-ltdl
		--with-cfitsio="${EPREFIX}/usr"
		--with-wcs="${EPREFIX}/usr"
		--with-fftw="${EPREFIX}/usr"
		$(use_enable doc maintainer-mode)
		$(use_enable threads)
	)
	if use gasgano; then
		myeconfargs+=(
			--enable-gasgano
			--with-gasgano="${EPREFIX}/usr"
			--with-gasgano-classpath="${EPREFIX}/usr/share/gasgano/lib"
			--with-java="$(java-config -O)"
		)
	else
		myeconfargs+=( --disable-gasgano )
	fi
	autotools-utils_src_configure
}

src_compile() {
	autotools-utils_src_compile all $(use doc && echo html)
}

src_install() {
	autotools-utils_src_install all $(use doc && echo install-html)
}