[gentoo-commits] gentoo-x86 commit in dev-python/carbon: ChangeLog carbon-0.9.12-r1.ebuild

[gentoo-commits] gentoo-x86 commit in dev-python/carbon: ChangeLog carbon-0.9.12-r1.ebuild

[Alexys Jacob (ultrabug)]

ultrabug    14/02/19 16:27:36

  Modified:             ChangeLog
  Added:                carbon-0.9.12-r1.ebuild
  Log:
  fix twisted-core dep, add init scripts
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key B658FA13)

Revision  Changes    Path
1.7                  dev-python/carbon/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/carbon/ChangeLog?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/carbon/ChangeLog?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/carbon/ChangeLog?r1=1.6&r2=1.7

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/carbon/ChangeLog,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- ChangeLog	26 Jan 2014 04:35:05 -0000	1.6
+++ ChangeLog	19 Feb 2014 16:27:36 -0000	1.7
@@ -1,6 +1,13 @@
 # ChangeLog for dev-python/carbon
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/carbon/ChangeLog,v 1.6 2014/01/26 04:35:05 idella4 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/carbon/ChangeLog,v 1.7 2014/02/19 16:27:36 ultrabug Exp $
+
+*carbon-0.9.12-r1 (19 Feb 2014)
+
+  19 Feb 2014; Ultrabug <ultrabug@gentoo.org> +carbon-0.9.12-r1.ebuild,
+  +files/carbon.confd, +files/carbon.initd:
+  fix twisted-core dep, add init scripts for carbon-cache, carbon-relay and
+  carbon-aggregator
 
 *carbon-0.9.12 (26 Jan 2014)
 



1.1                  dev-python/carbon/carbon-0.9.12-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/carbon/carbon-0.9.12-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/carbon/carbon-0.9.12-r1.ebuild?rev=1.1&content-type=text/plain

Index: carbon-0.9.12-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/carbon/carbon-0.9.12-r1.ebuild,v 1.1 2014/02/19 16:27:36 ultrabug Exp $

EAPI=5

PYTHON_COMPAT=( python{2_6,2_7} )

inherit distutils-r1

DESCRIPTION="Backend data caching and persistence daemon for Graphite"
HOMEPAGE="http://graphite.wikidot.com/"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"

SLOT="0"
LICENSE="Apache-2.0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND=""
RDEPEND="${DEPEND}
	~dev-python/twisted-core-12.3.0[${PYTHON_USEDEP}]
	dev-python/whisper[${PYTHON_USEDEP}]
	dev-python/txAMQP[${PYTHON_USEDEP}]"

PATCHES=(
	# Do not install the configuration and data files. We install them
	# somewhere sensible by hand.
	"${FILESDIR}"/${P}-no-data-files.patch
	)

python_prepare_all() {
	# This sets prefix to /opt/graphite. We want FHS-style paths instead.
	rm setup.cfg || die
	distutils-r1_python_prepare_all
}

python_install_all() {
	distutils-r1_python_install_all

	insinto /etc/carbon
	doins conf/*

	dodir /var/log/carbon /var/lib/carbon/{whisper,lists,rrd}

	newinitd "${FILESDIR}"/carbon.initd carbon-cache
	newinitd "${FILESDIR}"/carbon.initd carbon-relay
	newinitd "${FILESDIR}"/carbon.initd carbon-aggregator

	newconfd "${FILESDIR}"/carbon.confd carbon-cache
	newconfd "${FILESDIR}"/carbon.confd carbon-relay
	newconfd "${FILESDIR}"/carbon.confd carbon-aggregator
}

pkg_postinst() {
	einfo 'This ebuild installs carbon into FHS-style paths.'
	einfo 'You will probably have to set GRAPHITE_CONF_DIR to /etc/carbon'
	einfo 'and GRAPHITE_STORAGE_DIR to /var/lib/carbon to make use of this'
	einfo '(see /etc/carbon/carbon.conf.example).'
	einfo ' '
	einfo 'OpenRC init script supports multiple instances !'
	einfo 'Example to run an instance b of carbon-cache :'
	einfo '    ln -s /etc/init.d/carbon-cache /etc/init.d/carbon-cache.b'
	einfo '    cp /etc/conf.d/carbon-cache /etc/conf.d/carbon-cache.b'
}