[gentoo-commits] gentoo-x86 commit in dev-libs/wayland: wayland-1.3.0.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in dev-libs/wayland: wayland-1.3.0.ebuild ChangeLog

[Matt Turner (mattst88)]

mattst88    13/12/31 18:23:49

  Modified:             ChangeLog
  Added:                wayland-1.3.0.ebuild
  Log:
  Version bump to 1.3.0, bug 494900.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 974CA72A)

Revision  Changes    Path
1.32                 dev-libs/wayland/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/wayland/ChangeLog?rev=1.32&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/wayland/ChangeLog?rev=1.32&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/wayland/ChangeLog?r1=1.31&r2=1.32

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/wayland/ChangeLog,v
retrieving revision 1.31
retrieving revision 1.32
diff -u -r1.31 -r1.32
--- ChangeLog	31 Dec 2013 18:11:14 -0000	1.31
+++ ChangeLog	31 Dec 2013 18:23:49 -0000	1.32
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/wayland
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/wayland/ChangeLog,v 1.31 2013/12/31 18:11:14 mattst88 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/wayland/ChangeLog,v 1.32 2013/12/31 18:23:49 mattst88 Exp $
+
+*wayland-1.3.0 (31 Dec 2013)
+
+  31 Dec 2013; Matt Turner <mattst88@gentoo.org> +wayland-1.3.0.ebuild:
+  Version bump to 1.3.0, bug 494900.
 
   31 Dec 2013; Matt Turner <mattst88@gentoo.org> wayland-1.2.1-r1.ebuild:
   Add missing MULTILIB_USEDEP to dependencies.



1.1                  dev-libs/wayland/wayland-1.3.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/wayland/wayland-1.3.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/wayland/wayland-1.3.0.ebuild?rev=1.1&content-type=text/plain

Index: wayland-1.3.0.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/wayland/wayland-1.3.0.ebuild,v 1.1 2013/12/31 18:23:49 mattst88 Exp $

EAPI=5

if [[ ${PV} = 9999* ]]; then
	EGIT_REPO_URI="git://anongit.freedesktop.org/git/${PN}/${PN}"
	GIT_ECLASS="git-r3"
	EXPERIMENTAL="true"
	AUTOTOOLS_AUTORECONF=1
fi

inherit autotools-multilib toolchain-funcs $GIT_ECLASS

DESCRIPTION="Wayland protocol libraries"
HOMEPAGE="http://wayland.freedesktop.org/"

if [[ $PV = 9999* ]]; then
	SRC_URI="${SRC_PATCHES}"
	KEYWORDS=""
else
	SRC_URI="http://wayland.freedesktop.org/releases/${P}.tar.xz"
	KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~x86"
fi

LICENSE="MIT"
SLOT="0"
IUSE="doc static-libs"

RDEPEND="dev-libs/expat[${MULTILIB_USEDEP}]
	virtual/libffi[${MULTILIB_USEDEP}]"
DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen )
	virtual/pkgconfig"

src_prepare() {
	# Remove resources-test from TESTS as it has failed since it was added.
	sed -i -e 's/	resources-test$(EXEEXT)/	$(NULL)/' ${S}/tests/Makefile.in || die

	autotools-multilib_src_prepare
}

src_configure() {
	local myeconfargs=(
		$(use_enable doc documentation)
	)
	if tc-is-cross-compiler ; then
		myeconfargs+=( --disable-scanner )
	fi
	if ! multilib_build_binaries; then
		myeconfargs+=( --disable-documentation )
	fi

	autotools-multilib_src_configure
}

src_test() {
	export XDG_RUNTIME_DIR="${T}/runtime-dir"
	mkdir "${XDG_RUNTIME_DIR}" || die
	chmod 0700 "${XDG_RUNTIME_DIR}" || die

	autotools-multilib_src_test
}