[gentoo-commits] gentoo-x86 commit in dev-java/logback: metadata.xml logback-1.0.13.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in dev-java/logback: metadata.xml logback-1.0.13.ebuild ChangeLog

[Johann Schmitz (ercpe)]

ercpe       13/12/23 07:38:53

  Added:                metadata.xml logback-1.0.13.ebuild ChangeLog
  Log:
  Added ebuild for logback
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 77C501ED)

Revision  Changes    Path
1.1                  dev-java/logback/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/logback/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/logback/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<herd>java</herd>
	<use>
		<flag name="tomcat">Builds Apache Tomcat support</flag>
	</use>
</pkgmetadata>




1.1                  dev-java/logback/logback-1.0.13.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/logback/logback-1.0.13.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/logback/logback-1.0.13.ebuild?rev=1.1&content-type=text/plain

Index: logback-1.0.13.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/logback/logback-1.0.13.ebuild,v 1.1 2013/12/23 07:38:53 ercpe Exp $

EAPI=5

JAVA_PKG_IUSE="doc source examples"

inherit java-pkg-2 java-ant-2

DESCRIPTION="A generic, reliable, fast & flexible logging framework for Java"
HOMEPAGE="http://logback.qos.ch/"
SRC_URI="http://logback.qos.ch/dist/${PN}-${PV}.tar.gz
		http://dev.gentoo.org/~ercpe/distfiles/${CATEGORY}/${PN}/${P}-build.tar.bz2"

LICENSE="|| ( EPL-1.0 LGPL-2.1 )"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="tomcat"

CDEPEND="dev-java/janino:0
	dev-java/jansi:0
	java-virtuals/javamail:0
	java-virtuals/servlet-api:2.5
	dev-java/slf4j-api:0
	tomcat? ( www-servers/tomcat:7 )
"

RDEPEND="${CDEPEND}
	>=virtual/jre-1.5"
DEPEND="${CDEPEND}
	>=virtual/jdk-1.5"

JAVA_ANT_REWRITE_CLASSPATH="true"
EANT_GENTOO_CLASSPATH="janino,jansi,javamail,servlet-api-2.5,slf4j-api"
EANT_GENTOO_CLASSPATH_EXTRA="${S}/${PN}-core/target/${PN}-core.jar"

java_prepare() {
	find "${S}" -name "*.jar" -delete || die

	use tomcat || rm -r "${S}"/${PN}-access/src/main/java/ch/qos/logback/access/tomcat/ || die
	# remove the next line when we have jetty in the tree 
	rm -r "${S}"/${PN}-access/src/main/java/ch/qos/logback/access/jetty/ || die

	use tomcat && EANT_GENTOO_CLASSPATH+=",tomcat-7"
}

src_install() {
	java-pkg_dojar "${S}"/${PN}-core/target/${PN}-core.jar
	java-pkg_dojar "${S}"/${PN}-access/target/${PN}-access.jar

	use source && java-pkg_dosrc "${S}"/${PN}-core/src/main/java "${S}"/${PN}-access/src/main/java
	use doc && java-pkg_dojavadoc "${S}"/${PN}-core/target/site/apidocs
	use examples && java-pkg_doexamples "${S}"/${PN}-examples/src/main/java/chapters/*
}



1.1                  dev-java/logback/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/logback/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/logback/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for dev-java/logback
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/logback/ChangeLog,v 1.1 2013/12/23 07:38:53 ercpe Exp $

*logback-1.0.13 (23 Dec 2013)

  23 Dec 2013; Johann Schmitz <ercpe@gentoo.org> +logback-1.0.13.ebuild,
  +metadata.xml:
  Added ebuild for logback