* [gentoo-commits] gentoo-x86 commit in dev-util/eric: eric-5.3.8.ebuild eric-4.5.16.ebuild ChangeLog eric-5.3.7.ebuild eric-4.5.15.ebuild
@ 2013-11-24 22:54 Davide Pesavento (pesa)
0 siblings, 0 replies; only message in thread
From: Davide Pesavento (pesa) @ 2013-11-24 22:54 UTC (permalink / raw
To: gentoo-commits
pesa 13/11/24 22:54:02
Modified: ChangeLog
Added: eric-5.3.8.ebuild eric-4.5.16.ebuild
Removed: eric-5.3.7.ebuild eric-4.5.15.ebuild
Log:
Version bumps; tweak sed expression wrt bug 487272.
(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 17A85C72)
Revision Changes Path
1.205 dev-util/eric/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/eric/ChangeLog?rev=1.205&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/eric/ChangeLog?rev=1.205&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/eric/ChangeLog?r1=1.204&r2=1.205
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/eric/ChangeLog,v
retrieving revision 1.204
retrieving revision 1.205
diff -u -r1.204 -r1.205
--- ChangeLog 14 Oct 2013 18:05:35 -0000 1.204
+++ ChangeLog 24 Nov 2013 22:54:02 -0000 1.205
@@ -1,6 +1,14 @@
# ChangeLog for dev-util/eric
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/eric/ChangeLog,v 1.204 2013/10/14 18:05:35 chainsaw Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/eric/ChangeLog,v 1.205 2013/11/24 22:54:02 pesa Exp $
+
+*eric-5.3.8 (24 Nov 2013)
+*eric-4.5.16 (24 Nov 2013)
+
+ 24 Nov 2013; Davide Pesavento <pesa@gentoo.org> +eric-4.5.16.ebuild,
+ +eric-5.3.8.ebuild, -eric-4.5.15.ebuild, -eric-5.3.7.ebuild,
+ -files/eric-4.4-no-interactive.patch:
+ Version bumps; tweak sed expression wrt bug 487272.
14 Oct 2013; Tony Vroon <chainsaw@gentoo.org> eric-4.5.14.ebuild,
eric-5.3.6.ebuild:
1.1 dev-util/eric/eric-5.3.8.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/eric/eric-5.3.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/eric/eric-5.3.8.ebuild?rev=1.1&content-type=text/plain
Index: eric-5.3.8.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/eric/eric-5.3.8.ebuild,v 1.1 2013/11/24 22:54:02 pesa Exp $
EAPI=4
PYTHON_DEPEND="3:3.1"
PYTHON_USE_WITH="sqlite"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="2.* *-jython 2.7-pypy-*"
PLOCALES="cs de en es fr it ru tr zh_CN"
inherit eutils l10n python
DESCRIPTION="A full featured Python IDE using PyQt4 and QScintilla"
HOMEPAGE="http://eric-ide.python-projects.org/"
SLOT="5"
MY_PV=${PV/_pre/-snapshot-}
MY_P=${PN}${SLOT}-${MY_PV}
BASE_URI="mirror://sourceforge/eric-ide/${PN}${SLOT}/stable/${PV}"
SRC_URI="${BASE_URI}/${MY_P}.tar.gz"
for L in ${PLOCALES}; do
SRC_URI+=" linguas_${L}? ( ${BASE_URI}/${PN}${SLOT}-i18n-${L/zh_CN/zh_CN.GB2312}-${MY_PV}.tar.gz )"
done
unset L
LICENSE="GPL-3"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="spell"
DEPEND="
>=dev-python/sip-4.12.4
>=dev-python/PyQt4-4.9.6-r1[X,help,sql,svg,webkit]
>=dev-python/qscintilla-python-2.6
"
RDEPEND="${DEPEND}
>=dev-python/chardet-2.0.1
>=dev-python/coverage-3.2
>=dev-python/pygments-1.5
"
PDEPEND="
spell? ( dev-python/pyenchant )
"
S=${WORKDIR}/${MY_P}
PYTHON_VERSIONED_EXECUTABLES=("/usr/bin/.*")
src_prepare() {
# Avoid file collisions between different slots of Eric.
sed -i -e 's/^Icon=eric$/&5/' eric/eric5.desktop || die
sed -i -e 's/\([^[:alnum:]]\)eric\.png\([^[:alnum:]]\)/\1eric5.png\2/' \
$(grep -lr 'eric\.png' .) || die
mv eric/icons/default/eric{,5}.png || die
mv eric/pixmaps/eric{,5}.png || die
rm -f eric/APIs/Python/zope-*.api
rm -f eric/APIs/Ruby/Ruby-*.api
# Delete internal copies of dev-python/chardet,
# dev-python/coverage and dev-python/pygments.
rm -fr eric/ThirdParty
rm -fr eric/DebugClients/Python{,3}/coverage
sed -i -e 's/from DebugClients\.Python3\?\.coverage/from coverage/' \
$(grep -lr 'from DebugClients\.Python3\?\.coverage' .) || die
# Fix desktop files (bug 458092).
sed -i -e '/^Categories=/s:Python:X-&:' eric/eric5{,_webbrowser}.desktop || die
}
src_install() {
installation() {
"$(PYTHON)" install.py \
-z \
-b "${EPREFIX}/usr/bin" \
-i "${T}/images/${PYTHON_ABI}" \
-d "${EPREFIX}$(python_get_sitedir)" \
-c
}
python_execute_function installation
python_merge_intermediate_installation_images "${T}/images"
doicon eric/icons/default/eric5.png || die
}
pkg_postinst() {
python_mod_optimize -x "/eric5/(DebugClients/Python|UtilitiesPython2)/" eric5{,config.py,plugins}
elog
elog "If you want to use Eric with mod_python, have a look at"
elog "\"${EROOT}$(python_get_sitedir -b -f)/eric5/patch_modpython.py\"."
elog
elog "The following packages will give Eric extended functionality:"
elog " dev-python/pylint"
elog " dev-python/pysvn"
elog
elog "This version has a plugin interface with plugin-autofetch from"
elog "the application itself. You may want to check those as well."
elog
}
pkg_postrm() {
python_mod_cleanup eric5{,config.py,plugins}
}
1.1 dev-util/eric/eric-4.5.16.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/eric/eric-4.5.16.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/eric/eric-4.5.16.ebuild?rev=1.1&content-type=text/plain
Index: eric-4.5.16.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/eric/eric-4.5.16.ebuild,v 1.1 2013/11/24 22:54:02 pesa Exp $
EAPI=4
PYTHON_DEPEND="2:2.6"
SUPPORT_PYTHON_ABIS="1"
# 2.4 and 2.5 are restricted to avoid conditional dependency on dev-python/simplejson.
RESTRICT_PYTHON_ABIS="2.4 2.5 3.* *-jython 2.7-pypy-*"
PLOCALES="cs de en es fr it ru tr zh_CN"
inherit eutils l10n python
DESCRIPTION="A full featured Python IDE using PyQt4 and QScintilla"
HOMEPAGE="http://eric-ide.python-projects.org/"
SLOT="4"
MY_PV=${PV/_pre/-snapshot-}
MY_P=${PN}${SLOT}-${MY_PV}
BASE_URI="mirror://sourceforge/eric-ide/${PN}${SLOT}/stable/${PV}"
SRC_URI="${BASE_URI}/${MY_P}.tar.gz"
for L in ${PLOCALES}; do
SRC_URI+=" linguas_${L}? ( ${BASE_URI}/${PN}${SLOT}-i18n-${L/zh_CN/zh_CN.GB2312}-${MY_PV}.tar.gz )"
done
unset L
LICENSE="GPL-3"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="kde spell"
DEPEND="
>=dev-python/sip-4.12.4
>=dev-python/PyQt4-4.9.6-r1[X,help,svg,webkit]
>=dev-python/qscintilla-python-2.3
kde? ( kde-base/pykde4 )
"
RDEPEND="${DEPEND}
>=dev-python/chardet-2.0.1
>=dev-python/coverage-3.0.1
>=dev-python/pygments-1.3.1
"
PDEPEND="
spell? ( dev-python/pyenchant )
"
S=${WORKDIR}/${MY_P}
PYTHON_VERSIONED_EXECUTABLES=("/usr/bin/.*")
src_prepare() {
epatch "${FILESDIR}/eric-4.5-no-interactive.patch"
use kde || epatch "${FILESDIR}/eric-4.4-no-pykde.patch"
# Delete internal copies of dev-python/chardet, dev-python/coverage,
# dev-python/pygments and dev-python/simplejson.
rm -fr eric/ThirdParty
rm -fr eric/DebugClients/Python{,3}/coverage
sed -i -e 's/from DebugClients\.Python3\?\.coverage/from coverage/' \
$(grep -lr 'from DebugClients\.Python3\?\.coverage' .) || die
}
src_install() {
installation() {
"$(PYTHON)" install.py \
-z \
-b "${EPREFIX}/usr/bin" \
-i "${T}/images/${PYTHON_ABI}" \
-d "${EPREFIX}$(python_get_sitedir)" \
-c
}
python_execute_function installation
python_merge_intermediate_installation_images "${T}/images"
doicon eric/icons/default/eric.png || die
make_desktop_entry "eric4 --nosplash" eric4 eric "Development;IDE;Qt"
}
pkg_postinst() {
python_mod_optimize eric4{,config.py,plugins}
elog
elog "If you want to use Eric with mod_python, have a look at"
elog "\"${EROOT}$(python_get_sitedir -b -f)/eric4/patch_modpython.py\"."
elog
elog "The following packages will give Eric extended functionality:"
elog " dev-python/pylint"
elog " dev-python/pysvn"
elog
elog "This version has a plugin interface with plugin-autofetch from"
elog "the application itself. You may want to check those as well."
elog
}
pkg_postrm() {
python_mod_cleanup eric4{,config.py,plugins}
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2013-11-24 22:54 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-11-24 22:54 [gentoo-commits] gentoo-x86 commit in dev-util/eric: eric-5.3.8.ebuild eric-4.5.16.ebuild ChangeLog eric-5.3.7.ebuild eric-4.5.15.ebuild Davide Pesavento (pesa)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox