[gentoo-commits] gentoo-x86 commit in net-analyzer/fail2ban: fail2ban-0.8.11.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in net-analyzer/fail2ban: fail2ban-0.8.11.ebuild ChangeLog

[Jeroen Roovers (jer)]

jer         13/12/21 15:30:25

  Modified:             ChangeLog
  Added:                fail2ban-0.8.11.ebuild
  Log:
  Version bump (bug #491288 by Manuel Rüger).
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.118                net-analyzer/fail2ban/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/fail2ban/ChangeLog?rev=1.118&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/fail2ban/ChangeLog?rev=1.118&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/fail2ban/ChangeLog?r1=1.117&r2=1.118

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/fail2ban/ChangeLog,v
retrieving revision 1.117
retrieving revision 1.118
diff -u -r1.117 -r1.118
--- ChangeLog	26 Sep 2013 00:26:12 -0000	1.117
+++ ChangeLog	21 Dec 2013 15:30:25 -0000	1.118
@@ -1,6 +1,11 @@
 # ChangeLog for net-analyzer/fail2ban
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/fail2ban/ChangeLog,v 1.117 2013/09/26 00:26:12 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/fail2ban/ChangeLog,v 1.118 2013/12/21 15:30:25 jer Exp $
+
+*fail2ban-0.8.11 (21 Dec 2013)
+
+  21 Dec 2013; Jeroen Roovers <jer@gentoo.org> +fail2ban-0.8.11.ebuild:
+  Version bump (bug #491288 by Manuel Rüger).
 
   26 Sep 2013; Jeroen Roovers <jer@gentoo.org> -fail2ban-0.8.10.ebuild:
   Old.



1.1                  net-analyzer/fail2ban/fail2ban-0.8.11.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/fail2ban/fail2ban-0.8.11.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/fail2ban/fail2ban-0.8.11.ebuild?rev=1.1&content-type=text/plain

Index: fail2ban-0.8.11.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/fail2ban/fail2ban-0.8.11.ebuild,v 1.1 2013/12/21 15:30:25 jer Exp $

EAPI=5
PYTHON_COMPAT=( python2_{6,7} )
DISTUTILS_SINGLE_IMPL=yes

inherit distutils-r1 systemd vcs-snapshot

DESCRIPTION="Bans IP that make too many password failures"
HOMEPAGE="http://www.fail2ban.org/"
SRC_URI="https://github.com/${PN}/${PN}/tarball/${PV} -> ${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="selinux"

DEPEND="selinux? ( sec-policy/selinux-fail2ban )"
RDEPEND="net-misc/whois
	virtual/mta
	virtual/logger
	net-firewall/iptables
	selinux? ( sec-policy/selinux-fail2ban )"

src_prepare() {
	sed -i -e 's|/var\(/run/fail2ban\)|\1|g' $( find . -type f ) || die
}

src_test() {
	./${PN}-testcases-all
}

DOCS=( ChangeLog DEVELOP README.md THANKS TODO doc/run-rootless.txt )

src_install() {
	distutils-r1_src_install

	rm -rf "${D}"/usr/share/doc/${PN}

	# not FILESDIR
	newconfd files/gentoo-confd ${PN}
	newinitd files/gentoo-initd ${PN}
	systemd_dounit files/${PN}.service
	systemd_dotmpfilesd files/${PN}-tmpfiles.conf
	doman man/*.1

	# Use INSTALL_MASK  if you do not want to touch /etc/logrotate.d.
	# See http://thread.gmane.org/gmane.linux.gentoo.devel/35675
	insinto /etc/logrotate.d
	newins files/${PN}-logrotate ${PN}
}

pkg_preinst() {
	has_version "<${CATEGORY}/${PN}-0.7"
	previous_less_than_0_7=$?
}

pkg_postinst() {
	if [[ $previous_less_than_0_7 = 0 ]] ; then
		elog
		elog "Configuration files are now in /etc/fail2ban/"
		elog "You probably have to manually update your configuration"
		elog "files before restarting Fail2ban!"
		elog
		elog "Fail2ban is not installed under /usr/lib anymore. The"
		elog "new location is under /usr/share."
		elog
		elog "You are upgrading from version 0.6.x, please see:"
		elog "http://www.fail2ban.org/wiki/index.php/HOWTO_Upgrade_from_0.6_to_0.8"
	fi
	if ! has_version ${CATEGORY}/${PN} && \
		! has_version dev-python/pyinotify && ! has_version app-admin/gamin; then
		elog "For most jail.conf configurations, it is recommended you install either"
		elog "dev-python/pyinotify or app-admin/gamin (in order of preference)"
		elog "to control how log file modifications are detected"
	fi
}