[gentoo-commits] gentoo-x86 commit in kde-base/marble: marble-4.12.0.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in kde-base/marble: marble-4.12.0.ebuild ChangeLog

[Johannes Huber (johu)]

johu        13/12/18 19:57:48

  Modified:             ChangeLog
  Added:                marble-4.12.0.ebuild
  Log:
  Version bump KDE SC 4.12.0
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key F3CFD2BD)

Revision  Changes    Path
1.227                kde-base/marble/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/marble/ChangeLog?rev=1.227&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/marble/ChangeLog?rev=1.227&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/marble/ChangeLog?r1=1.226&r2=1.227

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/marble/ChangeLog,v
retrieving revision 1.226
retrieving revision 1.227
diff -u -r1.226 -r1.227
--- ChangeLog	12 Dec 2013 03:37:29 -0000	1.226
+++ ChangeLog	18 Dec 2013 19:57:48 -0000	1.227
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/marble
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/marble/ChangeLog,v 1.226 2013/12/12 03:37:29 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/marble/ChangeLog,v 1.227 2013/12/18 19:57:48 johu Exp $
+
+*marble-4.12.0 (18 Dec 2013)
+
+  18 Dec 2013; Johannes Huber <johu@gentoo.org> +marble-4.12.0.ebuild:
+  Version bump KDE SC 4.12.0
 
   12 Dec 2013; Agostino Sarubbo <ago@gentoo.org> -marble-4.10.5.ebuild:
   Remove old



1.1                  kde-base/marble/marble-4.12.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/marble/marble-4.12.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/marble/marble-4.12.0.ebuild?rev=1.1&content-type=text/plain

Index: marble-4.12.0.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/marble/marble-4.12.0.ebuild,v 1.1 2013/12/18 19:57:48 johu Exp $

EAPI=5

KDE_HANDBOOK="optional"
KDE_REQUIRED="optional"
CPPUNIT_REQUIRED="optional"
PYTHON_DEPEND="python? 2"
inherit kde4-base python

DESCRIPTION="Generic geographical map widget"
HOMEPAGE="http://marble.kde.org/"
KEYWORDS=" ~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="debug designer-plugin gps +kde plasma python shapefile test zip"

# tests fail / segfault. Last checked for 4.9.0
RESTRICT="test"

RDEPEND="
	dev-qt/qtcore:4
	dev-qt/qtdbus:4
	dev-qt/qtdeclarative:4
	dev-qt/qtgui:4
	dev-qt/qtscript:4
	dev-qt/qtsql:4
	dev-qt/qtsvg:4
	dev-qt/qtwebkit:4
	gps? ( >=sci-geosciences/gpsd-2.95[qt4] )
	python? (
		>=dev-python/PyQt4-4.4.4-r1
		kde? ( $(add_kdebase_dep pykde4) )
	)
	shapefile? ( sci-libs/shapelib )
	zip? ( dev-libs/quazip )
"
DEPEND="
	${RDEPEND}
	test? ( dev-qt/qttest:4 )
"
# the qt dependencies are needed because with USE=-kde nothing is pulled in
# by default... bugs 414165 & 429346

REQUIRED_USE="
	plasma? ( kde )
	python? ( kde )
"

pkg_setup() {
	python_set_active_version 2
	kde4-base_pkg_setup
	python_pkg_setup
}

src_prepare() {
	kde4-base_src_prepare
	python_convert_shebangs -r $(python_get_version) .
}

src_configure() {
	local mycmakeargs=(
		$(cmake-utils_use_with designer-plugin DESIGNER_PLUGIN)
		$(cmake-utils_use python EXPERIMENTAL_PYTHON_BINDINGS)
		$(cmake-utils_use_with python PyQt4)
		$(cmake-utils_use_with python PythonLibrary)
		$(cmake-utils_use_with python SIP)
		$(cmake-utils_use_with gps libgps)
		$(cmake-utils_use !kde QTONLY)
		$(cmake-utils_use_with plasma)
		$(cmake-utils_use_with shapefile libshp)
		$(cmake-utils_use_with zip quazip)
		-DBUILD_MARBLE_TESTS=OFF
		-DWITH_liblocation=0
		-DWITH_QextSerialPort=OFF
		$(use kde && cmake-utils_use_with python PyKDE4)
	)

	kde4-base_src_configure
}

src_test() {
	if use kde; then
		elog "Marble tests can only be run in the qt-only version"
	else
		local mycmakeargs=(
			-DBUILD_MARBLE_TESTS=ON
		)
		kde4-base_src_test
	fi
}