* [gentoo-commits] gentoo-x86 commit in media-gfx/graphicsmagick: graphicsmagick-1.3.19.ebuild ChangeLog metadata.xml
@ 2014-01-02 9:01 Tim Harder (radhermit)
0 siblings, 0 replies; only message in thread
From: Tim Harder (radhermit) @ 2014-01-02 9:01 UTC (permalink / raw
To: gentoo-commits
radhermit 14/01/02 09:01:49
Modified: ChangeLog metadata.xml
Added: graphicsmagick-1.3.19.ebuild
Log:
Version bump. Add webp use flag, fix perl bindings build issue (bug #456180, patch by Tiziano Müller), and fix generated config file flags (bug #479560).
(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)
Revision Changes Path
1.120 media-gfx/graphicsmagick/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphicsmagick/ChangeLog?rev=1.120&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphicsmagick/ChangeLog?rev=1.120&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphicsmagick/ChangeLog?r1=1.119&r2=1.120
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/graphicsmagick/ChangeLog,v
retrieving revision 1.119
retrieving revision 1.120
diff -u -r1.119 -r1.120
--- ChangeLog 3 Aug 2013 07:47:35 -0000 1.119
+++ ChangeLog 2 Jan 2014 09:01:49 -0000 1.120
@@ -1,6 +1,15 @@
# ChangeLog for media-gfx/graphicsmagick
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/graphicsmagick/ChangeLog,v 1.119 2013/08/03 07:47:35 ago Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/graphicsmagick/ChangeLog,v 1.120 2014/01/02 09:01:49 radhermit Exp $
+
+*graphicsmagick-1.3.19 (02 Jan 2014)
+
+ 02 Jan 2014; Tim Harder <radhermit@gentoo.org> +graphicsmagick-1.3.19.ebuild,
+ +files/graphicsmagick-1.3.19-flags.patch,
+ +files/graphicsmagick-1.3.19-freetype.patch,
+ +files/graphicsmagick-1.3.19-perl.patch, metadata.xml:
+ Version bump. Add webp use flag, fix perl bindings build issue (bug #456180,
+ patch by Tiziano Müller), and fix generated config file flags (bug #479560).
03 Aug 2013; Agostino Sarubbo <ago@gentoo.org> graphicsmagick-1.3.18.ebuild:
Stable for sparc, wrt bug #477606
1.12 media-gfx/graphicsmagick/metadata.xml
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphicsmagick/metadata.xml?rev=1.12&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphicsmagick/metadata.xml?rev=1.12&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphicsmagick/metadata.xml?r1=1.11&r2=1.12
Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/graphicsmagick/metadata.xml,v
retrieving revision 1.11
retrieving revision 1.12
diff -u -r1.11 -r1.12
--- metadata.xml 16 Jun 2012 16:22:59 -0000 1.11
+++ metadata.xml 2 Jan 2014 09:01:49 -0000 1.12
@@ -16,5 +16,6 @@
<flag name='modules'>Compile graphicsmagick with dynamically loadable modules</flag>
<flag name='q16'>Set storage quantum size to 16 (~2*memory)</flag>
<flag name='q32'>Set storage quantum size to 32 (~5*memory)</flag>
+ <flag name='webp'>Enable support for webp image format</flag>
</use>
</pkgmetadata>
1.1 media-gfx/graphicsmagick/graphicsmagick-1.3.19.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphicsmagick/graphicsmagick-1.3.19.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphicsmagick/graphicsmagick-1.3.19.ebuild?rev=1.1&content-type=text/plain
Index: graphicsmagick-1.3.19.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/graphicsmagick/graphicsmagick-1.3.19.ebuild,v 1.1 2014/01/02 09:01:49 radhermit Exp $
EAPI=5
inherit toolchain-funcs eutils autotools
MY_P=${P/graphicsm/GraphicsM}
DESCRIPTION="Collection of tools and libraries for many image formats"
HOMEPAGE="http://www.graphicsmagick.org/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.xz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
IUSE="bzip2 cxx debug fpx imagemagick jbig jpeg jpeg2k lcms lzma modules openmp
perl png postscript q16 q32 static-libs svg threads tiff truetype webp wmf X zlib"
RDEPEND=">=sys-devel/libtool-2.2.6b
bzip2? ( app-arch/bzip2 )
fpx? ( media-libs/libfpx )
imagemagick? ( !media-gfx/imagemagick )
jbig? ( media-libs/jbigkit )
jpeg? ( virtual/jpeg )
jpeg2k? ( media-libs/jasper )
lcms? ( media-libs/lcms:2 )
lzma? ( app-arch/xz-utils )
perl? ( dev-lang/perl )
png? ( media-libs/libpng:0 )
postscript? ( app-text/ghostscript-gpl )
svg? ( dev-libs/libxml2 )
tiff? ( media-libs/tiff:0 )
truetype? (
media-fonts/urw-fonts
>=media-libs/freetype-2
)
webp? ( media-libs/libwebp )
wmf? ( media-libs/libwmf )
X? (
x11-libs/libSM
x11-libs/libXext
)
zlib? ( sys-libs/zlib )"
DEPEND="${RDEPEND}"
S=${WORKDIR}/${MY_P}
src_prepare() {
epatch "${FILESDIR}"/${PN}-1.3.19-freetype.patch
epatch "${FILESDIR}"/${PN}-1.3.19-flags.patch
epatch "${FILESDIR}"/${PN}-1.3.19-perl.patch
epatch "${FILESDIR}"/${PN}-1.3.18-powerpc.patch
eautoreconf
}
src_configure() {
local depth=8
use q16 && depth=16
use q32 && depth=32
local openmp=disable
if use openmp && tc-has-openmp; then
openmp=enable
fi
econf \
--docdir="${EPREFIX}"/usr/share/doc/${PF} \
--htmldir="${EPREFIX}"/usr/share/doc/${PF}/html \
--${openmp}-openmp \
--enable-largefile \
--enable-shared \
$(use_enable static-libs static) \
$(use_enable debug prof) \
$(use_enable debug gcov) \
$(use_enable imagemagick magick-compat) \
$(use_with threads) \
$(use_with modules) \
--with-quantum-depth=${depth} \
--without-frozenpaths \
$(use_with cxx magick-plus-plus) \
$(use_with perl) \
--with-perl-options=INSTALLDIRS=vendor \
$(use_with bzip2 bzlib) \
$(use_with postscript dps) \
$(use_with fpx) \
--without-gslib \
$(use_with jbig) \
$(use_with webp) \
$(use_with jpeg) \
$(use_with jpeg2k jp2) \
--without-lcms \
$(use_with lcms lcms2) \
$(use_with lzma) \
$(use_with png) \
$(use_with tiff) \
$(use_with truetype ttf) \
$(use_with wmf) \
--with-fontpath="${EPREFIX}"/usr/share/fonts \
--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/urw-fonts \
--with-windows-font-dir="${EPREFIX}"/usr/share/fonts/corefonts \
$(use_with svg xml) \
$(use_with zlib) \
$(use_with X x)
}
src_compile() {
default
use perl && emake perl-build
}
src_test() {
unset DISPLAY # some perl tests fail when DISPLAY is set
default
}
src_install() {
default
if use perl; then
emake -C PerlMagick DESTDIR="${D}" install
find "${ED}" -type f -name perllocal.pod -exec rm -f {} +
find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} +
fi
find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2014-01-02 9:01 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-01-02 9:01 [gentoo-commits] gentoo-x86 commit in media-gfx/graphicsmagick: graphicsmagick-1.3.19.ebuild ChangeLog metadata.xml Tim Harder (radhermit)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox