[gentoo-commits] gentoo-x86 commit in x11-themes/light-themes: light-themes-0.1.93-r3.ebuild ChangeLog light-themes-0.1.93.ebuild light-themes-0.1.8.32.ebuild

[gentoo-commits] gentoo-x86 commit in x11-themes/light-themes: light-themes-0.1.93-r3.ebuild ChangeLog light-themes-0.1.93.ebuild light-themes-0.1.8.32.ebuild

[Pacho Ramos (pacho)]

pacho       14/02/02 08:40:54

  Modified:             ChangeLog
  Added:                light-themes-0.1.93-r3.ebuild
  Removed:              light-themes-0.1.93.ebuild
                        light-themes-0.1.8.32.ebuild
  Log:
  Provide icons with a Gentoo-style coloring by David Abbott (#499506), thanks to Ulrich Muller for his help with licensing. Drop old.
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.22                 x11-themes/light-themes/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-themes/light-themes/ChangeLog?rev=1.22&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-themes/light-themes/ChangeLog?rev=1.22&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-themes/light-themes/ChangeLog?r1=1.21&r2=1.22

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-themes/light-themes/ChangeLog,v
retrieving revision 1.21
retrieving revision 1.22
diff -u -r1.21 -r1.22
--- ChangeLog	8 Dec 2013 19:54:09 -0000	1.21
+++ ChangeLog	2 Feb 2014 08:40:54 -0000	1.22
@@ -1,6 +1,13 @@
 # ChangeLog for x11-themes/light-themes
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-themes/light-themes/ChangeLog,v 1.21 2013/12/08 19:54:09 pacho Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/x11-themes/light-themes/ChangeLog,v 1.22 2014/02/02 08:40:54 pacho Exp $
+
+*light-themes-0.1.93-r3 (02 Feb 2014)
+
+  02 Feb 2014; Pacho Ramos <pacho@gentoo.org> +light-themes-0.1.93-r3.ebuild,
+  -light-themes-0.1.8.32.ebuild, -light-themes-0.1.93.ebuild:
+  Provide icons with a Gentoo-style coloring by David Abbott (#499506), thanks
+  to Ulrich Muller for his help with licensing. Drop old.
 
   08 Dec 2013; Pacho Ramos <pacho@gentoo.org> light-themes-0.1.93-r2.ebuild:
   x86 stable, bug #478252



1.1                  x11-themes/light-themes/light-themes-0.1.93-r3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-themes/light-themes/light-themes-0.1.93-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-themes/light-themes/light-themes-0.1.93-r3.ebuild?rev=1.1&content-type=text/plain

Index: light-themes-0.1.93-r3.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-themes/light-themes/light-themes-0.1.93-r3.ebuild,v 1.1 2014/02/02 08:40:54 pacho Exp $

EAPI=5
inherit eutils

DESCRIPTION="GTK2/GTK3 Ambiance and Radiance themes from Ubuntu"
HOMEPAGE="https://launchpad.net/light-themes"
SRC_URI="
	mirror://ubuntu/pool/main/${PN:0:1}/${PN}/${PN}_${PV}.tar.gz
	http://dev.gentoo.org/~pacho/${PN}/Gentoo-Buttons.tar.xz
"

LICENSE="CC-BY-SA-3.0 CC-BY-SA-4.0"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="gtk3"

DEPEND="app-arch/xz-utils"
RDEPEND="
	x11-themes/gtk-engines-murrine
	gtk3? ( x11-themes/gtk-engines-unico )
"

src_prepare() {
	# Apply upstream fixes for gtk+-3.8 compat, bug #469062
	# upstream: https://bugs.launchpad.net/ubuntu-themes/+bug/1130183
	epatch "${FILESDIR}/${P}-gtk3.8-1.patch"
	epatch "${FILESDIR}/${P}-gtk3.8-2.patch"
	epatch "${FILESDIR}/${P}-gtk3.8-3.patch"

	cp -r Ambiance/ Ambiance-Gentoo || die
	cp -r Radiance/ Radiance-Gentoo || die
	sed -i -e 's/Ambiance/Ambiance-Gentoo/g' Ambiance-Gentoo/index.theme \
		Ambiance-Gentoo/metacity-1/metacity-theme-1.xml || die
	sed -i -e 's/Radiance/Radiance-Gentoo/g' Radiance-Gentoo/index.theme \
		Radiance-Gentoo/metacity-1/metacity-theme-1.xml || die
	sed -i -e 's/nselected_bg_color:#f07746/nselected_bg_color:#755fbb/g' \
		Ambiance-Gentoo/gtk-2.0/gtkrc Ambiance-Gentoo/gtk-3.0/settings.ini \
		Radiance-Gentoo/gtk-2.0/gtkrc Radiance-Gentoo/gtk-3.0/settings.ini || die
	sed -i -e 's/selected_bg_color #f07746/selected_bg_color #755fbb/g' \
		Ambiance-Gentoo/gtk-3.0/gtk-main.css Radiance-Gentoo/gtk-3.0/gtk-main.css || die

	cp -f "${WORKDIR}"/Gentoo-Buttons/*.png "${S}"/Ambiance-Gentoo/metacity-1/. || die
	cp -f "${WORKDIR}"/Gentoo-Buttons/*.png "${S}"/Radiance-Gentoo/metacity-1/. || die
}

src_install() {
	insinto /usr/share/themes
	doins -r Radiance* Ambiance*

	use gtk3 || {
		rm -R "${D}"/usr/share/themes/*/gtk-3.0 || die
	}
}