[gentoo-commits] gentoo-x86 commit in games-strategy/openra: ChangeLog openra-20131223-r1.ebuild openra-20131223.ebuild

[gentoo-commits] gentoo-x86 commit in games-strategy/openra: ChangeLog openra-20131223-r1.ebuild openra-20131223.ebuild

[Julian Ospald (hasufell)]

hasufell    13/12/24 21:46:19

  Modified:             ChangeLog
  Added:                openra-20131223-r1.ebuild
  Removed:              openra-20131223.ebuild
  Log:
  revbump, rm obsolete cg useflag, fix sdl2 support
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

Revision  Changes    Path
1.25                 games-strategy/openra/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/openra/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/openra/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/openra/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-strategy/openra/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog	22 Dec 2013 22:37:14 -0000	1.24
+++ ChangeLog	24 Dec 2013 21:46:19 -0000	1.25
@@ -1,6 +1,12 @@
 # ChangeLog for games-strategy/openra
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-strategy/openra/ChangeLog,v 1.24 2013/12/22 22:37:14 hasufell Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-strategy/openra/ChangeLog,v 1.25 2013/12/24 21:46:19 hasufell Exp $
+
+*openra-20131223-r1 (24 Dec 2013)
+
+  24 Dec 2013; Julian Ospald <hasufell@gentoo.org> -openra-20131223.ebuild,
+  +openra-20131223-r1.ebuild, +files/openra-20131223-sdl2.patch:
+  revbump, rm obsolete cg useflag, fix sdl2 support
 
 *openra-20131223 (22 Dec 2013)
 



1.1                  games-strategy/openra/openra-20131223-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/openra/openra-20131223-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/openra/openra-20131223-r1.ebuild?rev=1.1&content-type=text/plain

Index: openra-20131223-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-strategy/openra/openra-20131223-r1.ebuild,v 1.1 2013/12/24 21:46:19 hasufell Exp $

EAPI=5

inherit eutils mono-env gnome2-utils vcs-snapshot games

DESCRIPTION="A free RTS engine supporting games like Command & Conquer and Red Alert"
HOMEPAGE="http://open-ra.org/"
SRC_URI="https://github.com/OpenRA/OpenRA/tarball/release-${PV} -> ${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="tools"

DEPEND="dev-dotnet/libgdiplus
	dev-lang/mono
	media-libs/freetype:2[X]
	|| (
		media-libs/libsdl[X,opengl,video]
		media-libs/libsdl2[X,opengl,video]
	)
	media-libs/openal
	virtual/jpeg
	virtual/opengl"
RDEPEND="${DEPEND}"

pkg_setup() {
	mono-env_pkg_setup
	games_pkg_setup
}

src_unpack() {
	vcs-snapshot_src_unpack
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-sdl2.patch
	# register game-version
	sed \
		-e "/Version/s/{DEV_VERSION}/release-${PV}/" \
		-i mods/{ra,cnc,d2k}/mod.yaml || die
}

src_compile() {
	emake $(usex tools "all" "")
}

src_install() {
	emake \
		bindir="${GAMES_BINDIR}" \
		libexecdir="$(games_get_libdir)" \
		DESTDIR="${D}" \
		$(usex tools "install-all" "install")

	# icons
	insinto /usr/share/icons/
	doins -r packaging/linux/hicolor

	# desktop entries
	make_desktop_entry "${PN} Game.Mods=cnc" "OpenRA CNC" ${PN}
	make_desktop_entry "${PN} Game.Mods=ra" "OpenRA RA" ${PN}
	make_desktop_entry "${PN} Game.Mods=d2k" "OpenRA Dune2k" ${PN}
	make_desktop_entry "${PN}-editor" "OpenRA Map Editor" ${PN}

	dodoc "${FILESDIR}"/README.gentoo README.md CHANGELOG

	# file permissions
	prepgamesdirs
}

pkg_preinst() {
	games_pkg_preinst
	gnome2_icon_savelist
}

pkg_postinst() {
	games_pkg_postinst
	gnome2_icon_cache_update

	elog "optional dependencies:"
	elog "  media-gfx/nvidia-cg-toolkit (fallback renderer if OpenGL fails)"
	elog
	elog "you might also want to emerge media-libs/libsdl2 specifically,"
	elog "because ${PN} supports both sdl1.2 and sdl2, but the ebuild only"
	elog "pulls in one of them, prefering sdl1.2."
}

pkg_postrm() {
	gnome2_icon_cache_update
}