* [gentoo-commits] gentoo-x86 commit in net-wireless/bluez: bluez-5.14.ebuild ChangeLog bluez-5.12.ebuild bluez-4.101-r7.ebuild bluez-4.101-r6.ebuild
@ 2014-02-09 9:10 Pacho Ramos (pacho)
0 siblings, 0 replies; only message in thread
From: Pacho Ramos (pacho) @ 2014-02-09 9:10 UTC (permalink / raw
To: gentoo-commits
pacho 14/02/09 09:10:29
Modified: ChangeLog
Added: bluez-5.14.ebuild
Removed: bluez-5.12.ebuild bluez-4.101-r7.ebuild
bluez-4.101-r6.ebuild
Log:
Version bump, drop old
(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)
Revision Changes Path
1.186 net-wireless/bluez/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/bluez/ChangeLog?rev=1.186&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/bluez/ChangeLog?rev=1.186&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/bluez/ChangeLog?r1=1.185&r2=1.186
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-wireless/bluez/ChangeLog,v
retrieving revision 1.185
retrieving revision 1.186
diff -u -r1.185 -r1.186
--- ChangeLog 19 Jan 2014 10:31:05 -0000 1.185
+++ ChangeLog 9 Feb 2014 09:10:28 -0000 1.186
@@ -1,6 +1,16 @@
# ChangeLog for net-wireless/bluez
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/bluez/ChangeLog,v 1.185 2014/01/19 10:31:05 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/bluez/ChangeLog,v 1.186 2014/02/09 09:10:28 pacho Exp $
+
+*bluez-5.14 (09 Feb 2014)
+
+ 09 Feb 2014; Pacho Ramos <pacho@gentoo.org> +bluez-5.14.ebuild,
+ +files/0001-Allow-using-obexd-without-systemd-in-the-user-sessio.patch,
+ -bluez-4.101-r6.ebuild, -bluez-4.101-r7.ebuild, -bluez-5.12.ebuild,
+ -files/bluez-4.101-mgmt-update.patch, -files/bluez-4.101-network1.patch,
+ -files/bluez-4.101-network2.patch, -files/bluez-4.101-network3.patch,
+ -files/bluez-4.101-network4.patch:
+ Version bump, drop old
19 Jan 2014; Agostino Sarubbo <ago@gentoo.org> bluez-4.101-r8.ebuild:
Stable for ppc64, wrt bug #496866
1.1 net-wireless/bluez/bluez-5.14.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/bluez/bluez-5.14.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/bluez/bluez-5.14.ebuild?rev=1.1&content-type=text/plain
Index: bluez-5.14.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-wireless/bluez/bluez-5.14.ebuild,v 1.1 2014/02/09 09:10:28 pacho Exp $
EAPI=5
PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} )
inherit eutils multilib python-any-r1 readme.gentoo systemd udev user
DESCRIPTION="Bluetooth Tools and System Daemons for Linux"
HOMEPAGE="http://www.bluez.org"
SRC_URI="mirror://kernel/linux/bluetooth/${P}.tar.xz"
LICENSE="GPL-2+ LGPL-2.1+"
SLOT="0/3"
KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86"
IUSE="cups debug +obex readline selinux systemd test"
REQUIRED_USE="test? ( ${PYTHON_REQUIRED_USE} )"
RDEPEND="
>=dev-libs/glib-2.28:2
>=sys-apps/dbus-1.6:=
>=sys-apps/hwids-20121202.2
>=virtual/udev-171
cups? ( net-print/cups:= )
obex? ( dev-libs/libical )
readline? ( sys-libs/readline:= )
selinux? ( sec-policy/selinux-bluetooth )
systemd? ( sys-apps/systemd )
"
DEPEND="${RDEPEND}
virtual/pkgconfig
test? (
${PYTHON_DEPS}
>=dev-python/dbus-python-1
dev-python/pygobject:2
dev-python/pygobject:3
)
"
DOC_CONTENTS="
If you want to use rfcomm as a normal user, you need to add the user
to the uucp group.
"
pkg_setup() {
enewgroup plugdev
use test && python-any-r1_pkg_setup
}
src_prepare() {
# Use static group "plugdev" if there is no ConsoleKit (or systemd logind)
epatch "${FILESDIR}"/bluez-plugdev.patch
# Fedora patch for better compat with non-full systemd setups
epatch "${FILESDIR}"/0001-Allow-using-obexd-without-systemd-in-the-user-sessio.patch
if use cups; then
sed -i \
-e "s:cupsdir = \$(libdir)/cups:cupsdir = `cups-config --serverbin`:" \
Makefile.{in,tools} || die
fi
}
src_configure() {
# readline is automagic when client is enabled
export ac_cv_header_readline_readline_h=$(usex readline)
# Missing flags: experimental (sap, nfc, ...)
econf \
--localstatedir=/var \
--enable-experimental \
--enable-optimization \
$(use_enable debug) \
--enable-pie \
--enable-threads \
--enable-library \
$(use_enable test) \
--enable-tools \
--enable-monitor \
--enable-udev \
$(use_enable cups) \
$(use_enable obex) \
--enable-client \
$(use_enable systemd) \
$(systemd_with_unitdir) \
--enable-sixaxis
}
src_install() {
default
prune_libtool_files --modules
keepdir /var/lib/bluetooth
# Unittests are not that useful once installed
if use test ; then
rm -r "${ED}"/usr/$(get_libdir)/bluez/test || die
fi
insinto /etc/bluetooth
local d
for d in input network proximity; do
doins profiles/${d}/${d}.conf
done
doins src/main.conf
doins src/bluetooth.conf
insinto /usr/share/dbus-1/system-services
doins src/org.bluez.service
newinitd "${FILESDIR}"/bluetooth-init.d-r3 bluetooth
newinitd "${FILESDIR}"/rfcomm-init.d rfcomm
newconfd "${FILESDIR}"/rfcomm-conf.d rfcomm
readme.gentoo_create_doc
}
pkg_postinst() {
readme.gentoo_print_elog
udev_reload
has_version net-dialup/ppp || elog "To use dial up networking you must install net-dialup/ppp."
if ! has_version sys-auth/consolekit && ! has_version sys-apps/systemd; then
elog "Since you don't have sys-auth/consolekit neither sys-apps/systemd, you will only"
elog "be able to run bluetooth clients as root. If you want to be able to run bluetooth clientes as"
elog "a regular user, you need to enable the consolekit use flag for this package or"
elog "to add the user to the plugdev group."
fi
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2014-02-09 9:10 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-02-09 9:10 [gentoo-commits] gentoo-x86 commit in net-wireless/bluez: bluez-5.14.ebuild ChangeLog bluez-5.12.ebuild bluez-4.101-r7.ebuild bluez-4.101-r6.ebuild Pacho Ramos (pacho)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox