[gentoo-commits] gentoo-x86 commit in net-p2p/retroshare: retroshare-0.5.5c.ebuild ChangeLog

["Julian Ospald (hasufell)" <hasufell@gentoo.org>]

hasufell    14/02/17 22:52:34

  Modified:             ChangeLog
  Added:                retroshare-0.5.5c.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

Revision  Changes    Path
1.5                  net-p2p/retroshare/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/retroshare/ChangeLog?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/retroshare/ChangeLog?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/retroshare/ChangeLog?r1=1.4&r2=1.5

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-p2p/retroshare/ChangeLog,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- ChangeLog	17 Nov 2013 13:06:54 -0000	1.4
+++ ChangeLog	17 Feb 2014 22:52:34 -0000	1.5
@@ -1,6 +1,11 @@
 # ChangeLog for net-p2p/retroshare
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-p2p/retroshare/ChangeLog,v 1.4 2013/11/17 13:06:54 hasufell Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/retroshare/ChangeLog,v 1.5 2014/02/17 22:52:34 hasufell Exp $
+
+*retroshare-0.5.5c (17 Feb 2014)
+
+  17 Feb 2014; Julian Ospald <hasufell@gentoo.org> +retroshare-0.5.5c.ebuild:
+  version bump
 
 *retroshare-0.5.5b (17 Nov 2013)
 



1.1                  net-p2p/retroshare/retroshare-0.5.5c.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/retroshare/retroshare-0.5.5c.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/retroshare/retroshare-0.5.5c.ebuild?rev=1.1&content-type=text/plain

Index: retroshare-0.5.5c.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-p2p/retroshare/retroshare-0.5.5c.ebuild,v 1.1 2014/02/17 22:52:34 hasufell Exp $

EAPI=5

inherit eutils multilib gnome2-utils qmake-utils

MY_PN="RetroShare"
MY_P="${MY_PN}-v${PV}"

DESCRIPTION="P2P private sharing application"
HOMEPAGE="http://retroshare.sourceforge.net"
SRC_URI="mirror://sourceforge/retroshare/retroshare_0.5.5-0.7068.tar.gz"

# pegmarkdown can also be used with MIT
LICENSE="GPL-2 GPL-3 Apache-2.0 LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="cli feedreader links-cloud qt4 voip"
REQUIRED_USE="|| ( cli qt4 )
	feedreader? ( qt4 )
	links-cloud? ( qt4 )
	voip? ( qt4 )"

RDEPEND="
	app-arch/bzip2
	dev-libs/openssl:0
	gnome-base/libgnome-keyring
	net-libs/libupnp
	sys-libs/zlib
	cli? (
		dev-libs/protobuf
		net-libs/libssh[server]
	)
	feedreader? (
		dev-libs/libxml2
		dev-libs/libxslt
		net-misc/curl
		dev-qt/qtcore:4
		dev-qt/qtgui:4
	)
	qt4? (
		x11-libs/libX11
		x11-libs/libXScrnSaver
		dev-qt/qtcore:4
		|| ( ( >=dev-qt/qtgui-4.8.5:4 dev-qt/designer:4 ) <dev-qt/qtgui-4.8.5:4 )
	)
	voip? (
		media-libs/speex
		dev-qt/qt-mobility[multimedia]
		dev-qt/qtmultimedia:4
	)"
DEPEND="${RDEPEND}
	app-arch/unzip
	dev-qt/qtcore:4
	virtual/pkgconfig"

S=${WORKDIR}/retroshare-0.5.5/src

src_prepare() {
	local dir

	sed -i \
		-e "s|/usr/lib/retroshare/extensions/|/usr/$(get_libdir)/${PN}/extensions/|" \
		libretroshare/src/rsserver/rsinit.cc \
		|| die "sed failed"

	rs_src_dirs="libbitdht/src openpgpsdk/src libretroshare/src supportlibs/pegmarkdown"
	use cli && rs_src_dirs="${rs_src_dirs} retroshare-nogui/src"
	use qt4 && rs_src_dirs="${rs_src_dirs} retroshare-gui/src"
	use links-cloud && rs_src_dirs="${rs_src_dirs} plugins/LinksCloud"
	use feedreader && rs_src_dirs="${rs_src_dirs} plugins/FeedReader"

	if use voip ; then
		rs_src_dirs="${rs_src_dirs} plugins/VOIP"
		echo "QT += multimedia" >> "plugins/VOIP/VOIP.pro" || die
		echo "CONFIG += mobility" >> "plugins/VOIP/VOIP.pro" || die
	fi
}

src_configure() {
	for dir in ${rs_src_dirs} ; do
		cd "${S}"/${dir} || die
		eqmake4
	done
}

src_compile() {
	local dir

	for dir in ${rs_src_dirs} ; do
		emake -C ${dir}
	done

	unset rs_src_dirs
}

src_install() {
	local i
	local extension_dir="/usr/$(get_libdir)/${PN}/extensions/"

	use cli && dobin retroshare-nogui/src/retroshare-nogui
	use qt4 && dobin retroshare-gui/src/RetroShare

	exeinto "${extension_dir}"
	use feedreader && doexe plugins/FeedReader/*.so*
	use links-cloud && doexe plugins/LinksCloud/*.so*
	use voip && doexe plugins/VOIP/*.so*

	insinto /usr/share/RetroShare
	doins libbitdht/src/bitdht/bdboot.txt

	dodoc README.txt
	make_desktop_entry RetroShare
	for i in 24 48 64 ; do
		doicon -s ${i} build_scripts/Ubuntu_src/data/${i}x${i}/${PN}.png
	done
	doicon -s 128 build_scripts/Ubuntu_src/data/${PN}.png
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	gnome2_icon_cache_update
}

pkg_postrm() {
	gnome2_icon_cache_update
}