[gentoo-commits] gentoo-x86 commit in app-emulation/vagrant: ChangeLog vagrant-1.4.3-r2.ebuild

[gentoo-commits] gentoo-x86 commit in app-emulation/vagrant: ChangeLog vagrant-1.4.3-r2.ebuild

[Tim Harder (radhermit)]

radhermit    14/02/06 06:09:01

  Modified:             ChangeLog
  Added:                vagrant-1.4.3-r2.ebuild
  Log:
  Loosen net-ssh dep (bug #500466) and move to ruby20.
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.36                 app-emulation/vagrant/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/vagrant/ChangeLog?rev=1.36&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/vagrant/ChangeLog?rev=1.36&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/vagrant/ChangeLog?r1=1.35&r2=1.36

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/vagrant/ChangeLog,v
retrieving revision 1.35
retrieving revision 1.36
diff -u -r1.35 -r1.36
--- ChangeLog	22 Jan 2014 07:20:28 -0000	1.35
+++ ChangeLog	6 Feb 2014 06:09:01 -0000	1.36
@@ -1,6 +1,11 @@
 # ChangeLog for app-emulation/vagrant
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/vagrant/ChangeLog,v 1.35 2014/01/22 07:20:28 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/vagrant/ChangeLog,v 1.36 2014/02/06 06:09:01 radhermit Exp $
+
+*vagrant-1.4.3-r2 (06 Feb 2014)
+
+  06 Feb 2014; Tim Harder <radhermit@gentoo.org> +vagrant-1.4.3-r2.ebuild:
+  Loosen net-ssh dep (bug #500466) and move to ruby20.
 
   22 Jan 2014; Tim Harder <radhermit@gentoo.org> -vagrant-1.4.1.ebuild,
   -vagrant-1.4.3.ebuild:



1.1                  app-emulation/vagrant/vagrant-1.4.3-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/vagrant/vagrant-1.4.3-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/vagrant/vagrant-1.4.3-r2.ebuild?rev=1.1&content-type=text/plain

Index: vagrant-1.4.3-r2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/vagrant/vagrant-1.4.3-r2.ebuild,v 1.1 2014/02/06 06:09:01 radhermit Exp $

EAPI="5"
USE_RUBY="ruby20"

RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"
RUBY_FAKEGEM_GEMSPEC="vagrant.gemspec"
RUBY_FAKEGEM_EXTRAINSTALL="config keys plugins templates"
RUBY_FAKEGEM_TASK_DOC=""

inherit ruby-fakegem eutils

DESCRIPTION="A tool for building and distributing virtual machines using VirtualBox"
HOMEPAGE="http://vagrantup.com/"
SRC_URI="https://github.com/mitchellh/vagrant/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x64-macos"
IUSE="test"

# Missing ebuild for contest
RESTRICT="test"

RDEPEND="${RDEPEND}
	app-arch/libarchive
	net-misc/curl
	!x64-macos? ( || ( app-emulation/virtualbox app-emulation/virtualbox-bin ) )"

ruby_add_rdepend "
	>=dev-ruby/childprocess-0.3.7
	>=dev-ruby/erubis-2.7.0
	dev-ruby/i18n:0.6
	>=dev-ruby/json-1.5.1
	>=dev-ruby/log4r-1.1.9
	>=dev-ruby/net-ssh-2.6.6
	>=dev-ruby/net-scp-1.1.0
"

ruby_add_bdepend "
	dev-ruby/rake
	test? ( dev-ruby/mocha virtual/ruby-minitest )
"

all_ruby_prepare() {
	# remove bundler support
	sed -i '/[Bb]undler/d' Rakefile || die
	rm Gemfile || die

	# loosen dependencies
	sed -e '/childprocess\|erubis\|log4r\|net-scp/s/~>/>=/' \
		-e '/net-ssh/s:, "< 2.8.0"::' \
		-i ${PN}.gemspec || die

	epatch "${FILESDIR}"/${PN}-1.2.1-no-warning.patch
	epatch "${FILESDIR}"/${PN}-1.2.2-rvm.patch
}

pkg_postinst() {
	if use x64-macos ; then
		ewarn
		ewarn "For Mac OS X prefixes, you must install the virtualbox"
		ewarn "package specifically for OS X which can be found at:"
		ewarn "https://www.virtualbox.org/wiki/Downloads"
		ewarn
	fi
}