[gentoo-commits] gentoo-x86 commit in app-backup/deja-dup: deja-dup-29.5.ebuild ChangeLog deja-dup-29.4.ebuild

[gentoo-commits] gentoo-x86 commit in app-backup/deja-dup: deja-dup-29.5.ebuild ChangeLog deja-dup-29.4.ebuild

[Justin Lecher (jlec)]

jlec        14/01/31 08:25:49

  Modified:             ChangeLog
  Added:                deja-dup-29.5.ebuild
  Removed:              deja-dup-29.4.ebuild
  Log:
  Version BUmp
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

Revision  Changes    Path
1.44                 app-backup/deja-dup/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/deja-dup/ChangeLog?rev=1.44&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/deja-dup/ChangeLog?rev=1.44&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/deja-dup/ChangeLog?r1=1.43&r2=1.44

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-backup/deja-dup/ChangeLog,v
retrieving revision 1.43
retrieving revision 1.44
diff -u -r1.43 -r1.44
--- ChangeLog	13 Jan 2014 07:13:17 -0000	1.43
+++ ChangeLog	31 Jan 2014 08:25:49 -0000	1.44
@@ -1,6 +1,12 @@
 # ChangeLog for app-backup/deja-dup
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-backup/deja-dup/ChangeLog,v 1.43 2014/01/13 07:13:17 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-backup/deja-dup/ChangeLog,v 1.44 2014/01/31 08:25:49 jlec Exp $
+
+*deja-dup-29.5 (31 Jan 2014)
+
+  31 Jan 2014; Justin Lecher <jlec@gentoo.org> +deja-dup-29.5.ebuild,
+  +files/deja-dup-29.5-cmake.patch, -deja-dup-29.4.ebuild:
+  Version BUmp
 
 *deja-dup-29.4 (13 Jan 2014)
 



1.1                  app-backup/deja-dup/deja-dup-29.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/deja-dup/deja-dup-29.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/deja-dup/deja-dup-29.5.ebuild?rev=1.1&content-type=text/plain

Index: deja-dup-29.5.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-backup/deja-dup/deja-dup-29.5.ebuild,v 1.1 2014/01/31 08:25:49 jlec Exp $

EAPI=5

GNOME2_LA_PUNT="yes"

VALA_MIN_API_VERSION="0.20"
VALA_MAX_API_VERSION="0.22"

inherit cmake-utils eutils gnome2 vala

DESCRIPTION="Simple backup tool using duplicity back-end"
HOMEPAGE="https://launchpad.net/deja-dup/"
SRC_URI="http://launchpad.net/${PN}/30/${PV}/+download/${P}.tar.xz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="nautilus test"

RESTRICT="test"

COMMON_DEPEND="
	app-crypt/libsecret[vala]
	>=dev-libs/glib-2.34:2
	>=dev-libs/libpeas-1.0
	x11-libs/gtk+:3
	>=x11-libs/libnotify-0.7

	>=app-backup/duplicity-0.6.21
	dev-libs/dbus-glib

	nautilus? ( gnome-base/nautilus )"
RDEPEND="${COMMON_DEPEND}
	gnome-base/dconf
	gnome-base/gvfs[fuse]"
DEPEND="${COMMON_DEPEND}
	app-text/yelp-tools
	$(vala_depend)
	dev-perl/Locale-gettext
	virtual/pkgconfig
	dev-util/intltool
	sys-devel/gettext"

PATCHES=( "${FILESDIR}"/${P}-cmake.patch )

src_prepare() {
	sed \
		-e '/RPATH/s:PKG_LIBEXECDIR:PKG_LIBDIR:g' \
		-i CMakeLists.txt || die
	vala_src_prepare
	gnome2_src_prepare
	cmake-utils_src_prepare
}

src_configure() {
	local mycmakeargs=(
		-DENABLE_CCPANEL=OFF
		-DENABLE_UNITY=OFF
		-DENABLE_UNITY_CCPANEL=OFF
		-DCMAKE_INSTALL_SYSCONFDIR="${EPREFIX}"/etc
		$(cmake-utils_use_enable nautilus)
		$(cmake-utils_use_enable test TESTING)
	)
	cmake-utils_src_configure
}

src_compile() {
	cmake-utils_src_compile
}

src_install() {
	cmake-utils_src_install
}