[gentoo-commits] gentoo-x86 commit in net-nntp/nzbget: ChangeLog nzbget-12.0_pre906.ebuild

[gentoo-commits] gentoo-x86 commit in net-nntp/nzbget: ChangeLog nzbget-12.0_pre906.ebuild

[Tim Harder (radhermit)]

radhermit    13/11/14 07:57:56

  Modified:             ChangeLog
  Added:                nzbget-12.0_pre906.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.78                 net-nntp/nzbget/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-nntp/nzbget/ChangeLog?rev=1.78&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-nntp/nzbget/ChangeLog?rev=1.78&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-nntp/nzbget/ChangeLog?r1=1.77&r2=1.78

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-nntp/nzbget/ChangeLog,v
retrieving revision 1.77
retrieving revision 1.78
diff -u -r1.77 -r1.78
--- ChangeLog	3 Nov 2013 07:33:51 -0000	1.77
+++ ChangeLog	14 Nov 2013 07:57:56 -0000	1.78
@@ -1,6 +1,11 @@
 # ChangeLog for net-nntp/nzbget
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-nntp/nzbget/ChangeLog,v 1.77 2013/11/03 07:33:51 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-nntp/nzbget/ChangeLog,v 1.78 2013/11/14 07:57:56 radhermit Exp $
+
+*nzbget-12.0_pre906 (14 Nov 2013)
+
+  14 Nov 2013; Tim Harder <radhermit@gentoo.org> +nzbget-12.0_pre906.ebuild:
+  Version bump.
 
 *nzbget-12.0_pre883 (03 Nov 2013)
 



1.1                  net-nntp/nzbget/nzbget-12.0_pre906.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-nntp/nzbget/nzbget-12.0_pre906.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-nntp/nzbget/nzbget-12.0_pre906.ebuild?rev=1.1&content-type=text/plain

Index: nzbget-12.0_pre906.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-nntp/nzbget/nzbget-12.0_pre906.ebuild,v 1.1 2013/11/14 07:57:56 radhermit Exp $

EAPI=5

inherit autotools user

MY_P=${P/_pre/-testing-r}

DESCRIPTION="A command-line based binary newsgrapper supporting .nzb files"
HOMEPAGE="http://nzbget.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="debug gnutls ncurses parcheck ssl zlib "

RDEPEND="dev-libs/libxml2
	ncurses? ( sys-libs/ncurses )
	parcheck? (
		app-arch/libpar2
		dev-libs/libsigc++:2
	)
	ssl? (
		gnutls? ( net-libs/gnutls )
		!gnutls? ( dev-libs/openssl )
	)
	zlib? ( sys-libs/zlib )"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

DOCS=( AUTHORS ChangeLog README nzbget.conf )

S=${WORKDIR}/${P/_pre*/-testing}

src_prepare() {
	sed -i 's:^ScriptDir=.*:ScriptDir=/usr/share/nzbget/ppscripts:' nzbget.conf || die

	sed -e 's:^MainDir=.*:MainDir=/var/lib/nzbget:' \
		-e 's:^LockFile=.*:LockFile=/run/nzbget/nzbget.pid:' \
		-e 's:^LogFile=.*:LogFile=/var/log/nzbget/nzbget.log:' \
		"${S}"/nzbget.conf > "${S}"/nzbgetd.conf || die

	sed -i "/^dist_doc_DATA/d" Makefile.am || die

	eautoreconf
}

src_configure() {
	econf \
		$(use_enable debug) \
		$(use_enable ncurses curses) \
		$(use_enable parcheck) \
		--disable-libpar2-bugfixes-check \
		$(use_enable ssl tls) \
		$(use_enable zlib gzip) \
		--with-tlslib=$(usex gnutls GnuTLS OpenSSL)
}

src_install() {
	default

	# remove unneeded service script
	rm "${D}"/usr/sbin/nzbgetd || die

	insinto /etc
	doins nzbget.conf
	doins nzbgetd.conf

	# remove duplicate script/config
	rm "${D}"/usr/share/nzbget/nzbget.conf || die

	keepdir /var/lib/nzbget/{dst,nzb,queue,tmp}
	keepdir /var/log/nzbget

	newinitd "${FILESDIR}"/nzbget.initd nzbget
	newconfd "${FILESDIR}"/nzbget.confd nzbget
}

pkg_preinst() {
	enewgroup nzbget
	enewuser nzbget -1 -1 /var/lib/nzbget nzbget

	fowners nzbget:nzbget /var/lib/nzbget/{dst,nzb,queue,tmp}
	fperms 750 /var/lib/nzbget/{queue,tmp}
	fperms 770 /var/lib/nzbget/{dst,nzb}

	fowners nzbget:nzbget /var/log/nzbget
	fperms 750 /var/log/nzbget

	fowners root:nzbget /etc/nzbgetd.conf
	fperms 640 /etc/nzbgetd.conf
}

pkg_postinst() {
	if [[ -z ${REPLACING_VERSIONS} ]] ; then
		elog
		elog "Please add users that you want to be able to use the system-wide"
		elog "nzbget daemon to the nzbget group. To access the daemon run nzbget"
		elog "with the --configfile /etc/nzbgetd.conf option."
		elog
	fi
}