* [gentoo-commits] gentoo-x86 commit in net-misc/tigervnc: ChangeLog tigervnc-1.3.0-r1.ebuild
@ 2014-02-08 19:40 Raul Porcel (armin76)
0 siblings, 0 replies; only message in thread
From: Raul Porcel (armin76) @ 2014-02-08 19:40 UTC (permalink / raw
To: gentoo-commits
armin76 14/02/08 19:40:31
Modified: ChangeLog
Added: tigervnc-1.3.0-r1.ebuild
Log:
Revision bump with xorg-server-1.15 support wrt bug #500028
(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 0xF6AD3240)
Revision Changes Path
1.171 net-misc/tigervnc/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tigervnc/ChangeLog?rev=1.171&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tigervnc/ChangeLog?rev=1.171&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tigervnc/ChangeLog?r1=1.170&r2=1.171
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/tigervnc/ChangeLog,v
retrieving revision 1.170
retrieving revision 1.171
diff -u -r1.170 -r1.171
--- ChangeLog 1 Feb 2014 19:15:18 -0000 1.170
+++ ChangeLog 8 Feb 2014 19:40:31 -0000 1.171
@@ -1,6 +1,11 @@
# ChangeLog for net-misc/tigervnc
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/tigervnc/ChangeLog,v 1.170 2014/02/01 19:15:18 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/tigervnc/ChangeLog,v 1.171 2014/02/08 19:40:31 armin76 Exp $
+
+*tigervnc-1.3.0-r1 (08 Feb 2014)
+
+ 08 Feb 2014; Raúl Porcel <armin76@gentoo.org> +tigervnc-1.3.0-r1.ebuild:
+ Revision bump with xorg-server-1.15 support wrt bug #500028
01 Feb 2014; Raúl Porcel <armin76@gentoo.org> tigervnc-1.3.0.ebuild:
Add missing dep, wrt bug #488666
1.1 net-misc/tigervnc/tigervnc-1.3.0-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tigervnc/tigervnc-1.3.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tigervnc/tigervnc-1.3.0-r1.ebuild?rev=1.1&content-type=text/plain
Index: tigervnc-1.3.0-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/tigervnc/tigervnc-1.3.0-r1.ebuild,v 1.1 2014/02/08 19:40:31 armin76 Exp $
EAPI="4"
inherit eutils cmake-utils autotools java-pkg-opt-2 flag-o-matic
PATCHVER="0.2"
XSERVER_VERSION="1.15.0"
OPENGL_DIR="xorg-x11"
#MY_P="${PN}-1.2.80-20130314svn5065"
#S="${WORKDIR}/${MY_P}"
DESCRIPTION="Remote desktop viewer display system"
HOMEPAGE="http://www.tigervnc.org"
SRC_URI="mirror://sourceforge/tigervnc/${P}.tar.bz2
mirror://gentoo/${PN}.png
mirror://gentoo/${P}-patches-${PATCHVER}.tar.bz2
http://dev.gentoo.org/~armin76/dist/${P}-patches-${PATCHVER}.tar.bz2
server? ( ftp://ftp.freedesktop.org/pub/xorg/individual/xserver/xorg-server-${XSERVER_VERSION}.tar.bz2 )"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86"
IUSE="gnutls java nptl +opengl pam server +xorgmodule"
RDEPEND="virtual/jpeg:0
sys-libs/zlib
>=x11-libs/libXtst-1.0.99.2
>=x11-libs/fltk-1.3.1
gnutls? ( net-libs/gnutls )
java? ( >=virtual/jre-1.5 )
pam? ( virtual/pam )
server? (
dev-lang/perl
>=x11-libs/libXi-1.2.99.1
>=x11-libs/libXfont-1.4.2
>=x11-libs/libxkbfile-1.0.4
x11-libs/libXrender
>=x11-libs/pixman-0.21.8
>=x11-apps/xauth-1.0.3
x11-apps/xsetroot
>=x11-misc/xkeyboard-config-2.4.1-r3
opengl? ( >=app-admin/eselect-opengl-1.0.8 )
xorgmodule? ( =x11-base/xorg-server-${XSERVER_VERSION%.*}* )
)
!net-misc/vnc
!net-misc/tightvnc
!net-misc/xf4vnc"
DEPEND="${RDEPEND}
amd64? ( dev-lang/nasm )
x86? ( dev-lang/nasm )
>=x11-proto/inputproto-2.1.99.3
>=x11-proto/xextproto-7.1.99
>=x11-proto/xproto-7.0.22
java? ( >=virtual/jdk-1.5 )
server? (
virtual/pkgconfig
media-fonts/font-util
x11-misc/util-macros
>=x11-proto/bigreqsproto-1.1.0
>=x11-proto/compositeproto-0.4
>=x11-proto/damageproto-1.1
>=x11-proto/fixesproto-5.0
>=x11-proto/fontsproto-2.0.2
>=x11-proto/glproto-1.4.16
>=x11-proto/randrproto-1.4.0
>=x11-proto/renderproto-0.11
>=x11-proto/resourceproto-1.0.2
>=x11-proto/scrnsaverproto-1.1
>=x11-proto/videoproto-2.2.2
>=x11-proto/xcmiscproto-1.2.0
>=x11-proto/xineramaproto-1.1.3
>=x11-libs/xtrans-1.2.2
>=x11-proto/dri2proto-2.8
opengl? ( >=media-libs/mesa-7.8_rc[nptl=] )
)"
CMAKE_IN_SOURCE_BUILD=1
pkg_setup() {
if ! use server ; then
echo
einfo "The 'server' USE flag will build tigervnc's server."
einfo "If '-server' is chosen only the client is built to save space."
einfo "Stop the build now if you need to add 'server' to USE flags.\n"
else
ewarn "Forcing on xorg-x11 for new enough glxtokens.h..."
OLD_IMPLEM="$(eselect opengl show)"
eselect opengl set ${OPENGL_DIR}
fi
}
switch_opengl_implem() {
# Switch to the xorg implementation.
# Use new opengl-update that will not reset user selected
# OpenGL interface ...
echo
eselect opengl set ${OLD_IMPLEM}
}
src_prepare() {
if use server ; then
cp -r "${WORKDIR}"/xorg-server-${XSERVER_VERSION}/* unix/xserver
else
rm "${WORKDIR}"/patches/*_server_*
fi
EPATCH_SOURCE="${WORKDIR}/patches" EPATCH_SUFFIX="patch" \
EPATCH_FORCE="yes" epatch
if use server ; then
cd unix/xserver
epatch ../xserver114.patch
eautoreconf
fi
}
src_configure() {
use arm || use hppa && append-flags "-fPIC"
mycmakeargs=(
-G "Unix Makefiles"
$(cmake-utils_use_enable gnutls GNUTLS)
$(cmake-utils_use_enable pam PAM)
$(cmake-utils_use_build java JAVA)
)
cmake-utils_src_configure
if use server; then
cd unix/xserver
econf \
$(use_enable nptl glx-tls) \
$(use_enable opengl glx) \
--disable-config-dbus \
--disable-config-hal \
--disable-config-udev \
--disable-devel-docs \
--disable-dmx \
--disable-dri \
--disable-dri3 \
--disable-kdrive \
--disable-selective-werror \
--disable-silent-rules \
--disable-static \
--disable-unit-tests \
--disable-xephyr \
--disable-xinerama \
--disable-xnest \
--disable-xorg \
--disable-xvfb \
--disable-xwin \
--enable-dri2 \
--with-pic \
--without-dtrace \
--disable-present \
--disable-unit-tests
fi
}
src_compile() {
cmake-utils_src_compile
if use server ; then
cd unix/xserver
emake
fi
}
src_install() {
cmake-utils_src_install
newicon "${DISTDIR}"/tigervnc.png vncviewer.png
make_desktop_entry vncviewer vncviewer vncviewer Network
if use server ; then
cd unix/xserver/hw/vnc
emake DESTDIR="${D}" install
! use xorgmodule && rm -rf "${D}"/usr/$(get_libdir)/xorg
newconfd "${FILESDIR}"/${PN}.confd ${PN}
newinitd "${FILESDIR}"/${PN}.initd ${PN}
rm "${D}"/usr/$(get_libdir)/xorg/modules/extensions/libvnc.la
else
cd "${D}"
for f in vncserver vncpasswd x0vncserver vncconfig; do
rm usr/bin/$f
rm usr/share/man/man1/$f.1
done
fi
}
pkg_postinst() {
use server && switch_opengl_implem
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2014-02-08 19:40 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-02-08 19:40 [gentoo-commits] gentoo-x86 commit in net-misc/tigervnc: ChangeLog tigervnc-1.3.0-r1.ebuild Raul Porcel (armin76)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox