[gentoo-commits] gentoo-x86 commit in app-arch/dpkg: ChangeLog dpkg-1.17.5.ebuild dpkg-1.17.3.ebuild

[gentoo-commits] gentoo-x86 commit in app-arch/dpkg: ChangeLog dpkg-1.17.5.ebuild dpkg-1.17.3.ebuild

[Jeroen Roovers (jer)]

jer         13/12/12 15:25:25

  Modified:             ChangeLog
  Added:                dpkg-1.17.5.ebuild
  Removed:              dpkg-1.17.3.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.245                app-arch/dpkg/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/dpkg/ChangeLog?rev=1.245&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/dpkg/ChangeLog?rev=1.245&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/dpkg/ChangeLog?r1=1.244&r2=1.245

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-arch/dpkg/ChangeLog,v
retrieving revision 1.244
retrieving revision 1.245
diff -u -r1.244 -r1.245
--- ChangeLog	7 Dec 2013 13:38:39 -0000	1.244
+++ ChangeLog	12 Dec 2013 15:25:25 -0000	1.245
@@ -1,6 +1,12 @@
 # ChangeLog for app-arch/dpkg
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/dpkg/ChangeLog,v 1.244 2013/12/07 13:38:39 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-arch/dpkg/ChangeLog,v 1.245 2013/12/12 15:25:25 jer Exp $
+
+*dpkg-1.17.5 (12 Dec 2013)
+
+  12 Dec 2013; Jeroen Roovers <jer@gentoo.org> -dpkg-1.17.3.ebuild,
+  +dpkg-1.17.5.ebuild:
+  Version bump.
 
 *dpkg-1.17.4 (07 Dec 2013)
 



1.1                  app-arch/dpkg/dpkg-1.17.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/dpkg/dpkg-1.17.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/dpkg/dpkg-1.17.5.ebuild?rev=1.1&content-type=text/plain

Index: dpkg-1.17.5.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-arch/dpkg/dpkg-1.17.5.ebuild,v 1.1 2013/12/12 15:25:25 jer Exp $

EAPI=5
inherit eutils multilib autotools toolchain-funcs

DESCRIPTION="Package maintenance system for Debian"
HOMEPAGE="http://packages.qa.debian.org/dpkg"
SRC_URI="mirror://debian/pool/main/d/${PN}/${P/-/_}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-solaris ~x86-solaris"
IUSE="+bzip2 dselect +lzma nls test unicode +update-alternatives +zlib"
REQUIRED_USE="dselect? ( nls )"

RDEPEND="
	>=dev-lang/perl-5.6.0
	dev-perl/TimeDate
	>=sys-libs/ncurses-5.2-r7
	lzma? ( app-arch/xz-utils )
	zlib? ( >=sys-libs/zlib-1.1.4 )
	bzip2? ( app-arch/bzip2 )
"
DEPEND="
	${RDEPEND}
	app-arch/xz-utils
	sys-devel/flex
	virtual/pkgconfig
	nls? (
		app-text/po4a
		>=sys-devel/gettext-0.18.2
	)
	test? (
		dev-perl/DateTime-Format-DateParse
		dev-perl/IO-String
		dev-perl/Test-Pod
	)
"

DOCS=( ChangeLog THANKS TODO )

src_prepare() {
	# do not expect Debian's gzip --rsyncable extension
	epatch "${FILESDIR}"/${PN}-1.17.0-gzip-rsyncable.patch

	epatch "${FILESDIR}"/${PN}-1.17.1-flags.patch

	# Force the use of the running bash for get-version (this file is never
	# installed, so no need to worry about hardcoding a temporary bash)
	sed -i -e '1c\#!'"${BASH}" get-version || die

	# this test depends on a Debian only gzip extension that adds --rsyncable
	# which will therefore always fail on Gentoo. (bug #310847).
	sed -i scripts/Makefile.am \
		-e '/850_Dpkg_Compression.t/d' \
		|| die "sed failed"

	# test fails (bug #414095)
	sed -i utils/Makefile.am \
		-e '/^test_cases/d;/100_update_alternatives/d' || die

	use nls && strip-linguas -i po

	eautoreconf
}

src_configure() {
	tc-export CC
	econf \
		$(use_enable dselect) \
		$(use_enable nls) \
		$(use_enable unicode) \
		$(use_enable update-alternatives) \
		$(use_with bzip2 bz2) \
		$(use_with zlib) \
		$(use_with lzma liblzma) \
		--disable-compiler-warnings \
		--disable-silent-rules \
		--disable-start-stop-daemon \
		--localstatedir="${EPREFIX}"/var \
		--without-selinux
}

src_compile() {
	emake AR=$(tc-getAR)
}

src_install() {
	default

	keepdir /usr/$(get_libdir)/db/methods/{mnt,floppy,disk}
	keepdir /usr/$(get_libdir)/db/{alternatives,info,methods,parts,updates}
}