[gentoo-commits] gentoo-x86 commit in media-video/avidemux: avidemux-2.6.7.ebuild avidemux-9999.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in media-video/avidemux: avidemux-2.6.7.ebuild avidemux-9999.ebuild ChangeLog

[Tom Wijsman (tomwij)]

tomwij      13/12/17 23:26:58

  Modified:             avidemux-9999.ebuild ChangeLog
  Added:                avidemux-2.6.7.ebuild
  Log:
  Version bump to 2.6.7, fixes bug #493730.
  
  (Portage version: HEAD/cvs/Linux x86_64, signed Manifest commit with key 6D34E57D)

Revision  Changes    Path
1.4                  media-video/avidemux/avidemux-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/avidemux/avidemux-9999.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/avidemux/avidemux-9999.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/avidemux/avidemux-9999.ebuild?r1=1.3&r2=1.4

Index: avidemux-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/avidemux/avidemux-9999.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- avidemux-9999.ebuild	1 Sep 2013 11:24:28 -0000	1.3
+++ avidemux-9999.ebuild	17 Dec 2013 23:26:58 -0000	1.4
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/avidemux/avidemux-9999.ebuild,v 1.3 2013/09/01 11:24:28 tomwij Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/avidemux/avidemux-9999.ebuild,v 1.4 2013/12/17 23:26:58 tomwij Exp $
 
 EAPI="5"
 
@@ -25,7 +25,7 @@
 	inherit git-2
 else
 	MY_P="${PN}_${PV}"
-	SRC_URI="mirror://sourceforge/${PN}/${PV}/${MY_P}.tar.gz"
+	SRC_URI="mirror://sourceforge/${PN}/${PN}/${PV}/${MY_P}.tar.gz"
 fi
 
 DEPEND="



1.227                media-video/avidemux/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/avidemux/ChangeLog?rev=1.227&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/avidemux/ChangeLog?rev=1.227&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/avidemux/ChangeLog?r1=1.226&r2=1.227

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/avidemux/ChangeLog,v
retrieving revision 1.226
retrieving revision 1.227
diff -u -r1.226 -r1.227
--- ChangeLog	1 Sep 2013 18:54:38 -0000	1.226
+++ ChangeLog	17 Dec 2013 23:26:58 -0000	1.227
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/avidemux
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/avidemux/ChangeLog,v 1.226 2013/09/01 18:54:38 tomwij Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/avidemux/ChangeLog,v 1.227 2013/12/17 23:26:58 tomwij Exp $
+
+*avidemux-2.6.7 (17 Dec 2013)
+
+  17 Dec 2013; Tom Wijsman <TomWij@gentoo.org> +avidemux-2.6.7.ebuild,
+  avidemux-9999.ebuild:
+  Version bump to 2.6.7, fixes bug #493730.
 
 *avidemux-2.6.5-r1 (01 Sep 2013)
 



1.1                  media-video/avidemux/avidemux-2.6.7.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/avidemux/avidemux-2.6.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/avidemux/avidemux-2.6.7.ebuild?rev=1.1&content-type=text/plain

Index: avidemux-2.6.7.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/avidemux/avidemux-2.6.7.ebuild,v 1.1 2013/12/17 23:26:58 tomwij Exp $

EAPI="5"

PLOCALES="ca cs de el es fr it ja pt_BR ru sr sr@latin tr"

inherit cmake-utils eutils flag-o-matic l10n

SLOT="2.6"

DESCRIPTION="Video editor designed for simple cutting, filtering and encoding tasks."
HOMEPAGE="http://fixounet.free.fr/${PN}"

# Multiple licenses because of all the bundled stuff.
LICENSE="GPL-1 GPL-2 MIT PSF-2 public-domain"
IUSE="debug opengl nls qt4 sdl vaapi vdpau video_cards_fglrx xv"
KEYWORDS="~amd64 ~x86"

if [[ ${PV} == *9999* ]] ; then
	KEYWORDS=""
	EGIT_REPO_URI="git://gitorious.org/${PN}2-6/${PN}2-6.git https://git.gitorious.org/${PN}2-6/${PN}2-6.git"

	inherit git-2
