[gentoo-commits] gentoo-x86 commit in x11-misc/sunflower: sunflower-0.1_alpha57.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in x11-misc/sunflower: sunflower-0.1_alpha57.ebuild ChangeLog

[Julian Ospald (hasufell)]

hasufell    14/01/27 13:45:28

  Modified:             ChangeLog
  Added:                sunflower-0.1_alpha57.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

Revision  Changes    Path
1.10                 x11-misc/sunflower/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/sunflower/ChangeLog?rev=1.10&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/sunflower/ChangeLog?rev=1.10&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/sunflower/ChangeLog?r1=1.9&r2=1.10

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/sunflower/ChangeLog,v
retrieving revision 1.9
retrieving revision 1.10
diff -u -r1.9 -r1.10
--- ChangeLog	30 Oct 2013 22:18:37 -0000	1.9
+++ ChangeLog	27 Jan 2014 13:45:28 -0000	1.10
@@ -1,6 +1,12 @@
 # ChangeLog for x11-misc/sunflower
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/sunflower/ChangeLog,v 1.9 2013/10/30 22:18:37 hasufell Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/sunflower/ChangeLog,v 1.10 2014/01/27 13:45:28 hasufell Exp $
+
+*sunflower-0.1_alpha57 (27 Jan 2014)
+
+  27 Jan 2014; Julian Ospald <hasufell@gentoo.org>
+  +sunflower-0.1_alpha57.ebuild:
+  version bump
 
   30 Oct 2013; Julian Ospald <hasufell@gentoo.org>
   -sunflower-0.1_alpha53.ebuild, -sunflower-0.1_alpha54.ebuild,



1.1                  x11-misc/sunflower/sunflower-0.1_alpha57.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/sunflower/sunflower-0.1_alpha57.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/sunflower/sunflower-0.1_alpha57.ebuild?rev=1.1&content-type=text/plain

Index: sunflower-0.1_alpha57.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/sunflower/sunflower-0.1_alpha57.ebuild,v 1.1 2014/01/27 13:45:28 hasufell Exp $

EAPI=5

PYTHON_COMPAT=( python{2_6,2_7} )
inherit eutils fdo-mime gnome2-utils python-r1

MY_PN="Sunflower"
DESCRIPTION="Small and highly customizable twin-panel file manager with plugin-support"
HOMEPAGE="http://code.google.com/p/sunflower-fm"
SRC_URI="http://sunflower-fm.org/pub/sunflower-${PV/_alpha/a-}.tgz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""
REQUIRED_USE="${PYTHON_REQUIRED_USE}"

DEPEND="${PYTHON_DEPS}"
RDEPEND="${DEPEND}
	>=dev-python/pygtk-2.15.0[${PYTHON_USEDEP}]
	>=dev-python/notify-python-0.1[${PYTHON_USEDEP}]
	gnome-base/librsvg:2
	virtual/python-argparse[${PYTHON_USEDEP}]"

S=${WORKDIR}/${MY_PN}

src_prepare() {
	find "${S}" -name "*.py[co]" -delete || die
	find "${S}"/translations -name "*.po" -delete || die
	rm "${S}"/translations/${PN}.pot || die

	sed -i \
		-e '/^application_file/s/os.path.dirname(sys.argv\[0\])/os.getcwd()/' \
		${MY_PN}.py || die
}

src_install() {
	touch __init__.py || die
	installme() {
		# install modules
		python_moduleinto ${PN}
		python_domodule images application ${MY_PN}.py \
			AUTHORS CHANGES COPYING DEPENDS TODO __init__.py

		# generate and install startup scripts
		sed \
			-e "s#@SITEDIR@#$(python_get_sitedir)/${PN}#" \
			"${FILESDIR}"/${PN} > "${T}"/${PN} || die
		python_doscript "${T}"/${PN}
	}

	# install for all enabled implementations
	python_foreach_impl installme

	insinto /usr/share/locale
	# correct gettext behavior
	if [[ -n "${LINGUAS+x}" ]] ; then
		for i in $(cd "${S}"/translations ; echo *) ; do
			if has ${i} ${LINGUAS} ; then
				doins -r "${S}"/translations/${i}
			fi
		done
	else
		doins -r "${S}"/translations/*
	fi

	newicon -s 64 images/${PN}_64.png ${PN}.png
	doicon -s scalable images/${PN}.svg
	newmenu ${MY_PN}.desktop ${PN}.desktop
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	gnome2_icon_cache_update

	# TODO: better description
	elog "optional dependencies:"
	elog "  dev-python/libgnome-python"
	elog "  media-libs/mutagen"
	elog "  x11-libs/vte:0[python] (terminal support)"
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	gnome2_icon_cache_update
}