[gentoo-commits] gentoo-x86 commit in net-misc/plowshare: ChangeLog plowshare-20131130.ebuild plowshare-20120609-r2.ebuild

[gentoo-commits] gentoo-x86 commit in net-misc/plowshare: ChangeLog plowshare-20131130.ebuild plowshare-20120609-r2.ebuild

[Bernard Cafarelli (voyageur)]

voyageur    14/01/05 21:33:45

  Modified:             ChangeLog
  Added:                plowshare-20131130.ebuild
  Removed:              plowshare-20120609-r2.ebuild
  Log:
  Version bump, drop old
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key C74525F2)

Revision  Changes    Path
1.25                 net-misc/plowshare/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/plowshare/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/plowshare/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/plowshare/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/plowshare/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog	9 Aug 2013 13:44:07 -0000	1.24
+++ ChangeLog	5 Jan 2014 21:33:45 -0000	1.25
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/plowshare
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/plowshare/ChangeLog,v 1.24 2013/08/09 13:44:07 axs Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/plowshare/ChangeLog,v 1.25 2014/01/05 21:33:45 voyageur Exp $
+
+*plowshare-20131130 (05 Jan 2014)
+
+  05 Jan 2014; Bernard Cafarelli <voyageur@gentoo.org>
+  -plowshare-20120609-r2.ebuild, +plowshare-20131130.ebuild:
+  Version bump, drop old
 
   09 Aug 2013; Ian Stakenvicius <axs@gentoo.org> plowshare-20120609-r2.ebuild,
   plowshare-20130520.ebuild:



1.1                  net-misc/plowshare/plowshare-20131130.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/plowshare/plowshare-20131130.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/plowshare/plowshare-20131130.ebuild?rev=1.1&content-type=text/plain

Index: plowshare-20131130.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/plowshare/plowshare-20131130.ebuild,v 1.1 2014/01/05 21:33:45 voyageur Exp $

EAPI=5

inherit bash-completion-r1

MY_P="${PN}4-snapshot-git${PV}.3c63b19"

DESCRIPTION="Command-line downloader and uploader for file-sharing websites"
HOMEPAGE="http://code.google.com/p/plowshare/"
SRC_URI="http://${PN}.googlecode.com/files/${MY_P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~x86"
IUSE="bash-completion +javascript scripts view-captcha"

RDEPEND="
	>=app-shells/bash-4
	|| ( app-text/recode ( dev-lang/perl dev-perl/HTML-Parser ) )
	|| ( media-gfx/imagemagick[tiff] media-gfx/graphicsmagick[imagemagick,tiff] )
	net-misc/curl
	sys-apps/util-linux
	javascript? ( || ( dev-lang/spidermonkey:0 dev-java/rhino ) )
	view-captcha? ( || ( media-gfx/aview media-libs/libcaca ) )"
DEPEND=""

S=${WORKDIR}/${MY_P}

# NOTES:
# javascript dep should be any javascript interpreter using /usr/bin/js

# Modules using detect_javascript
JS_MODULES="letitbit rapidgator zalaa zippyshare"

src_prepare() {
	if ! use javascript; then
		for module in ${JS_MODULES}; do
			sed -i -e "s:^${module}.*::" src/modules/config || die "${module} sed failed"
			rm src/modules/${module}.sh || die "${module} rm failed"
		done
	fi

	# Don't let 'make install' install docs.
	sed -i -e "/INSTALL.*DOCDIR/d" Makefile || die "sed failed"

	if use bash-completion; then
		sed -i -e \
			"s,/usr/local\(/share/plowshare4/modules/config\),${EPREFIX}/usr\1," \
			etc/plowshare.completion || die "sed failed"
	fi
}

src_compile() {
	# There is a Makefile but it's not compiling anything, let's not try.
	:
}

src_test() {
	# Disable tests because all of them need a working Internet connection.
	:
}

src_install() {
	emake DESTDIR="${D}" PREFIX="/usr" install

	dodoc AUTHORS README

	if use scripts; then
		exeinto /usr/bin/
		doexe contrib/{plowdown_{add_remote_loop,loop,parallel}}.sh
	fi

	if use bash-completion; then
		newbashcomp etc/${PN}.completion ${PN}
	fi
}

pkg_postinst() {
	if ! use javascript; then
		ewarn "Without javascript you will not be able to use:"
		ewarn " ${JS_MODULES}"
	fi
}