else
	MY_P="${PN}_${PV}"
	SRC_URI="mirror://sourceforge/${PN}/${PN}/${PV}/${MY_P}.tar.gz"
fi

DEPEND="
	~media-libs/avidemux-core-${PV}:${SLOT}[nls?,sdl?,vaapi?,vdpau?,video_cards_fglrx?,xv?]
	opengl? ( virtual/opengl:0 )
	qt4? ( >=dev-qt/qtgui-4.8.3:4 )
	vaapi? ( x11-libs/libva:0 )
	video_cards_fglrx? ( x11-libs/xvba-video:0 )
"
RDEPEND="$DEPEND"
PDEPEND="~media-libs/avidemux-plugins-${PV}:${SLOT}[opengl?,qt4?]"

S="${WORKDIR}/${MY_P}"

processes="buildCli:avidemux/cli"
use qt4 && processes+=" buildQt4:avidemux/qt4"

src_prepare() {
	cmake-utils_src_prepare

	# Fix icon name -> avidemux-2.6.png
	sed -i -e "/^Icon/ s:${PN}:${PN}-2.6:" ${PN}2.desktop || die "Icon name fix failed."

	# The desktop file is broken. It uses avidemux2 instead of avidemux3
	# so it will actually launch avidemux-2.5 if it is installed.
	sed -i -e "/^Exec/ s:${PN}2:${PN}3:" ${PN}2.desktop || die "Desktop file fix failed."
	sed -i -re '/^Exec/ s:(avidemux3_)gtk:\1qt4:' ${PN}2.desktop || die "Desktop file fix failed."

	# Fix QA warnings that complain a trailing ; is missing and Application is deprecated.
	sed -i -e 's/Application;AudioVideo/AudioVideo;/g' ${PN}2.desktop || die "Desktop file fix failed."

	# Now rename the desktop file to not collide with 2.5.
	mv ${PN}2.desktop ${PN}-2.6.desktop || die "Collision rename failed."

	# Remove "Build Option" dialog because it doesn't reflect what the GUI can or has been built with. (Bug #463628)
	sed -i -e '/Build Option/d' avidemux/common/ADM_commonUI/myOwnMenu.h || die "Couldn't remove \"Build Option\" dialog."
}

src_configure() {
	local mycmakeargs="
		-DAVIDEMUX_SOURCE_DIR='${S}'
		$(cmake-utils_use nls GETTEXT)
		$(cmake-utils_use sdl)
		$(cmake-utils_use vaapi LIBVA)
		$(cmake-utils_use vdpau)
		$(cmake-utils_use video_cards_fglrx XVBA)
		$(cmake-utils_use xv XVIDEO)
	"

	if use debug ; then
		mycmakeargs+=" -DVERBOSE=1 -DCMAKE_BUILD_TYPE=Debug -DADM_DEBUG=1"
	fi

	for process in ${processes} ; do
		local build="${process%%:*}"

		mkdir "${S}"/${build} || die "Can't create build folder."
		cd "${S}"/${build} || die "Can't enter build folder."
		CMAKE_USE_DIR="${S}"/${process#*:} BUILD_DIR="${S}"/${build} cmake-utils_src_configure
	done

	# Add lax vector typing for PowerPC.
	if use ppc || use ppc64 ; then
		append-cflags -flax-vector-conversions
	fi

	# See bug 432322.
	use x86 && replace-flags -O0 -O1
}

src_compile() {
	for process in ${processes} ; do
		BUILD_DIR="${S}/${process%%:*}" cmake-utils_src_compile
	done
}

DOCS=( AUTHORS README )

src_install() {
	for process in ${processes} ; do
		BUILD_DIR="${S}/${process%%:*}" cmake-utils_src_install
	done

	if [[ -f "${ED}"/usr/bin/avidemux3_cli ]] ; then
		fperms +x /usr/bin/avidemux3_cli
	fi

	if [[ -f "${ED}"/usr/bin/avidemux3_jobs ]] ; then
		fperms +x /usr/bin/avidemux3_jobs
	fi

	cd "${S}" || die "Can't enter source folder."
	newicon ${PN}_icon.png ${PN}-2.6.png

	if use qt4 ; then
		fperms +x /usr/bin/avidemux3_qt4
		domenu ${PN}-2.6.desktop
	fi
}