* [gentoo-commits] gentoo-x86 commit in sys-boot/grub: grub-9999-r1.ebuild grub-2.02_beta1.ebuild ChangeLog
@ 2013-12-19 3:25 Mike Gilbert (floppym)
0 siblings, 0 replies; 2+ messages in thread
From: Mike Gilbert (floppym) @ 2013-12-19 3:25 UTC (permalink / raw
To: gentoo-commits
floppym 13/12/19 03:25:54
Modified: grub-9999-r1.ebuild ChangeLog
Added: grub-2.02_beta1.ebuild
Log:
Version bump.
(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)
Revision Changes Path
1.7 sys-boot/grub/grub-9999-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/grub-9999-r1.ebuild?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/grub-9999-r1.ebuild?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/grub-9999-r1.ebuild?r1=1.6&r2=1.7
Index: grub-9999-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-boot/grub/grub-9999-r1.ebuild,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- grub-9999-r1.ebuild 9 Dec 2013 23:07:13 -0000 1.6
+++ grub-9999-r1.ebuild 19 Dec 2013 03:25:54 -0000 1.7
@@ -1,6 +1,6 @@
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-boot/grub/grub-9999-r1.ebuild,v 1.6 2013/12/09 23:07:13 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-boot/grub/grub-9999-r1.ebuild,v 1.7 2013/12/19 03:25:54 floppym Exp $
EAPI=5
@@ -18,7 +18,7 @@
if [[ ${PV} != 9999 ]]; then
if [[ ${PV} == *_alpha* || ${PV} == *_beta* || ${PV} == *_rc* ]]; then
- MY_P=${P/_/~}
+ MY_P="${P/_/~}"
SRC_URI="mirror://gnu-alpha/${PN}/${MY_P}.tar.xz"
S=${WORKDIR}/${MY_P}
else
@@ -36,10 +36,10 @@
fi
DEJAVU=dejavu-sans-ttf-2.34
-UNIFONT=unifont-5.1.20080820.pcf
+UNIFONT=unifont-6.3.20131217
SRC_URI+=" truetype? (
mirror://sourceforge/dejavu/${DEJAVU}.zip
- http://unifoundry.com/${UNIFONT}.gz
+ http://unifoundry.com/pub/${UNIFONT}/${UNIFONT}.pcf.gz
)"
DESCRIPTION="GNU GRUB boot loader"
@@ -172,7 +172,7 @@
setup_fonts() {
ln -s "${WORKDIR}/${DEJAVU}/ttf/DejaVuSans.ttf" DejaVuSans.ttf || die
- ln -s "${WORKDIR}/${UNIFONT}" unifont.pcf || die
+ ln -s "${WORKDIR}/${UNIFONT}.pcf" unifont.pcf || die
}
grub_configure() {
1.297 sys-boot/grub/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/ChangeLog?rev=1.297&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/ChangeLog?rev=1.297&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/ChangeLog?r1=1.296&r2=1.297
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-boot/grub/ChangeLog,v
retrieving revision 1.296
retrieving revision 1.297
diff -u -r1.296 -r1.297
--- ChangeLog 9 Dec 2013 23:27:48 -0000 1.296
+++ ChangeLog 19 Dec 2013 03:25:54 -0000 1.297
@@ -1,6 +1,12 @@
# ChangeLog for sys-boot/grub
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-boot/grub/ChangeLog,v 1.296 2013/12/09 23:27:48 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-boot/grub/ChangeLog,v 1.297 2013/12/19 03:25:54 floppym Exp $
+
+*grub-2.02_beta1 (19 Dec 2013)
+
+ 19 Dec 2013; Mike Gilbert <floppym@gentoo.org> +grub-2.02_beta1.ebuild,
+ grub-9999-r1.ebuild:
+ Version bump.
09 Dec 2013; Mike Gilbert <floppym@gentoo.org>
+files/grub-2.00-freetype-2.5.1.patch, grub-2.00_p5107-r2.ebuild:
1.1 sys-boot/grub/grub-2.02_beta1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/grub-2.02_beta1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/grub-2.02_beta1.ebuild?rev=1.1&content-type=text/plain
Index: grub-2.02_beta1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-boot/grub/grub-2.02_beta1.ebuild,v 1.1 2013/12/19 03:25:54 floppym Exp $
EAPI=5
if [[ ${PV} == 9999 ]]; then
AUTOTOOLS_AUTORECONF=1
GRUB_AUTOGEN=1
fi
if [[ -n ${GRUB_AUTOGEN} ]]; then
PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} )
inherit python-any-r1
fi
inherit autotools-utils bash-completion-r1 eutils flag-o-matic mount-boot multibuild pax-utils toolchain-funcs versionator
if [[ ${PV} != 9999 ]]; then
if [[ ${PV} == *_alpha* || ${PV} == *_beta* || ${PV} == *_rc* ]]; then
MY_P="${P/_/~}"
SRC_URI="mirror://gnu-alpha/${PN}/${MY_P}.tar.xz"
S=${WORKDIR}/${MY_P}
else
SRC_URI="mirror://gnu/${PN}/${P}.tar.xz
mirror://gentoo/${P}.tar.xz
http://dev.gentoo.org/~floppym/dist/${P}.tar.xz"
S=${WORKDIR}/${P%_*}
fi
KEYWORDS="~amd64 ~x86"
PATCHES=()
else
inherit git-r3
EGIT_REPO_URI="git://git.sv.gnu.org/grub.git
http://git.savannah.gnu.org/r/grub.git"
fi
DEJAVU=dejavu-sans-ttf-2.34
UNIFONT=unifont-6.3.20131217
SRC_URI+=" truetype? (
mirror://sourceforge/dejavu/${DEJAVU}.zip
http://unifoundry.com/pub/${UNIFONT}/${UNIFONT}.pcf.gz
)"
DESCRIPTION="GNU GRUB boot loader"
HOMEPAGE="http://www.gnu.org/software/grub/"
# Includes licenses for dejavu and unifont
LICENSE="GPL-3 truetype? ( BitstreamVera GPL-2-with-font-exception )"
SLOT="2"
IUSE="debug device-mapper doc efiemu mount +multislot nls static sdl test truetype libzfs"
GRUB_ALL_PLATFORMS=(
# everywhere:
emu
# mips only:
qemu-mips yeeloong
# amd64, x86, ppc, ppc64:
ieee1275
# amd64, x86:
coreboot multiboot efi-32 pc qemu
# amd64, ia64:
efi-64
)
IUSE+=" ${GRUB_ALL_PLATFORMS[@]/#/grub_platforms_}"
REQUIRED_USE="grub_platforms_qemu? ( truetype )
grub_platforms_yeeloong? ( truetype )"
# os-prober: Used on runtime to detect other OSes
# xorriso (dev-libs/libisoburn): Used on runtime for mkrescue
RDEPEND="
app-arch/xz-utils
>=sys-libs/ncurses-5.2-r5
debug? (
sdl? ( media-libs/libsdl )
)
device-mapper? ( >=sys-fs/lvm2-2.02.45 )
libzfs? ( sys-fs/zfs )
mount? ( sys-fs/fuse )
truetype? ( media-libs/freetype )
ppc? ( sys-apps/ibm-powerpc-utils sys-apps/powerpc-utils )
ppc64? ( sys-apps/ibm-powerpc-utils sys-apps/powerpc-utils )
"
DEPEND="${RDEPEND}
${PYTHON_DEPS}
app-misc/pax-utils
sys-devel/flex
sys-devel/bison
sys-apps/help2man
sys-apps/texinfo
static? (
app-arch/xz-utils[static-libs(+)]
truetype? (
app-arch/bzip2[static-libs(+)]
media-libs/freetype[static-libs(+)]
sys-libs/zlib[static-libs(+)]
)
)
test? (
dev-libs/libisoburn
app-emulation/qemu
)
truetype? ( app-arch/unzip )
"
RDEPEND+="
kernel_linux? (
grub_platforms_efi-32? ( sys-boot/efibootmgr )
grub_platforms_efi-64? ( sys-boot/efibootmgr )
)
!multislot? ( !sys-boot/grub:0 )
"
STRIP_MASK="*/grub/*/*.{mod,img}"
RESTRICT="test"
QA_EXECSTACK="
usr/bin/grub*
usr/sbin/grub*
usr/lib*/grub/*/*.mod
usr/lib*/grub/*/*.module
usr/lib*/grub/*/kernel.exec
usr/lib*/grub/*/kernel.img
"
QA_WX_LOAD="
usr/lib*/grub/*/kernel.exec
usr/lib*/grub/*/kernel.img
usr/lib*/grub/*/*.image
"
QA_PRESTRIPPED="
usr/lib.*/grub/.*/kernel.img
"
pkg_pretend() {
if [[ ${MERGE_TYPE} != binary ]]; then
# Bug 439082
if ! version_is_at_least 4.8 "$(gcc-version)" &&
$(tc-getLD) --version | grep -q "GNU gold"; then
eerror "GRUB does not function correctly when built with the gold linker."
eerror "Please select the bfd linker with binutils-config."
die "GNU gold detected"
fi
fi
}
src_unpack() {
if [[ ${PV} == 9999 ]]; then
git-r3_src_unpack
fi
default_src_unpack
}
src_prepare() {
[[ ${PATCHES} ]] && epatch "${PATCHES[@]}"
sed -i -e /autoreconf/d autogen.sh || die
if use multislot; then
# fix texinfo file name, bug 416035
sed -i -e 's/^\* GRUB:/* GRUB2:/' -e 's/(grub)/(grub2)/' docs/grub.texi || die
fi
epatch_user
if [[ -n ${GRUB_AUTOGEN} ]]; then
python_setup
bash autogen.sh || die
fi
if [[ -n ${AUTOTOOLS_AUTORECONF} ]]; then
autopoint() { return 0; }
eautoreconf
fi
}
setup_fonts() {
ln -s "${WORKDIR}/${DEJAVU}/ttf/DejaVuSans.ttf" DejaVuSans.ttf || die
ln -s "${WORKDIR}/${UNIFONT}.pcf" unifont.pcf || die
}
grub_configure() {
local platform
case ${MULTIBUILD_VARIANT} in
efi-32)
platform=efi
if [[ ${CTARGET:-${CHOST}} == x86_64* ]]; then
local CTARGET=${CTARGET:-i386}
fi ;;
efi-64)
platform=efi
if [[ ${CTARGET:-${CHOST}} == i?86* ]]; then
local CTARGET=${CTARGET:-x86_64}
local TARGET_CFLAGS="-Os -march=x86-64 ${TARGET_CFLAGS}"
local TARGET_CPPFLAGS="-march=x86-64 ${TARGET_CPPFLAGS}"
export TARGET_CFLAGS TARGET_CPPFLAGS
fi ;;
guessed) ;;
*) platform=${MULTIBUILD_VARIANT} ;;
esac
local myeconfargs=(
--disable-werror
--program-prefix=
--libdir="${EPREFIX}"/usr/lib
--htmldir="${EPREFIX}"/usr/share/doc/${PF}/html
$(use_enable debug mm-debug)
$(use_enable debug grub-emu-usb)
$(use_enable device-mapper)
$(use_enable mount grub-mount)
$(use_enable nls)
$(use_enable truetype grub-mkfont)
$(use_enable libzfs)
$(use sdl && use_enable debug grub-emu-sdl)
${platform:+--with-platform=}${platform}
# Let configure detect this where supported
$(usex efiemu '' '--disable-efiemu')
)
if use multislot; then
myeconfargs+=( --program-transform-name="s,grub,grub2," )
fi
if use truetype; then
mkdir -p "${BUILD_DIR}" || die
run_in_build_dir setup_fonts
fi
autotools-utils_src_configure
}
src_configure() {
# We don't want to leak flags onto boot code.
export HOST_CCASFLAGS=${CCASFLAGS}
export HOST_CFLAGS=${CFLAGS}
export HOST_CPPFLAGS=${CPPFLAGS}
export HOST_LDFLAGS=${LDFLAGS}
unset CCASFLAGS CFLAGS CPPFLAGS LDFLAGS
use static && HOST_LDFLAGS+=" -static"
if version_is_at_least 4.8 "$(gcc-version)"; then
export TARGET_LDFLAGS+=" -fuse-ld=bfd"
fi
tc-export CC NM OBJCOPY STRIP
export TARGET_CC=${TARGET_CC:-${CC}}
tc-export BUILD_CC # Bug 485592
# Portage will take care of cleaning up GRUB_PLATFORMS
MULTIBUILD_VARIANTS=( ${GRUB_PLATFORMS:-guessed} )
multibuild_parallel_foreach_variant grub_configure
}
src_compile() {
# Sandbox bug 404013.
use libzfs && addpredict /etc/dfs:/dev/zfs
multibuild_foreach_variant autotools-utils_src_compile
use doc && multibuild_for_best_variant \
autotools-utils_src_compile -C docs html
}
src_test() {
# The qemu dependency is a bit complex.
# You will need to adjust QEMU_SOFTMMU_TARGETS to match the cpu/platform.
multibuild_foreach_variant autotools-utils_src_test
}
src_install() {
multibuild_foreach_variant autotools-utils_src_install \
bashcompletiondir="$(get_bashcompdir)"
use doc && multibuild_for_best_variant run_in_build_dir \
emake -C docs DESTDIR="${D}" install-html
if use multislot; then
mv "${ED%/}"/usr/share/info/grub{,2}.info || die
fi
insinto /etc/default
newins "${FILESDIR}"/grub.default-2 grub
cd "${ED}" || die
pax-mark mpes $(scanelf -BF %F usr/{bin,sbin})
}
pkg_postinst() {
mount-boot_mount_boot_partition
if [[ -e "${ROOT%/}/boot/grub2/grub.cfg" && ! -e "${ROOT%/}/boot/grub/grub.cfg" ]]; then
mkdir -p "${ROOT%/}/boot/grub"
ln -s ../grub2/grub.cfg "${ROOT%/}/boot/grub/grub.cfg"
fi
mount-boot_pkg_postinst
elog "For information on how to configure GRUB2 please refer to the guide:"
elog " http://wiki.gentoo.org/wiki/GRUB2_Quick_Start"
if has_version 'sys-boot/grub:0'; then
elog "A migration guide for GRUB Legacy users is available:"
elog " http://www.gentoo.org/doc/en/grub2-migration.xml"
fi
if [[ -z ${REPLACING_VERSIONS} ]]; then
if ! has_version sys-boot/os-prober; then
elog "Install sys-boot/os-prober to enable detection of other operating systems using grub2-mkconfig."
fi
if ! has_version dev-libs/libisoburn; then
elog "Install dev-libs/libisoburn to enable creation of rescue media using grub2-mkrescue."
fi
else
local v
for v in ${REPLACING_VERSIONS}; do
if use multislot && ! version_is_at_least 2.00_p5107-r1 ${v}; then
ewarn "The grub directory has changed from /boot/grub2 to /boot/grub."
ewarn "Please run grub2-install and grub2-mkconfig -o /boot/grub/grub.cfg."
break
fi
done
fi
}
^ permalink raw reply [flat|nested] 2+ messages in thread
* [gentoo-commits] gentoo-x86 commit in sys-boot/grub: grub-9999-r1.ebuild grub-2.02_beta1.ebuild ChangeLog
@ 2013-12-19 14:57 Mike Gilbert (floppym)
0 siblings, 0 replies; 2+ messages in thread
From: Mike Gilbert (floppym) @ 2013-12-19 14:57 UTC (permalink / raw
To: gentoo-commits
floppym 13/12/19 14:57:24
Modified: grub-9999-r1.ebuild grub-2.02_beta1.ebuild
ChangeLog
Log:
Adjust default menu options for grub-2.02.
(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)
Revision Changes Path
1.8 sys-boot/grub/grub-9999-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/grub-9999-r1.ebuild?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/grub-9999-r1.ebuild?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/grub-9999-r1.ebuild?r1=1.7&r2=1.8
Index: grub-9999-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-boot/grub/grub-9999-r1.ebuild,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- grub-9999-r1.ebuild 19 Dec 2013 03:25:54 -0000 1.7
+++ grub-9999-r1.ebuild 19 Dec 2013 14:57:24 -0000 1.8
@@ -1,6 +1,6 @@
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-boot/grub/grub-9999-r1.ebuild,v 1.7 2013/12/19 03:25:54 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-boot/grub/grub-9999-r1.ebuild,v 1.8 2013/12/19 14:57:24 floppym Exp $
EAPI=5
@@ -278,7 +278,7 @@
fi
insinto /etc/default
- newins "${FILESDIR}"/grub.default-2 grub
+ newins "${FILESDIR}"/grub.default-3 grub
cd "${ED}" || die
pax-mark mpes $(scanelf -BF %F usr/{bin,sbin})
1.2 sys-boot/grub/grub-2.02_beta1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/grub-2.02_beta1.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/grub-2.02_beta1.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/grub-2.02_beta1.ebuild?r1=1.1&r2=1.2
Index: grub-2.02_beta1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-boot/grub/grub-2.02_beta1.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- grub-2.02_beta1.ebuild 19 Dec 2013 03:25:54 -0000 1.1
+++ grub-2.02_beta1.ebuild 19 Dec 2013 14:57:24 -0000 1.2
@@ -1,6 +1,6 @@
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-boot/grub/grub-2.02_beta1.ebuild,v 1.1 2013/12/19 03:25:54 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-boot/grub/grub-2.02_beta1.ebuild,v 1.2 2013/12/19 14:57:24 floppym Exp $
EAPI=5
@@ -278,7 +278,7 @@
fi
insinto /etc/default
- newins "${FILESDIR}"/grub.default-2 grub
+ newins "${FILESDIR}"/grub.default-3 grub
cd "${ED}" || die
pax-mark mpes $(scanelf -BF %F usr/{bin,sbin})
1.298 sys-boot/grub/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/ChangeLog?rev=1.298&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/ChangeLog?rev=1.298&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/ChangeLog?r1=1.297&r2=1.298
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-boot/grub/ChangeLog,v
retrieving revision 1.297
retrieving revision 1.298
diff -u -r1.297 -r1.298
--- ChangeLog 19 Dec 2013 03:25:54 -0000 1.297
+++ ChangeLog 19 Dec 2013 14:57:24 -0000 1.298
@@ -1,6 +1,10 @@
# ChangeLog for sys-boot/grub
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-boot/grub/ChangeLog,v 1.297 2013/12/19 03:25:54 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-boot/grub/ChangeLog,v 1.298 2013/12/19 14:57:24 floppym Exp $
+
+ 19 Dec 2013; Mike Gilbert <floppym@gentoo.org> +files/grub.default-3,
+ grub-2.02_beta1.ebuild, grub-9999-r1.ebuild:
+ Adjust default menu options for grub-2.02.
*grub-2.02_beta1 (19 Dec 2013)
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2013-12-19 14:57 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-12-19 14:57 [gentoo-commits] gentoo-x86 commit in sys-boot/grub: grub-9999-r1.ebuild grub-2.02_beta1.ebuild ChangeLog Mike Gilbert (floppym)
-- strict thread matches above, loose matches on Subject: below --
2013-12-19 3:25 Mike Gilbert (floppym)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox