[gentoo-commits] gentoo-x86 commit in sci-libs/ceres-solver: metadata.xml ceres-solver-1.8.0.ebuild ChangeLog ceres-solver-1.4.0.ebuild ceres-solver-1.6.0.ebuild

[gentoo-commits] gentoo-x86 commit in sci-libs/ceres-solver: metadata.xml ceres-solver-1.8.0.ebuild ChangeLog ceres-solver-1.4.0.ebuild ceres-solver-1.6.0.ebuild

[Sebastien Fabbro (bicatali)]

bicatali    13/11/14 01:49:00

  Modified:             metadata.xml ChangeLog
  Added:                ceres-solver-1.8.0.ebuild
  Removed:              ceres-solver-1.4.0.ebuild ceres-solver-1.6.0.ebuild
  Log:
  Version bump. Separate cxsparse (simpler library) from sparse flag, add lapack flag, adapt changes upstream to be more cmake friendly
  
  (Portage version: 2.2.7-prefix/cvs/Linux x86_64, signed Manifest commit with key 0x13CB1360)

Revision  Changes    Path
1.4                  sci-libs/ceres-solver/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/ceres-solver/metadata.xml?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/ceres-solver/metadata.xml?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/ceres-solver/metadata.xml?r1=1.3&r2=1.4

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-libs/ceres-solver/metadata.xml,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- metadata.xml	11 Jan 2013 19:37:29 -0000	1.3
+++ metadata.xml	14 Nov 2013 01:49:00 -0000	1.4
@@ -19,6 +19,8 @@
       adjustment problems
 </longdescription>
 <use>
+  <flag name="cxsparse">Enable simple support for sparse matrix algebra from
+  <pkg>sci-libs/cxsparse</pkg> with no LAPACK dependencies</flag>
   <flag name="schur">Enable fixed-size schur specializations (disable if
   binary size is an issue)</flag>
   <flag name="metis">Use METIS via <pkg>sci-libs/cholmod</pkg> for matrix partitioning</flag>



1.7                  sci-libs/ceres-solver/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/ceres-solver/ChangeLog?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/ceres-solver/ChangeLog?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/ceres-solver/ChangeLog?r1=1.6&r2=1.7

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-libs/ceres-solver/ChangeLog,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- ChangeLog	23 Oct 2013 18:36:55 -0000	1.6
+++ ChangeLog	14 Nov 2013 01:49:00 -0000	1.7
@@ -1,6 +1,15 @@
 # ChangeLog for sci-libs/ceres-solver
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/ceres-solver/ChangeLog,v 1.6 2013/10/23 18:36:55 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/ceres-solver/ChangeLog,v 1.7 2013/11/14 01:49:00 bicatali Exp $
+
+*ceres-solver-1.8.0 (14 Nov 2013)
+
+  14 Nov 2013; Sébastien Fabbro <bicatali@gentoo.org>
+  +ceres-solver-1.8.0.ebuild, -ceres-solver-1.4.0.ebuild,
+  -ceres-solver-1.6.0.ebuild, -files/ceres-solver-1.4.0-respect-libdir.patch,
+  -files/ceres-solver-1.4.0-test-no-suitesparse.patch, metadata.xml:
+  Version bump. Separate cxsparse (simpler library) from sparse flag, add lapack
+  flag, adapt changes upstream to be more cmake friendly
 
 *ceres-solver-1.7.0 (23 Oct 2013)
 



1.1                  sci-libs/ceres-solver/ceres-solver-1.8.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/ceres-solver/ceres-solver-1.8.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/ceres-solver/ceres-solver-1.8.0.ebuild?rev=1.1&content-type=text/plain

Index: ceres-solver-1.8.0.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-libs/ceres-solver/ceres-solver-1.8.0.ebuild,v 1.1 2013/11/14 01:49:00 bicatali Exp $

EAPI=5

inherit cmake-utils eutils multilib

DESCRIPTION="Nonlinear least-squares minimizer"
HOMEPAGE="https://code.google.com/p/ceres-solver/"
SRC_URI="https://${PN}.googlecode.com/files/${P}.tar.gz"

LICENSE="BSD"
SLOT="0/1"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="cxsparse doc examples gflags lapack openmp protobuf +schur sparse static-libs test"
REQUIRED_USE="test? ( gflags ) sparse? ( lapack )"

RDEPEND="
	dev-cpp/glog[gflags?]
	cxsparse? ( sci-libs/cxsparse )
	lapack? ( virtual/lapack )
	protobuf? ( dev-libs/protobuf )
	sparse? (
		sci-libs/amd
		sci-libs/camd
		sci-libs/ccolamd
		sci-libs/cholmod
		sci-libs/colamd
		sci-libs/spqr )"

DEPEND="${RDEPEND}
	dev-cpp/eigen:3
	lapack? ( virtual/pkgconfig )
	doc? ( dev-python/sphinx )"

src_prepare() {
	# prefix love
	sed -i \
		-e "s:/usr:${EPREFIX}/usr:g" \
		cmake/*.cmake || die

	# remove Werror and
	sed -i \
		-e 's/-Werror//g' \
		CMakeLists.txt || die

	# respect gentoo doc dir
	sed -i \
		-e "s:share/doc/ceres:share/doc/${PF}:" \
		docs/source/CMakeLists.txt || die
}

src_configure() {
	local mycmakeargs=(
		-DBUILD_SHARED_LIBS=ON
		-DBUILD_EXAMPLES=OFF
		$(cmake-utils_use_enable test TESTING)
		$(cmake-utils_use doc BUILD_DOCUMENTATION)
		$(cmake-utils_use gflags GFLAGS)
		$(cmake-utils_use lapack LAPACK)
		$(cmake-utils_use openmp OPENMP)
		$(cmake-utils_use protobuf PROTOBUF)
		$(cmake-utils_use schur SCHUR_SPECIALIZATIONS)
		$(cmake-utils_use cxsparse CXSPARSE)
		$(cmake-utils_use sparse SUITESPARSE)
	)
	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install
	dodoc README VERSION

	if use examples; then
		insinto /usr/share/doc/${PF}
		docompress -x /usr/share/doc/${PF}/examples
		doins -r examples data
	fi
}