* [gentoo-commits] gentoo-x86 commit in media-tv/xbmc: xbmc-12.3.ebuild ChangeLog
@ 2013-12-31 0:31 Mike Frysinger (vapier)
0 siblings, 0 replies; 2+ messages in thread
From: Mike Frysinger (vapier) @ 2013-12-31 0:31 UTC (permalink / raw
To: gentoo-commits
vapier 13/12/31 00:31:38
Modified: ChangeLog
Added: xbmc-12.3.ebuild
Log:
Version bump #496496 by Charles Nérot.
(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key FB7C4156)
Revision Changes Path
1.199 media-tv/xbmc/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/ChangeLog?rev=1.199&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/ChangeLog?rev=1.199&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/ChangeLog?r1=1.198&r2=1.199
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-tv/xbmc/ChangeLog,v
retrieving revision 1.198
retrieving revision 1.199
diff -u -r1.198 -r1.199
--- ChangeLog 31 Dec 2013 00:30:11 -0000 1.198
+++ ChangeLog 31 Dec 2013 00:31:38 -0000 1.199
@@ -1,6 +1,11 @@
# ChangeLog for media-tv/xbmc
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/ChangeLog,v 1.198 2013/12/31 00:30:11 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/ChangeLog,v 1.199 2013/12/31 00:31:38 vapier Exp $
+
+*xbmc-12.3 (31 Dec 2013)
+
+ 31 Dec 2013; Mike Frysinger <vapier@gentoo.org> +xbmc-12.3.ebuild:
+ Version bump #496496 by Charles Nérot.
30 Dec 2013; Mike Frysinger <vapier@gentoo.org> xbmc-9999.ebuild:
Always require java for live git ebuilds now #488118 by hal.
1.1 media-tv/xbmc/xbmc-12.3.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-12.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-12.3.ebuild?rev=1.1&content-type=text/plain
Index: xbmc-12.3.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/xbmc-12.3.ebuild,v 1.1 2013/12/31 00:31:38 vapier Exp $
EAPI="5"
# Does not work with py3 here
# It might work with py:2.5 but I didn't test that
PYTHON_COMPAT=( python{2_6,2_7} )
PYTHON_REQ_USE="sqlite"
inherit eutils python-single-r1 multiprocessing autotools
BACKPORTS_VERSION=1
case ${PV} in
9999)
EGIT_REPO_URI="git://github.com/xbmc/xbmc.git"
inherit git-2
SRC_URI="!java? ( mirror://gentoo/${P}-20121224-generated-addons.tar.xz )"
;;
*_alpha*|*_beta*|*_rc*)
MY_PV="Frodo_${PV#*_}"
MY_P="${PN}-${MY_PV}"
SRC_URI="https://github.com/xbmc/xbmc/archive/${MY_PV}.tar.gz -> ${P}.tar.gz
!java? ( mirror://gentoo/${P}-generated-addons.tar.xz )"
KEYWORDS="~amd64 ~x86"
;;
*)
MY_P=${P/_/-*_}
SRC_URI="http://mirrors.xbmc.org/releases/source/${MY_P}.tar.gz
mirror://gentoo/${PN}_backports-12-${BACKPORTS_VERSION}.tar.bz2
mirror://gentoo/${P}-generated-addons.tar.xz"
KEYWORDS="~amd64 ~x86"
;;
esac
DESCRIPTION="XBMC is a free and open source media-player and entertainment hub"
HOMEPAGE="http://xbmc.org/"
LICENSE="GPL-2"
SLOT="0"
IUSE="airplay alsa altivec avahi bluetooth bluray caps cec css debug gles goom java joystick midi mysql neon nfs +opengl profile +projectm pulseaudio pvr +rsxs rtmp +samba +sdl sse sse2 sftp udev upnp +usb vaapi vdpau webserver +X +xrandr"
REQUIRED_USE="
pvr? ( mysql )
rsxs? ( X )
X? ( sdl )
xrandr? ( X )
"
COMMON_DEPEND="${PYTHON_DEPS}
app-arch/bzip2
app-arch/unzip
app-arch/zip
app-i18n/enca
airplay? ( app-pda/libplist )
dev-libs/boost
dev-libs/fribidi
dev-libs/libcdio[-minimal]
cec? ( >=dev-libs/libcec-2.1 )
dev-libs/libpcre[cxx]
>=dev-libs/lzo-2.04
dev-libs/tinyxml[stl]
dev-libs/yajl
dev-python/simplejson[${PYTHON_USEDEP}]
media-libs/alsa-lib
media-libs/flac
media-libs/fontconfig
media-libs/freetype
>=media-libs/glew-1.5.6
media-libs/jasper
media-libs/jbigkit
>=media-libs/libass-0.9.7
bluray? ( media-libs/libbluray )
css? ( media-libs/libdvdcss )
media-libs/libmad
media-libs/libmodplug
media-libs/libmpeg2
media-libs/libogg
media-libs/libpng
projectm? ( media-libs/libprojectm )
media-libs/libsamplerate
sdl? ( media-libs/libsdl[audio,opengl,video,X] )
alsa? ( media-libs/libsdl[alsa] )
>=media-libs/taglib-1.8
media-libs/libvorbis
sdl? (
media-libs/sdl-gfx
>=media-libs/sdl-image-1.2.10[gif,jpeg,png]
media-libs/sdl-mixer
media-libs/sdl-sound
)
media-libs/tiff
pulseaudio? ( media-sound/pulseaudio )
media-sound/wavpack
|| ( media-libs/libpostproc media-video/ffmpeg:0 )
>=virtual/ffmpeg-0.6[encode]
rtmp? ( media-video/rtmpdump )
avahi? ( net-dns/avahi )
nfs? ( net-fs/libnfs )
webserver? ( net-libs/libmicrohttpd[messages] )
sftp? ( net-libs/libssh[sftp] )
net-misc/curl
samba? ( >=net-fs/samba-3.4.6[smbclient] )
bluetooth? ( net-wireless/bluez )
sys-apps/dbus
caps? ( sys-libs/libcap )
sys-libs/zlib
virtual/jpeg
usb? ( virtual/libusb )
mysql? ( virtual/mysql )
opengl? (
virtual/glu
virtual/opengl
)
gles? ( virtual/opengl )
vaapi? ( x11-libs/libva[opengl] )
vdpau? (
|| ( x11-libs/libvdpau >=x11-drivers/nvidia-drivers-180.51 )
virtual/ffmpeg[vdpau]
)
X? (
x11-apps/xdpyinfo
x11-apps/mesa-progs
x11-libs/libXinerama
xrandr? ( x11-libs/libXrandr )
x11-libs/libXrender
)"
RDEPEND="${COMMON_DEPEND}
udev? ( sys-fs/udisks:0 sys-power/upower )"
DEPEND="${COMMON_DEPEND}
app-arch/xz-utils
dev-lang/swig
dev-util/gperf
X? ( x11-proto/xineramaproto )
dev-util/cmake
x86? ( dev-lang/nasm )
java? ( virtual/jre )"
S=${WORKDIR}/${MY_P}-Frodo
pkg_setup() {
python-single-r1_pkg_setup
}
src_unpack() {
[[ ${PV} == "9999" ]] && git-2_src_unpack || default
}
src_prepare() {
epatch "${FILESDIR}"/${PN}-12.1-nomythtv.patch
epatch "${FILESDIR}"/${PN}-9999-no-arm-flags.patch #400617
# Backported fixes
EPATCH_MULTI_MSG="Applying patches backported from master..." \
EPATCH_SUFFIX="patch" \
epatch "${WORKDIR}/${PN}_backports"
# The mythtv patch touches configure.ac, so force a regen
rm -f configure
# some dirs ship generated autotools, some dont
multijob_init
local d
for d in $(printf 'f:\n\t@echo $(BOOTSTRAP_TARGETS)\ninclude bootstrap.mk\n' | emake -f - f) ; do
[[ -e ${d} ]] && continue
pushd ${d/%configure/.} >/dev/null || die
AT_NOELIBTOOLIZE="yes" AT_TOPLEVEL_EAUTORECONF="yes" \
multijob_child_init eautoreconf
popd >/dev/null
done
multijob_finish
elibtoolize
# Disable internal func checks as our USE/DEPEND
# stuff handles this just fine already #408395
export ac_cv_lib_avcodec_ff_vdpau_vc1_decode_picture=yes
local squish #290564
use altivec && squish="-DSQUISH_USE_ALTIVEC=1 -maltivec"
use sse && squish="-DSQUISH_USE_SSE=1 -msse"
use sse2 && squish="-DSQUISH_USE_SSE=2 -msse2"
sed -i \
-e '/^CXXFLAGS/{s:-D[^=]*=.::;s:-m[[:alnum:]]*::}' \
-e "1iCXXFLAGS += ${squish}" \
lib/libsquish/Makefile.in || die
# Fix XBMC's final version string showing as "exported"
# instead of the SVN revision number.
export HAVE_GIT=no GIT_REV=${EGIT_VERSION:-exported}
# avoid long delays when powerkit isn't running #348580
sed -i \
-e '/dbus_connection_send_with_reply_and_block/s:-1:3000:' \
xbmc/linux/*.cpp || die
epatch_user #293109
# Tweak autotool timestamps to avoid regeneration
find . -type f -exec touch -r configure {} +
}
src_configure() {
# Disable documentation generation
export ac_cv_path_LATEX=no
# Avoid help2man
export HELP2MAN=$(type -P help2man || echo true)
# No configure flage for this #403561
export ac_cv_lib_bluetooth_hci_devid=$(usex bluetooth)
# Requiring java is asine #434662
export ac_cv_path_JAVA_EXE=$(which $(usex java java true))
econf \
--docdir=/usr/share/doc/${PF} \
--disable-ccache \
--disable-optimizations \
--enable-external-libraries \
--enable-gl \
$(use_enable airplay) \
$(use_enable avahi) \
$(use_enable bluray libbluray) \
$(use_enable caps libcap) \
$(use_enable cec libcec) \
$(use_enable css dvdcss) \
$(use_enable debug) \
$(use_enable gles) \
$(use_enable goom) \
--disable-hal \
$(use_enable joystick) \
$(use_enable midi mid) \
$(use_enable mysql) \
$(use_enable neon) \
$(use_enable nfs) \
$(use_enable opengl gl) \
$(use_enable profile profiling) \
$(use_enable projectm) \
$(use_enable pulseaudio pulse) \
$(use_enable pvr mythtv) \
$(use_enable rsxs) \
$(use_enable rtmp) \
$(use_enable samba) \
$(use_enable sdl) \
$(use_enable sftp ssh) \
$(use_enable usb libusb) \
$(use_enable upnp) \
$(use_enable vaapi) \
$(use_enable vdpau) \
$(use_enable webserver) \
$(use_enable X x11) \
$(use_enable xrandr)
}
src_install() {
default
rm "${ED}"/usr/share/doc/*/{LICENSE.GPL,copying.txt}*
domenu tools/Linux/xbmc.desktop
newicon tools/Linux/xbmc-48x48.png xbmc.png
python_domodule tools/EventClients/lib/python/xbmcclient.py
python_newscript "tools/EventClients/Clients/XBMC Send/xbmc-send.py" xbmc-send
}
pkg_postinst() {
elog "Visit http://wiki.xbmc.org/?title=XBMC_Online_Manual"
}
^ permalink raw reply [flat|nested] 2+ messages in thread
* [gentoo-commits] gentoo-x86 commit in media-tv/xbmc: xbmc-12.3.ebuild ChangeLog
@ 2013-12-31 19:18 Mike Frysinger (vapier)
0 siblings, 0 replies; 2+ messages in thread
From: Mike Frysinger (vapier) @ 2013-12-31 19:18 UTC (permalink / raw
To: gentoo-commits
vapier 13/12/31 19:18:32
Modified: xbmc-12.3.ebuild ChangeLog
Log:
Add patch from upstream for building on cpus w/out sse2 #475266 by Jose Quinteiro.
(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key D2E96200)
Revision Changes Path
1.2 media-tv/xbmc/xbmc-12.3.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-12.3.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-12.3.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-12.3.ebuild?r1=1.1&r2=1.2
Index: xbmc-12.3.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-tv/xbmc/xbmc-12.3.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- xbmc-12.3.ebuild 31 Dec 2013 00:31:38 -0000 1.1
+++ xbmc-12.3.ebuild 31 Dec 2013 19:18:32 -0000 1.2
@@ -1,6 +1,6 @@
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/xbmc-12.3.ebuild,v 1.1 2013/12/31 00:31:38 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/xbmc-12.3.ebuild,v 1.2 2013/12/31 19:18:32 vapier Exp $
EAPI="5"
@@ -150,6 +150,7 @@
src_prepare() {
epatch "${FILESDIR}"/${PN}-12.1-nomythtv.patch
epatch "${FILESDIR}"/${PN}-9999-no-arm-flags.patch #400617
+ epatch "${FILESDIR}"/${PN}-12.3-no-sse2.patch #475266
# Backported fixes
EPATCH_MULTI_MSG="Applying patches backported from master..." \
EPATCH_SUFFIX="patch" \
1.200 media-tv/xbmc/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/ChangeLog?rev=1.200&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/ChangeLog?rev=1.200&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/ChangeLog?r1=1.199&r2=1.200
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-tv/xbmc/ChangeLog,v
retrieving revision 1.199
retrieving revision 1.200
diff -u -r1.199 -r1.200
--- ChangeLog 31 Dec 2013 00:31:38 -0000 1.199
+++ ChangeLog 31 Dec 2013 19:18:32 -0000 1.200
@@ -1,6 +1,11 @@
# ChangeLog for media-tv/xbmc
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/ChangeLog,v 1.199 2013/12/31 00:31:38 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/ChangeLog,v 1.200 2013/12/31 19:18:32 vapier Exp $
+
+ 31 Dec 2013; Mike Frysinger <vapier@gentoo.org>
+ +files/xbmc-12.3-no-sse2.patch, xbmc-12.3.ebuild:
+ Add patch from upstream for building on cpus w/out sse2 #475266 by Jose
+ Quinteiro.
*xbmc-12.3 (31 Dec 2013)
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2013-12-31 19:18 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-12-31 0:31 [gentoo-commits] gentoo-x86 commit in media-tv/xbmc: xbmc-12.3.ebuild ChangeLog Mike Frysinger (vapier)
-- strict thread matches above, loose matches on Subject: below --
2013-12-31 19:18 Mike Frysinger (vapier)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox